let f be non constant standard clockwise_oriented special_circular_sequence; :: thesis: for G being Go-board st f is_sequence_on G holds
for i, j, k being Element of NAT st 1 <= k & k + 1 <= len f & [i,j] in Indices G & [(i + 1),j] in Indices G & f /. k = G * i,j & f /. (k + 1) = G * (i + 1),j holds
(f /. k) `2 <> S-bound (L~ f)
let G be Go-board; :: thesis: ( f is_sequence_on G implies for i, j, k being Element of NAT st 1 <= k & k + 1 <= len f & [i,j] in Indices G & [(i + 1),j] in Indices G & f /. k = G * i,j & f /. (k + 1) = G * (i + 1),j holds
(f /. k) `2 <> S-bound (L~ f) )
assume A1: f is_sequence_on G ; :: thesis: for i, j, k being Element of NAT st 1 <= k & k + 1 <= len f & [i,j] in Indices G & [(i + 1),j] in Indices G & f /. k = G * i,j & f /. (k + 1) = G * (i + 1),j holds
(f /. k) `2 <> S-bound (L~ f)
let i, j, k be Element of NAT ; :: thesis: ( 1 <= k & k + 1 <= len f & [i,j] in Indices G & [(i + 1),j] in Indices G & f /. k = G * i,j & f /. (k + 1) = G * (i + 1),j implies (f /. k) `2 <> S-bound (L~ f) )
assume that
A2: ( 1 <= k & k + 1 <= len f ) and
A3: [i,j] in Indices G and
A4: [(i + 1),j] in Indices G and
A5: f /. k = G * i,j and
A6: f /. (k + 1) = G * (i + 1),j and
A7: (f /. k) `2 = S-bound (L~ f) ; :: thesis: contradiction
A8: right_cell f,k,G = cell G,i,(j -' 1) by A1, A2, A3, A4, A5, A6, GOBRD13:25;
A9: i <= len G by A3, MATRIX_1:39;
A10: j <= width G by A3, MATRIX_1:39;
A11: i + 1 <= len G by A4, MATRIX_1:39;
set p = (1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j));
A12: 0 + 1 <= i by A3, MATRIX_1:39;
A13: 1 <= j by A3, MATRIX_1:39;
then A14: (j -' 1) + 1 = j by XREAL_1:237;

per cases ( j = 1 or j > 1 ) by A13, XXREAL_0:1;

suppose j = 1 ; :: thesis: contradiction

hence contradiction by A1, A2, A3, A4, A5, A6, Th17; :: thesis: verum

end;

suppose j > 1 ; :: thesis: contradiction

then j >= 1 + 1 by NAT_1:13;
then A15: j - 1 >= (1 + 1) - 1 by XREAL_1:11;
j < (width G) + 1 by A10, NAT_1:13;
then A16: j - 1 < ((width G) + 1) - 1 by XREAL_1:11;
i < len G by A11, NAT_1:13;
then A17: Int (cell G,i,(j -' 1)) = { |[r,s]| where r, s is Real : ( (G * i,1) `1 < r & r < (G * (i + 1),1) `1 & (G * 1,(j -' 1)) `2 < s & s < (G * 1,j) `2 ) } by A12, A14, A15, A16, GOBOARD6:29;
A18: (1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j)) in Int (right_cell f,k,G) by A12, A10, A11, A8, A14, A15, GOBOARD6:34;
then consider r, s being Real such that
A19: (1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j)) = |[r,s]| and
(G * i,1) `1 < r and
r < (G * (i + 1),1) `1 and
(G * 1,(j -' 1)) `2 < s and
A20: s < (G * 1,j) `2 by A8, A17;
((1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j))) `2 = s by A19, EUCLID:56;
then ((1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j))) `2 < S-bound (L~ f) by A5, A7, A12, A9, A13, A10, A20, GOBOARD5:2;
then A21: (1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j)) in LeftComp f by Th13;
Int (right_cell f,k,G) c= RightComp f by A1, A2, JORDAN1H:31;
then (1 / 2) * ((G * i,(j -' 1)) + (G * (i + 1),j)) in (LeftComp f) /\ (RightComp f) by A18, A21, XBOOLE_0:def 4;
then LeftComp f meets RightComp f by XBOOLE_0:def 7;
hence contradiction by GOBRD14:24; :: thesis: verum

end;

end;