let A be closed-interval Subset of REAL ; :: thesis: for f1, f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = (exp_R (#) arctan ) + (exp_R / (f1 + (#Z 2))) holds
integral f,A = ((exp_R (#) arctan ) . (sup A)) - ((exp_R (#) arctan ) . (inf A))
let f1, f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = (exp_R (#) arctan ) + (exp_R / (f1 + (#Z 2))) holds
integral f,A = ((exp_R (#) arctan ) . (sup A)) - ((exp_R (#) arctan ) . (inf A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = (exp_R (#) arctan ) + (exp_R / (f1 + (#Z 2))) implies integral f,A = ((exp_R (#) arctan ) . (sup A)) - ((exp_R (#) arctan ) . (inf A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = (exp_R (#) arctan ) + (exp_R / (f1 + (#Z 2))) ) ; :: thesis: integral f,A = ((exp_R (#) arctan ) . (sup A)) - ((exp_R (#) arctan ) . (inf A))
A3: Z = (dom (exp_R (#) arctan )) /\ (dom (exp_R / (f1 + (#Z 2)))) by VALUED_1:def 1, A1;
A5: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
A6: exp_R (#) arctan is_differentiable_on Z by A1, SIN_COS9:123;
A7: Z c= dom (exp_R / (f1 + (#Z 2))) by XBOOLE_1:18, A3;
A8: Z c= dom (exp_R (#) ((f1 + (#Z 2)) ^ )) by A7, RFUNCT_1:47;
Z c= (dom exp_R ) /\ (dom ((f1 + (#Z 2)) ^ )) by A8, VALUED_1:def 4;
then A9: Z c= dom ((f1 + (#Z 2)) ^ ) by XBOOLE_1:18;
dom ((f1 + (#Z 2)) ^ ) c= dom (f1 + (#Z 2)) by RFUNCT_1:11;
then AA: Z c= dom (f1 + (#Z 2)) by XBOOLE_1:1, A9;
A10: (f1 + (#Z 2)) ^ is_differentiable_on Z by A1, A9, Th1;
A11: exp_R (#) ((f1 + (#Z 2)) ^ ) is_differentiable_on Z by A5, A10, A8, FDIFF_1:29;
A12: exp_R / (f1 + (#Z 2)) is_differentiable_on Z by A11, RFUNCT_1:47;
f | Z is continuous by FDIFF_1:33, A1, A6, A12, FDIFF_1:26;
then A14: f | A is continuous by A1, FCONT_1:17;
A15: ( f is_integrable_on A & f | A is bounded ) by A1, A14, INTEGRA5:10, INTEGRA5:11;
B1: for x being Real st x in Z holds
f . x = ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 )))

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 ))) )
assume B2: x in Z ; :: thesis: f . x = ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 )))
((exp_R (#) arctan ) + (exp_R / (f1 + (#Z 2)))) . x = ((exp_R (#) arctan ) . x) + ((exp_R / (f1 + (#Z 2))) . x) by VALUED_1:def 1, A1, B2
.= ((exp_R . x) * (arctan . x)) + ((exp_R / (f1 + (#Z 2))) . x) by VALUED_1:5
.= ((exp_R . x) * (arctan . x)) + ((exp_R . x) / ((f1 + (#Z 2)) . x)) by RFUNCT_1:def 4, A7, B2
.= ((exp_R . x) * (arctan . x)) + ((exp_R . x) / ((f1 . x) + ((#Z 2) . x))) by VALUED_1:def 1, AA, B2
.= ((exp_R . x) * (arctan . x)) + ((exp_R . x) / ((f1 . x) + (x #Z 2))) by TAYLOR_1:def 1
.= ((exp_R . x) * (arctan . x)) + ((exp_R . x) / ((f1 . x) + (x ^2 ))) by FDIFF_7:1
.= ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 ))) by A1, B2 ;
hence f . x = ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 ))) by A1; :: thesis: verum

end;

A16: for x being Real st x in dom ((exp_R (#) arctan ) `| Z) holds
((exp_R (#) arctan ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((exp_R (#) arctan ) `| Z) implies ((exp_R (#) arctan ) `| Z) . x = f . x )
assume x in dom ((exp_R (#) arctan ) `| Z) ; :: thesis: ((exp_R (#) arctan ) `| Z) . x = f . x
then A17: x in Z by A6, FDIFF_1:def 8;
then ((exp_R (#) arctan ) `| Z) . x = ((exp_R . x) * (arctan . x)) + ((exp_R . x) / (1 + (x ^2 ))) by A1, SIN_COS9:123
.= f . x by A17, B1 ;
hence ((exp_R (#) arctan ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R (#) arctan ) `| Z) = dom f by A1, A6, FDIFF_1:def 8;
then (exp_R (#) arctan ) `| Z = f by A16, PARTFUN1:34;
hence integral f,A = ((exp_R (#) arctan ) . (sup A)) - ((exp_R (#) arctan ) . (inf A)) by A1, A15, SIN_COS9:123, INTEGRA5:13; :: thesis: verum