let A be closed-interval Subset of REAL ; :: thesis: for n being Element of NAT st n > 0 & vol A > 0 holds
ex D being Division of A st
( len D = n & ( for i being Element of NAT st i in dom D holds
D . i = (inf A) + (((vol A) / n) * i) ) )
let n be Element of NAT ; :: thesis: ( n > 0 & vol A > 0 implies ex D being Division of A st
( len D = n & ( for i being Element of NAT st i in dom D holds
D . i = (inf A) + (((vol A) / n) * i) ) ) )
assume that
A1: n > 0 and
A2: vol A > 0 ; :: thesis: ex D being Division of A st
( len D = n & ( for i being Element of NAT st i in dom D holds
D . i = (inf A) + (((vol A) / n) * i) ) )
deffunc H₁( Nat) -> Element of REAL = (inf A) + (((vol A) / n) * $1);
consider D being FinSequence of REAL such that
A3: ( len D = n & ( for i being Nat st i in dom D holds
D . i = H₁(i) ) ) from FINSEQ_2:sch 1();
A4: for i, j being Element of NAT st i in dom D & j in dom D & i < j holds
D . i < D . j

proof

let i, j be Element of NAT ; :: thesis: ( i in dom D & j in dom D & i < j implies D . i < D . j )
assume that
A5: i in dom D and
A6: j in dom D and
A7: i < j ; :: thesis: D . i < D . j
(vol A) / n > 0 by A1, A2, XREAL_1:141;
then ((vol A) / n) * i < ((vol A) / n) * j by A7, XREAL_1:70;
then (inf A) + (((vol A) / n) * i) < (inf A) + (((vol A) / n) * j) by XREAL_1:8;
then D . i < (inf A) + (((vol A) / n) * j) by A3, A5;
hence D . i < D . j by A3, A6; :: thesis: verum

end;

A8: dom D = Seg n by A3, FINSEQ_1:def 3;
reconsider D = D as non empty increasing FinSequence of REAL by A1, A3, A4, SEQM_3:def 1;
D . (len D) = (inf A) + (((vol A) / n) * n) by A3, A8, FINSEQ_1:5;
then A9: D . (len D) = (inf A) + (vol A) by A1, XCMPLX_1:88;
for x1 being set st x1 in rng D holds
x1 in A

proof

let x1 be set ; :: thesis: ( x1 in rng D implies x1 in A )
assume x1 in rng D ; :: thesis: x1 in A
then consider i being Element of NAT such that
A10: i in dom D and
A11: D . i = x1 by PARTFUN1:26;
A12: 1 <= i by A10, FINSEQ_3:27;
i <= len D by A10, FINSEQ_3:27;
then ((vol A) / n) * i <= ((vol A) / n) * n by A2, A3, XREAL_1:66;
then ((vol A) / n) * i <= vol A by A1, XCMPLX_1:88;
then A13: (inf A) + (((vol A) / n) * i) <= (inf A) + (vol A) by XREAL_1:8;
(vol A) / n > 0 by A1, A2, XREAL_1:141;
then A14: inf A <= (inf A) + (((vol A) / n) * i) by A12, XREAL_1:31, XREAL_1:131;
x1 = (inf A) + (((vol A) / n) * i) by A3, A10, A11;
hence x1 in A by A14, A13, INTEGRA2:1; :: thesis: verum

end;

then rng D c= A by TARSKI:def 3;
then reconsider D = D as Division of A by A9, INTEGRA1:def 2;
take D ; :: thesis: ( len D = n & ( for i being Element of NAT st i in dom D holds
D . i = (inf A) + (((vol A) / n) * i) ) )
thus ( len D = n & ( for i being Element of NAT st i in dom D holds
D . i = (inf A) + (((vol A) / n) * i) ) ) by A3; :: thesis: verum