let K be Field; :: thesis: for a, b, c, d, e, f, g, h, i being Element of K
for M being Matrix of 3,K st M = <*<*a,b,c*>,<*d,e,f*>,<*g,h,i*>*> holds
Det M = ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h)
reconsider a3 = <*1,3,2*>, a4 = <*2,3,1*>, a5 = <*2,1,3*>, a6 = <*3,1,2*> as Element of Permutations 3 by Th27;
reconsider id3 = idseq 3 as Permutation of (Seg 3) ;
reconsider Id3 = idseq 3 as Element of Permutations 3 by MATRIX_2:def 11;
A1: id3 is even by MATRIX_2:29;
reconsider rid3 = Rev (idseq 3) as Element of Permutations 3 by Th4;
let a, b, c, d, e, f, g, h, i be Element of K; :: thesis: for M being Matrix of 3,K st M = <*<*a,b,c*>,<*d,e,f*>,<*g,h,i*>*> holds
Det M = ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h)
let M be Matrix of 3,K; :: thesis: ( M = <*<*a,b,c*>,<*d,e,f*>,<*g,h,i*>*> implies Det M = ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h) )
assume A2: M = <*<*a,b,c*>,<*d,e,f*>,<*g,h,i*>*> ; :: thesis: Det M = ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h)
FinOmega (Permutations 3) = Permutations 3 by MATRIX_2:30, MATRIX_2:def 17;
then reconsider X = {Id3,rid3,a3,a4,a5,a6} as Element of Fin (Permutations 3) by Th15, Th19, FINSEQ_2:62;
reconsider B1 = {.Id3,rid3,a3.}, B2 = {.a4,a5,a6.} as Element of Fin (Permutations 3) ;
set F = the addF of K;
A3: ( FinOmega (Permutations 3) = X & X = {Id3,rid3,a3} \/ {a4,a5,a6} ) by Th15, Th19, ENUMSET1:53, FINSEQ_2:62, MATRIX_2:def 17;

now

let x be set ; :: thesis: ( x in B1 implies x in B1 \ B2 )
assume A4: x in B1 ; :: thesis: x in B1 \ B2
then ( x = Id3 or x = rid3 or x = a3 ) by ENUMSET1:def 1;
then not x in B2 by Lm5, Lm6, Lm7, Lm8, Lm9, Th15, ENUMSET1:def 1, FINSEQ_2:62;
hence x in B1 \ B2 by A4, XBOOLE_0:def 5; :: thesis: verum

end;

then A5: B1 c= B1 \ B2 by TARSKI:def 3;
for x being set st x in B1 \ B2 holds
x in B1 by XBOOLE_0:def 5;
then B1 \ B2 c= B1 by TARSKI:def 3;
then B1 \ B2 = B1 by A5, XBOOLE_0:def 10;
then A6: B1 misses B2 by XBOOLE_1:83;
set r = Path_product M;
A7: 3 = len (Permutations 3) by MATRIX_2:20;
then Id3 is even by MATRIX_2:29;
then reconsider r1 = (Path_product M) . id3, r2 = (Path_product M) . rid3, r3 = (Path_product M) . a3, r4 = (Path_product M) . a4, r5 = (Path_product M) . a5, r6 = (Path_product M) . a6 as Element of K by FUNCT_2:7;
A8: (Path_product M) . id3 = - (the multF of K $$ (Path_matrix Id3,M)),Id3 by MATRIX_3:def 8
.= the multF of K $$ (Path_matrix Id3,M) by A1, A7, MATRIX_2:def 16
.= the multF of K $$ <*a,e,i*> by A2, Th20, FINSEQ_2:62
.= (a * e) * i by Th26 ;
A9: (Path_product M) . a6 = - (the multF of K $$ (Path_matrix a6,M)),a6 by MATRIX_3:def 8
.= the multF of K $$ (Path_matrix a6,M) by A7, Lm14, MATRIX_2:def 16
.= the multF of K $$ <*c,d,h*> by A2, Th25
.= (c * d) * h by Th26 ;
A10: (Path_product M) . a5 = - (the multF of K $$ (Path_matrix a5,M)),a5 by MATRIX_3:def 8
.= - (the multF of K $$ (Path_matrix a5,M)) by A7, Th43, MATRIX_2:def 16
.= - (the multF of K $$ <*b,d,i*>) by A2, Th24
.= - ((b * d) * i) by Th26 ;
A11: (Path_product M) . a4 = - (the multF of K $$ (Path_matrix a4,M)),a4 by MATRIX_3:def 8
.= the multF of K $$ (Path_matrix a4,M) by A7, Lm13, MATRIX_2:def 16
.= the multF of K $$ <*b,f,g*> by A2, Th23
.= (b * f) * g by Th26 ;
A12: (Path_product M) . a3 = - (the multF of K $$ (Path_matrix a3,M)),a3 by MATRIX_3:def 8
.= - (the multF of K $$ (Path_matrix a3,M)) by A7, Th44, MATRIX_2:def 16
.= - (the multF of K $$ <*a,f,h*>) by A2, Th22
.= - ((a * f) * h) by Th26 ;
A13: (Path_product M) . rid3 = - (the multF of K $$ (Path_matrix rid3,M)),rid3 by MATRIX_3:def 8
.= - (the multF of K $$ (Path_matrix rid3,M)) by A7, Th15, Th42, MATRIX_2:def 16
.= - (the multF of K $$ <*c,e,g*>) by A2, Th15, Th21
.= - ((c * e) * g) by Th26 ;
A14: ( the addF of K $$ B1,(Path_product M) = (r1 + r2) + r3 & the addF of K $$ B2,(Path_product M) = (r4 + r5) + r6 ) by Lm3, Lm4, Lm10, Lm11, Th15, FINSEQ_2:62, SETWOP_2:5;
Det M = the addF of K $$ (FinOmega (Permutations 3)),(Path_product M) by MATRIX_3:def 9
.= the addF of K . (the addF of K $$ B1,(Path_product M)),(the addF of K $$ B2,(Path_product M)) by A3, A6, SETWOP_2:6
.= ((r1 + r2) + r3) + (r4 + (r5 + r6)) by A14, RLVECT_1:def 6
.= (((r1 + r2) + r3) + r4) + (r5 + r6) by RLVECT_1:def 6
.= ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h) by A8, A13, A12, A11, A10, A9, RLVECT_1:def 6 ;
hence Det M = ((((((a * e) * i) - ((c * e) * g)) - ((a * f) * h)) + ((b * f) * g)) - ((b * d) * i)) + ((c * d) * h) ; :: thesis: verum