let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R (#) (cos / sin )) - (exp_R / (sin ^2 )) holds
integral f,A = ((exp_R (#) cot ) . (sup A)) - ((exp_R (#) cot ) . (inf A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R (#) (cos / sin )) - (exp_R / (sin ^2 )) holds
integral f,A = ((exp_R (#) cot ) . (sup A)) - ((exp_R (#) cot ) . (inf A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & Z = dom f & f = (exp_R (#) (cos / sin )) - (exp_R / (sin ^2 )) implies integral f,A = ((exp_R (#) cot ) . (sup A)) - ((exp_R (#) cot ) . (inf A)) )
assume A1: ( A c= Z & Z = dom f & f = (exp_R (#) (cos / sin )) - (exp_R / (sin ^2 )) ) ; :: thesis: integral f,A = ((exp_R (#) cot ) . (sup A)) - ((exp_R (#) cot ) . (inf A))
A3: Z = (dom (exp_R (#) (cos / sin ))) /\ (dom (exp_R / (sin ^2 ))) by A1, VALUED_1:12;
A4: ( Z c= dom (exp_R (#) (cos / sin )) & Z c= dom (exp_R / (sin ^2 )) ) by XBOOLE_1:18, A3;
A5: dom (exp_R (#) (cos / sin )) c= (dom exp_R ) /\ (dom (cos / sin )) by VALUED_1:def 4;
A6: dom (exp_R / (sin ^2 )) c= (dom exp_R ) /\ ((dom (sin ^2 )) \ ((sin ^2 ) " {0 })) by RFUNCT_1:def 4;
( dom (exp_R (#) (cos / sin )) c= dom exp_R & dom (exp_R (#) (cos / sin )) c= dom (cos / sin ) & dom (exp_R / (sin ^2 )) c= (dom (sin ^2 )) \ ((sin ^2 ) " {0 }) ) by XBOOLE_1:18, A5, A6;
then A7: ( Z c= dom exp_R & Z c= dom (cos / sin ) & Z c= (dom (sin ^2 )) \ ((sin ^2 ) " {0 }) ) by XBOOLE_1:1, A4;
A9: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
A10: for x being Real st x in Z holds
cos / sin is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cos / sin is_differentiable_in x )
assume x in Z ; :: thesis: cos / sin is_differentiable_in x
then sin . x <> 0 by A7, FDIFF_8:2;
hence cos / sin is_differentiable_in x by FDIFF_7:47; :: thesis: verum

end;

A11: cos / sin is_differentiable_on Z by A7, A10, FDIFF_1:16;
A12: exp_R (#) (cos / sin ) is_differentiable_on Z by A4, A9, A11, FDIFF_1:29;
A13: sin is_differentiable_on Z by FDIFF_1:34, SIN_COS:73;
A14: sin ^2 is_differentiable_on Z by FDIFF_2:20, A13;
A15: for x being Real st x in Z holds
(sin ^2 ) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies (sin ^2 ) . x <> 0 )
assume x in Z ; :: thesis: (sin ^2 ) . x <> 0
then x in dom (exp_R / (sin ^2 )) by A4;
then x in (dom exp_R ) /\ ((dom (sin ^2 )) \ ((sin ^2 ) " {0 })) by RFUNCT_1:def 4;
then x in (dom (sin ^2 )) \ ((sin ^2 ) " {0 }) by XBOOLE_0:def 4;
then x in dom ((sin ^2 ) ^ ) by RFUNCT_1:def 8;
hence (sin ^2 ) . x <> 0 by RFUNCT_1:13; :: thesis: verum

end;

A16: exp_R / (sin ^2 ) is_differentiable_on Z by A9, A14, A15, FDIFF_2:21;
f | Z is continuous by FDIFF_1:33, FDIFF_1:27, A1, A12, A16;
then A18: f | A is continuous by A1, FCONT_1:17;
A19: ( f is_integrable_on A & f | A is bounded ) by A1, A18, INTEGRA5:10, INTEGRA5:11;
A20: exp_R (#) cot is_differentiable_on Z by A4, FDIFF_8:31;
B1: for x being Real st x in Z holds
f . x = (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 )) )
assume B2: x in Z ; :: thesis: f . x = (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 ))
((exp_R (#) (cos / sin )) - (exp_R / (sin ^2 ))) . x = ((exp_R (#) (cos / sin )) . x) - ((exp_R / (sin ^2 )) . x) by VALUED_1:13, B2, A1
.= ((exp_R . x) * ((cos / sin ) . x)) - ((exp_R / (sin ^2 )) . x) by VALUED_1:5
.= ((exp_R . x) * ((cos . x) * ((sin . x) " ))) - ((exp_R / (sin ^2 )) . x) by RFUNCT_1:def 4, A7, B2
.= (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin ^2 ) . x)) by RFUNCT_1:def 4, A4, B2
.= (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 )) by VALUED_1:11 ;
hence f . x = (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 )) by A1; :: thesis: verum

end;

A21: for x being Real st x in dom ((exp_R (#) cot ) `| Z) holds
((exp_R (#) cot ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((exp_R (#) cot ) `| Z) implies ((exp_R (#) cot ) `| Z) . x = f . x )
assume x in dom ((exp_R (#) cot ) `| Z) ; :: thesis: ((exp_R (#) cot ) `| Z) . x = f . x
then A22: x in Z by A20, FDIFF_1:def 8;
then ((exp_R (#) cot ) `| Z) . x = (((exp_R . x) * (cos . x)) / (sin . x)) - ((exp_R . x) / ((sin . x) ^2 )) by A4, FDIFF_8:31
.= f . x by A22, B1 ;
hence ((exp_R (#) cot ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R (#) cot ) `| Z) = dom f by A1, A20, FDIFF_1:def 8;
then (exp_R (#) cot ) `| Z = f by A21, PARTFUN1:34;
hence integral f,A = ((exp_R (#) cot ) . (sup A)) - ((exp_R (#) cot ) . (inf A)) by A1, A19, A4, FDIFF_8:31, INTEGRA5:13; :: thesis: verum