let X be set ; :: thesis: for S being SigmaField of X
for F being Function of NAT ,S
for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ) holds
A /\ (great_dom f,-infty ) = union (rng F)
let S be SigmaField of X; :: thesis: for F being Function of NAT ,S
for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ) holds
A /\ (great_dom f,-infty ) = union (rng F)
let F be Function of NAT ,S; :: thesis: for f being PartFunc of X,ExtREAL
for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ) holds
A /\ (great_dom f,-infty ) = union (rng F)
let f be PartFunc of X,ExtREAL ; :: thesis: for A being set st ( for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ) holds
A /\ (great_dom f,-infty ) = union (rng F)
let A be set ; :: thesis: ( ( for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ) implies A /\ (great_dom f,-infty ) = union (rng F) )
assume A1: for n being Element of NAT holds F . n = A /\ (great_dom f,(R_EAL (- n))) ; :: thesis: A /\ (great_dom f,-infty ) = union (rng F)
A2: for x being set st x in A /\ (great_dom f,-infty ) holds
x in union (rng F)

proof

let x be set ; :: thesis: ( x in A /\ (great_dom f,-infty ) implies x in union (rng F) )
assume A3: x in A /\ (great_dom f,-infty ) ; :: thesis: x in union (rng F)
A4: x in A by A3, XBOOLE_0:def 4;
A5: x in great_dom f,-infty by A3, XBOOLE_0:def 4;
A6: x in dom f by A5, Def14;
A7: -infty < f . x by A5, Def14;
A8: ex n being Element of NAT st R_EAL (- n) < f . x

proof

per cases ( f . x = +infty or not f . x = +infty ) ;

suppose A9: f . x = +infty ; :: thesis: ex n being Element of NAT st R_EAL (- n) < f . x

take 0 ; :: thesis: R_EAL (- 0 ) < f . x
thus R_EAL (- 0 ) < f . x by A9; :: thesis: verum

end;

suppose A10: not f . x = +infty ; :: thesis: ex n being Element of NAT st R_EAL (- n) < f . x

A11: not +infty <= f . x by A10, XXREAL_0:4;
reconsider y1 = f . x as Real by A7, A11, XXREAL_0:48;
consider n1 being Element of NAT such that
A12: - n1 <= y1 by Th12;
A13: n1 < n1 + 1 by NAT_1:13;
A14: - (n1 + 1) < - n1 by A13, XREAL_1:26;
reconsider m = n1 + 1 as Element of NAT ;
take m ; :: thesis: R_EAL (- m) < f . x
thus R_EAL (- m) < f . x by A12, A14, XXREAL_0:2; :: thesis: verum

end;

end;

end;

consider n being Element of NAT such that
A15: R_EAL (- n) < f . x by A8;
reconsider x = x as Element of X by A3;
A16: x in great_dom f,(R_EAL (- n)) by A6, A15, Def14;
A17: x in A /\ (great_dom f,(R_EAL (- n))) by A4, A16, XBOOLE_0:def 4;
A18: x in F . n by A1, A17;
A19: n in NAT ;
A20: n in dom F by A19, FUNCT_2:def 1;
A21: F . n in rng F by A20, FUNCT_1:def 5;
thus x in union (rng F) by A18, A21, TARSKI:def 4; :: thesis: verum

end;

A22: A /\ (great_dom f,-infty ) c= union (rng F) by A2, TARSKI:def 3;
A23: for x being set st x in union (rng F) holds
x in A /\ (great_dom f,-infty )

proof

let x be set ; :: thesis: ( x in union (rng F) implies x in A /\ (great_dom f,-infty ) )
assume A24: x in union (rng F) ; :: thesis: x in A /\ (great_dom f,-infty )
consider Y being set such that
A25: x in Y and
A26: Y in rng F by A24, TARSKI:def 4;
consider m being Element of NAT such that
m in dom F and
A27: F . m = Y by A26, PARTFUN1:26;
A28: x in A /\ (great_dom f,(R_EAL (- m))) by A1, A25, A27;
A29: x in A by A28, XBOOLE_0:def 4;
A30: x in great_dom f,(R_EAL (- m)) by A28, XBOOLE_0:def 4;
A31: x in dom f by A30, Def14;
A32: R_EAL (- m) < f . x by A30, Def14;
reconsider x = x as Element of X by A25, A26;
A33: -infty < f . x by A32, XXREAL_0:2, XXREAL_0:12;
A34: x in great_dom f,-infty by A31, A33, Def14;
thus x in A /\ (great_dom f,-infty ) by A29, A34, XBOOLE_0:def 4; :: thesis: verum

end;

A35: union (rng F) c= A /\ (great_dom f,-infty ) by A23, TARSKI:def 3;
thus A /\ (great_dom f,-infty ) = union (rng F) by A22, A35, XBOOLE_0:def 10; :: thesis: verum