let X, Y be RealNormSpace; :: thesis: for f, g being Point of (R_NormSpace_of_BoundedLinearOperators X,Y)
for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let f, g be Point of (R_NormSpace_of_BoundedLinearOperators X,Y); :: thesis: for a being Real holds
( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
let a be Real; :: thesis: ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| )
A1: now
assume A2: f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ; :: thesis: ||.f.|| = 0
thus ||.f.|| = 0 :: thesis: verum
proof
reconsider g = f as bounded LinearOperator of X,Y by Def10;
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X,the carrier of Y ;
consider r0 being set such that
A3: r0 in PreNorms g by XBOOLE_0:def 1;
reconsider r0 = r0 as Real by A3;
A4: ( ( for s being real number st s in PreNorms g holds
s <= 0 ) implies sup (PreNorms g) <= 0 ) by SEQ_4:62;
A5: ( not PreNorms g is empty & PreNorms g is bounded_above ) by Th32;
A6: z = g by A2, Th37;
A7: now
let r be Real; :: thesis: ( r in PreNorms g implies ( 0 <= r & r <= 0 ) )
assume r in PreNorms g ; :: thesis: ( 0 <= r & r <= 0 )
then consider t being VECTOR of X such that
A8: r = ||.(g . t).|| and
||.t.|| <= 1 ;
||.(g . t).|| = ||.(0. Y).|| by A6, FUNCOP_1:13
.= 0 ;
hence ( 0 <= r & r <= 0 ) by A8; :: thesis: verum
end;
then 0 <= r0 by A3;
then sup (PreNorms g) = 0 by A7, A5, A3, A4, SEQ_4:def 4;
then (BoundedLinearOperatorsNorm X,Y) . f = 0 by Th36;
hence ||.f.|| = 0 by NORMSP_1:def 1; :: thesis: verum
end;
end;
A9: ||.(f + g).|| <= ||.f.|| + ||.g.||
proof
reconsider f1 = f, g1 = g, h1 = f + g as bounded LinearOperator of X,Y by Def10;
A10: ( ( for s being real number st s in PreNorms h1 holds
s <= ||.f.|| + ||.g.|| ) implies sup (PreNorms h1) <= ||.f.|| + ||.g.|| ) by SEQ_4:62;
A11: now
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= ||.f.|| + ||.g.|| )
assume A12: ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= ||.f.|| + ||.g.||
0 <= ||.g.|| by Th39;
then A13: ||.g.|| * ||.t.|| <= ||.g.|| * 1 by A12, XREAL_1:66;
0 <= ||.f.|| by Th39;
then ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A12, XREAL_1:66;
then A14: (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) <= (||.f.|| * 1) + (||.g.|| * 1) by A13, XREAL_1:9;
A15: ||.((f1 . t) + (g1 . t)).|| <= ||.(f1 . t).|| + ||.(g1 . t).|| by NORMSP_1:def 2;
A16: ||.(g1 . t).|| <= ||.g.|| * ||.t.|| by Th38;
||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th38;
then ||.(f1 . t).|| + ||.(g1 . t).|| <= (||.f.|| * ||.t.||) + (||.g.|| * ||.t.||) by A16, XREAL_1:9;
then A17: ||.(f1 . t).|| + ||.(g1 . t).|| <= ||.f.|| + ||.g.|| by A14, XXREAL_0:2;
||.(h1 . t).|| = ||.((f1 . t) + (g1 . t)).|| by Th41;
hence ||.(h1 . t).|| <= ||.f.|| + ||.g.|| by A15, A17, XXREAL_0:2; :: thesis: verum
end;
A18: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= ||.f.|| + ||.g.|| )
assume r in PreNorms h1 ; :: thesis: r <= ||.f.|| + ||.g.||
then ex t being VECTOR of X st
( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= ||.f.|| + ||.g.|| by A11; :: thesis: verum
end;
(BoundedLinearOperatorsNorm X,Y) . (f + g) = sup (PreNorms h1) by Th36;
hence ||.(f + g).|| <= ||.f.|| + ||.g.|| by A18, A10, NORMSP_1:def 1; :: thesis: verum
end;
A19: ||.(a * f).|| = (abs a) * ||.f.||
proof
reconsider f1 = f, h1 = a * f as bounded LinearOperator of X,Y by Def10;
A20: ( ( for s being real number st s in PreNorms h1 holds
s <= (abs a) * ||.f.|| ) implies sup (PreNorms h1) <= (abs a) * ||.f.|| ) by SEQ_4:62;
A21: now
A22: 0 <= ||.f.|| by Th39;
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(h1 . t).|| <= (abs a) * ||.f.|| )
assume ||.t.|| <= 1 ; :: thesis: ||.(h1 . t).|| <= (abs a) * ||.f.||
then A23: ||.f.|| * ||.t.|| <= ||.f.|| * 1 by A22, XREAL_1:66;
||.(f1 . t).|| <= ||.f.|| * ||.t.|| by Th38;
then A24: ||.(f1 . t).|| <= ||.f.|| by A23, XXREAL_0:2;
A25: ||.(a * (f1 . t)).|| = (abs a) * ||.(f1 . t).|| by NORMSP_1:def 2;
A26: 0 <= abs a by COMPLEX1:132;
||.(h1 . t).|| = ||.(a * (f1 . t)).|| by Th42;
hence ||.(h1 . t).|| <= (abs a) * ||.f.|| by A25, A24, A26, XREAL_1:66; :: thesis: verum
end;
A27: now
let r be Real; :: thesis: ( r in PreNorms h1 implies r <= (abs a) * ||.f.|| )
assume r in PreNorms h1 ; :: thesis: r <= (abs a) * ||.f.||
then ex t being VECTOR of X st
( r = ||.(h1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= (abs a) * ||.f.|| by A21; :: thesis: verum
end;
A28: now
per cases ( a <> 0 or a = 0 ) ;
case A29: a <> 0 ; :: thesis: (abs a) * ||.f.|| <= ||.(a * f).||
A30: now
A31: 0 <= ||.(a * f).|| by Th39;
let t be VECTOR of X; :: thesis: ( ||.t.|| <= 1 implies ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).|| )
assume ||.t.|| <= 1 ; :: thesis: ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).||
then A32: ||.(a * f).|| * ||.t.|| <= ||.(a * f).|| * 1 by A31, XREAL_1:66;
||.(h1 . t).|| <= ||.(a * f).|| * ||.t.|| by Th38;
then A33: ||.(h1 . t).|| <= ||.(a * f).|| by A32, XXREAL_0:2;
h1 . t = a * (f1 . t) by Th42;
then A34: (a " ) * (h1 . t) = ((a " ) * a) * (f1 . t) by RLVECT_1:def 9
.= 1 * (f1 . t) by A29, XCMPLX_0:def 7
.= f1 . t by RLVECT_1:def 9 ;
A35: abs (a " ) = abs (1 * (a " ))
.= abs (1 / a) by XCMPLX_0:def 9
.= 1 / (abs a) by ABSVALUE:15
.= 1 * ((abs a) " ) by XCMPLX_0:def 9
.= (abs a) " ;
A36: 0 <= abs (a " ) by COMPLEX1:132;
||.((a " ) * (h1 . t)).|| = (abs (a " )) * ||.(h1 . t).|| by NORMSP_1:def 2;
hence ||.(f1 . t).|| <= ((abs a) " ) * ||.(a * f).|| by A34, A33, A36, A35, XREAL_1:66; :: thesis: verum
end;
A37: now
let r be Real; :: thesis: ( r in PreNorms f1 implies r <= ((abs a) " ) * ||.(a * f).|| )
assume r in PreNorms f1 ; :: thesis: r <= ((abs a) " ) * ||.(a * f).||
then ex t being VECTOR of X st
( r = ||.(f1 . t).|| & ||.t.|| <= 1 ) ;
hence r <= ((abs a) " ) * ||.(a * f).|| by A30; :: thesis: verum
end;
A38: ( ( for s being real number st s in PreNorms f1 holds
s <= ((abs a) " ) * ||.(a * f).|| ) implies sup (PreNorms f1) <= ((abs a) " ) * ||.(a * f).|| ) by SEQ_4:62;
A39: 0 <= abs a by COMPLEX1:132;
(BoundedLinearOperatorsNorm X,Y) . f = sup (PreNorms f1) by Th36;
then ||.f.|| <= ((abs a) " ) * ||.(a * f).|| by A37, A38, NORMSP_1:def 1;
then (abs a) * ||.f.|| <= (abs a) * (((abs a) " ) * ||.(a * f).||) by A39, XREAL_1:66;
then A40: (abs a) * ||.f.|| <= ((abs a) * ((abs a) " )) * ||.(a * f).|| ;
abs a <> 0 by A29, COMPLEX1:133;
then (abs a) * ||.f.|| <= 1 * ||.(a * f).|| by A40, XCMPLX_0:def 7;
hence (abs a) * ||.f.|| <= ||.(a * f).|| ; :: thesis: verum
end;
end;
end;
(BoundedLinearOperatorsNorm X,Y) . (a * f) = sup (PreNorms h1) by Th36;
then ||.(a * f).|| <= (abs a) * ||.f.|| by A27, A20, NORMSP_1:def 1;
hence ||.(a * f).|| = (abs a) * ||.f.|| by A28, XXREAL_0:1; :: thesis: verum
end;
now
reconsider g = f as bounded LinearOperator of X,Y by Def10;
set z = the carrier of X --> (0. Y);
reconsider z = the carrier of X --> (0. Y) as Function of the carrier of X,the carrier of Y ;
assume A43: ||.f.|| = 0 ; :: thesis: f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y)
now
let t be VECTOR of X; :: thesis: g . t = z . t
||.(g . t).|| <= ||.f.|| * ||.t.|| by Th38;
then ||.(g . t).|| = 0 by A43, NORMSP_1:8;
hence g . t = 0. Y by NORMSP_1:def 2
.= z . t by FUNCOP_1:13 ;
:: thesis: verum
end;
then g = z by FUNCT_2:113;
hence f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) by Th37; :: thesis: verum
end;
hence ( ( ||.f.|| = 0 implies f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) ) & ( f = 0. (R_NormSpace_of_BoundedLinearOperators X,Y) implies ||.f.|| = 0 ) & ||.(a * f).|| = (abs a) * ||.f.|| & ||.(f + g).|| <= ||.f.|| + ||.g.|| ) by A1, A19, A9; :: thesis: verum