let A be closed-interval Subset of REAL ; :: thesis: for f1, f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arctan * exp_R ) & Z = dom f & f = exp_R / (f1 + (exp_R ^2 )) holds
integral f,A = ((arctan * exp_R ) . (sup A)) - ((arctan * exp_R ) . (inf A))
let f1, f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arctan * exp_R ) & Z = dom f & f = exp_R / (f1 + (exp_R ^2 )) holds
integral f,A = ((arctan * exp_R ) . (sup A)) - ((arctan * exp_R ) . (inf A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arctan * exp_R ) & Z = dom f & f = exp_R / (f1 + (exp_R ^2 )) implies integral f,A = ((arctan * exp_R ) . (sup A)) - ((arctan * exp_R ) . (inf A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
( exp_R . x < 1 & f1 . x = 1 ) ) & Z c= dom (arctan * exp_R ) & Z = dom f & f = exp_R / (f1 + (exp_R ^2 )) ) ; :: thesis: integral f,A = ((arctan * exp_R ) . (sup A)) - ((arctan * exp_R ) . (inf A))
A3: Z c= (dom exp_R ) /\ ((dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 })) by A1, RFUNCT_1:def 4;
A4: ( Z c= dom exp_R & Z c= (dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 }) ) by XBOOLE_1:18, A3;
A5: Z c= dom ((f1 + (exp_R ^2 )) ^ ) by RFUNCT_1:def 8, A4;
dom ((f1 + (exp_R ^2 )) ^ ) c= dom (f1 + (exp_R ^2 )) by RFUNCT_1:11;
then A6: Z c= dom (f1 + (exp_R ^2 )) by XBOOLE_1:1, A5;
B1: Z c= (dom f1) /\ (dom (exp_R ^2 )) by VALUED_1:def 1, A6;
B2: ( Z c= dom f1 & Z c= dom (exp_R ^2 ) ) by XBOOLE_1:18, B1;
A7: Z c= dom (exp_R (#) exp_R ) by XBOOLE_1:18, B1;
A8: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
A9: exp_R (#) exp_R is_differentiable_on Z by A7, A8, FDIFF_1:29;
A11: for x being Real st x in Z holds
f1 . x = (0 * x) + 1 by A1;
A12: f1 is_differentiable_on Z by FDIFF_1:31, B2, A11;
A13: f1 + (exp_R ^2 ) is_differentiable_on Z by A6, A9, A12, FDIFF_1:26;
A14: for x being Real st x in Z holds
(f1 + (exp_R ^2 )) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 + (exp_R ^2 )) . x <> 0 )
assume x in Z ; :: thesis: (f1 + (exp_R ^2 )) . x <> 0
then x in (dom exp_R ) /\ ((dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 })) by A1, RFUNCT_1:def 4;
then x in (dom (f1 + (exp_R ^2 ))) \ ((f1 + (exp_R ^2 )) " {0 }) by XBOOLE_0:def 4;
then x in dom ((f1 + (exp_R ^2 )) ^ ) by RFUNCT_1:def 8;
hence (f1 + (exp_R ^2 )) . x <> 0 by RFUNCT_1:13; :: thesis: verum

end;

A15: f is_differentiable_on Z by A1, A8, A13, A14, FDIFF_2:21;
A16: f | Z is continuous by FDIFF_1:33, A15;
A17: f | A is continuous by A1, A16, FCONT_1:17;
A18: ( f is_integrable_on A & f | A is bounded ) by A1, A17, INTEGRA5:10, INTEGRA5:11;
A19: for x being Real st x in Z holds
exp_R . x < 1 by A1;
then A20: arctan * exp_R is_differentiable_on Z by A1, SIN_COS9:115;
B3: for x being Real st x in Z holds
f . x = (exp_R . x) / (1 + ((exp_R . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . x) / (1 + ((exp_R . x) ^2 )) )
assume B4: x in Z ; :: thesis: f . x = (exp_R . x) / (1 + ((exp_R . x) ^2 ))
(exp_R / (f1 + (exp_R ^2 ))) . x = (exp_R . x) * (((f1 + (exp_R ^2 )) . x) " ) by RFUNCT_1:def 4, A1, B4
.= (exp_R . x) * (((f1 . x) + ((exp_R ^2 ) . x)) " ) by VALUED_1:def 1, B4, A6
.= (exp_R . x) * (((f1 . x) + ((exp_R . x) ^2 )) " ) by VALUED_1:11
.= (exp_R . x) / (1 + ((exp_R . x) ^2 )) by A1, B4 ;
hence f . x = (exp_R . x) / (1 + ((exp_R . x) ^2 )) by A1; :: thesis: verum

end;

A21: for x being Real st x in dom ((arctan * exp_R ) `| Z) holds
((arctan * exp_R ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((arctan * exp_R ) `| Z) implies ((arctan * exp_R ) `| Z) . x = f . x )
assume x in dom ((arctan * exp_R ) `| Z) ; :: thesis: ((arctan * exp_R ) `| Z) . x = f . x
then A22: x in Z by A20, FDIFF_1:def 8;
then ((arctan * exp_R ) `| Z) . x = (exp_R . x) / (1 + ((exp_R . x) ^2 )) by A1, A19, SIN_COS9:115
.= f . x by A22, B3 ;
hence ((arctan * exp_R ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((arctan * exp_R ) `| Z) = dom f by A1, A20, FDIFF_1:def 8;
then (arctan * exp_R ) `| Z = f by A21, PARTFUN1:34;
hence integral f,A = ((arctan * exp_R ) . (sup A)) - ((arctan * exp_R ) . (inf A)) by A1, A18, A20, INTEGRA5:13; :: thesis: verum