let n be Nat; :: thesis: for M1, M2 being Matrix of n, REAL st M1 is Positive & M2 is Negative & |:M1:| is_less_than |:M2:| holds
M1 + M2 is Negative
let M1, M2 be Matrix of n, REAL ; :: thesis: ( M1 is Positive & M2 is Negative & |:M1:| is_less_than |:M2:| implies M1 + M2 is Negative )
assume that
A1: M1 is Positive and
A2: M2 is Negative and
A3: |:M1:| is_less_than |:M2:| ; :: thesis: M1 + M2 is Negative
A4: Indices M1 = [:(Seg n),(Seg n):] by MATRIX_1:25;
A5: Indices (M1 + M2) = [:(Seg n),(Seg n):] by MATRIX_1:25;
A6: Indices M2 = [:(Seg n),(Seg n):] by MATRIX_1:25;
for i, j being Nat st [i,j] in Indices (M1 + M2) holds
(M1 + M2) * i,j < 0

proof

let i, j be Nat; :: thesis: ( [i,j] in Indices (M1 + M2) implies (M1 + M2) * i,j < 0 )
assume A7: [i,j] in Indices (M1 + M2) ; :: thesis: (M1 + M2) * i,j < 0
then [i,j] in Indices |:M1:| by A4, A5, Th5;
then |:M1:| * i,j < |:M2:| * i,j by A3, Def5;
then abs (M1 * i,j) < |:M2:| * i,j by A4, A5, A7, Def7;
then abs (M1 * i,j) < abs (M2 * i,j) by A6, A5, A7, Def7;
then A8: (abs (M1 * i,j)) - (abs (M2 * i,j)) < (abs (M2 * i,j)) - (abs (M2 * i,j)) by XREAL_1:11;
M2 * i,j < 0 by A2, A6, A5, A7, Def2;
then A9: - (M2 * i,j) = abs (M2 * i,j) by ABSVALUE:def 1;
M1 * i,j > 0 by A1, A4, A5, A7, Def1;
then abs (M1 * i,j) = M1 * i,j by ABSVALUE:def 1;
then (M1 * i,j) + (M2 * i,j) = (abs (M1 * i,j)) - (abs (M2 * i,j)) by A9;
hence (M1 + M2) * i,j < 0 by A4, A5, A7, A8, MATRIXR1:25; :: thesis: verum

end;

hence M1 + M2 is Negative by Def2; :: thesis: verum