let A be closed-interval Subset of REAL ; :: thesis: for f1, f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arccot * exp_R ) & Z = dom f & f = (- exp_R ) / (f1 + (exp_R ^2 )) holds
integral f,A = ((arccot * exp_R ) . (sup A)) - ((arccot * exp_R ) . (inf A))
let f1, f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arccot * exp_R ) & Z = dom f & f = (- exp_R ) / (f1 + (exp_R ^2 )) holds
integral f,A = ((arccot * exp_R ) . (sup A)) - ((arccot * exp_R ) . (inf A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arccot * exp_R ) & Z = dom f & f = (- exp_R ) / (f1 + (exp_R ^2 )) implies integral f,A = ((arccot * exp_R ) . (sup A)) - ((arccot * exp_R ) . (inf A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arccot * exp_R ) & Z = dom f & f = (- exp_R ) / (f1 + (exp_R ^2 )) ) ; :: thesis: integral f,A = ((arccot * exp_R ) . (sup A)) - ((arccot * exp_R ) . (inf A))
A3: Z c= (dom (- exp_R )) /\ ((dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 })) by A1, RFUNCT_1:def 4;
A4: ( Z c= dom (- exp_R ) & Z c= (dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 }) ) by XBOOLE_1:18, A3;
A5: Z c= dom ((f1 + (exp_R ^2 )) ^ ) by RFUNCT_1:def 8, A4;
dom ((f1 + (exp_R ^2 )) ^ ) c= dom (f1 + (exp_R ^2 )) by RFUNCT_1:11;
then A6: Z c= dom (f1 + (exp_R ^2 )) by XBOOLE_1:1, A5;
A7: Z c= (dom f1) /\ (dom (exp_R ^2 )) by VALUED_1:def 1, A6;
A8: ( Z c= dom f1 & Z c= dom (exp_R ^2 ) ) by XBOOLE_1:18, A7;
A9: Z c= dom (exp_R (#) exp_R ) by XBOOLE_1:18, A7;
A10: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
A11: (- 1) (#) exp_R is_differentiable_on Z by A4, A10, FDIFF_1:28, X;
A12: exp_R (#) exp_R is_differentiable_on Z by A9, A10, FDIFF_1:29;
A14: for x being Real st x in Z holds
f1 . x = (0 * x) + 1 by A1;
A15: f1 is_differentiable_on Z by FDIFF_1:31, A8, A14;
A16: f1 + (exp_R ^2 ) is_differentiable_on Z by A6, A12, A15, FDIFF_1:26;
A17: for x being Real st x in Z holds
(f1 + (exp_R ^2 )) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 + (exp_R ^2 )) . x <> 0 )
assume x in Z ; :: thesis: (f1 + (exp_R ^2 )) . x <> 0
then x in (dom (- exp_R )) /\ ((dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 })) by RFUNCT_1:def 4, A1;
then x in (dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 }) by XBOOLE_0:def 4;
then x in dom ((f1 + (exp_R ^2 )) ^ ) by RFUNCT_1:def 8;
hence (f1 + (exp_R ^2 )) . x <> 0 by RFUNCT_1:13; :: thesis: verum

end;

A18: f is_differentiable_on Z by A1, A11, A16, A17, FDIFF_2:21;
A19: f | Z is continuous by FDIFF_1:33, A18;
A20: f | A is continuous by A1, A19, FCONT_1:17;
A21: ( f is_integrable_on A & f | A is bounded ) by A1, A20, INTEGRA5:10, INTEGRA5:11;
A22: for x being Real st x in Z holds
exp_R . x < 1 by A1;
then A23: arccot * exp_R is_differentiable_on Z by A1, SIN_COS9:116;
B1: for x being Real st x in Z holds
f . x = - ((exp_R . x) / (1 + ((exp_R . x) ^2 )))

proof

let x be Real; :: thesis: ( x in Z implies f . x = - ((exp_R . x) / (1 + ((exp_R . x) ^2 ))) )
assume B2: x in Z ; :: thesis: f . x = - ((exp_R . x) / (1 + ((exp_R . x) ^2 )))
((- exp_R ) / (f1 + (exp_R ^2 ))) . x = ((- exp_R ) . x) * (((f1 + (exp_R ^2 )) . x) " ) by RFUNCT_1:def 4, A1, B2
.= (- (exp_R . x)) * (((f1 + (exp_R ^2 )) . x) " ) by RFUNCT_1:74
.= (- (exp_R . x)) * (((f1 . x) + ((exp_R ^2 ) . x)) " ) by VALUED_1:def 1, B2, A6
.= (- (exp_R . x)) * (((f1 . x) + ((exp_R . x) ^2 )) " ) by VALUED_1:11
.= (- (exp_R . x)) / (1 + ((exp_R . x) ^2 )) by A1, B2
.= - ((exp_R . x) / (1 + ((exp_R . x) ^2 ))) ;
hence f . x = - ((exp_R . x) / (1 + ((exp_R . x) ^2 ))) by A1; :: thesis: verum

end;

A24: for x being Real st x in dom ((arccot * exp_R ) `| Z) holds
((arccot * exp_R ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((arccot * exp_R ) `| Z) implies ((arccot * exp_R ) `| Z) . x = f . x )
assume x in dom ((arccot * exp_R ) `| Z) ; :: thesis: ((arccot * exp_R ) `| Z) . x = f . x
then A25: x in Z by A23, FDIFF_1:def 8;
((arccot * exp_R ) `| Z) . x = - ((exp_R . x) / (1 + ((exp_R . x) ^2 ))) by A1, A22, SIN_COS9:116, A25
.= f . x by A25, B1 ;
hence ((arccot * exp_R ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((arccot * exp_R ) `| Z) = dom f by A1, A23, FDIFF_1:def 8;
then (arccot * exp_R ) `| Z = f by A24, PARTFUN1:34;
hence integral f,A = ((arccot * exp_R ) . (sup A)) - ((arccot * exp_R ) . (inf A)) by A1, A21, A23, INTEGRA5:13; :: thesis: verum