let n be Element of NAT ; :: thesis: for A being closed-interval Subset of REAL
for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos ) & 1 <= n & Z c= dom ((#Z n) * tan ) & Z = dom f holds
integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A))
let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos ) & 1 <= n & Z c= dom ((#Z n) * tan ) & Z = dom f holds
integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos ) & 1 <= n & Z c= dom ((#Z n) * tan ) & Z = dom f holds
integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & f = (n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos ) & 1 <= n & Z c= dom ((#Z n) * tan ) & Z = dom f implies integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A)) )
assume A1: ( A c= Z & f = (n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos ) & 1 <= n & Z c= dom ((#Z n) * tan ) & Z = dom f ) ; :: thesis: integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A))
A2: Z = (dom (n (#) ((#Z (n - 1)) * sin ))) /\ ((dom ((#Z (n + 1)) * cos )) \ (((#Z (n + 1)) * cos ) " {0 })) by A1, RFUNCT_1:def 4;
A3: ( Z c= dom (n (#) ((#Z (n - 1)) * sin )) & Z c= (dom ((#Z (n + 1)) * cos )) \ (((#Z (n + 1)) * cos ) " {0 }) ) by A2, XBOOLE_1:18;
A4: Z c= dom (((#Z (n + 1)) * cos ) ^ ) by A3, RFUNCT_1:def 8;
dom (((#Z (n + 1)) * cos ) ^ ) c= dom ((#Z (n + 1)) * cos ) by RFUNCT_1:11;
then A5: Z c= dom ((#Z (n + 1)) * cos ) by A4, XBOOLE_1:1;
A6: for x being Real st x in Z holds
((#Z (n + 1)) * cos ) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies ((#Z (n + 1)) * cos ) . x <> 0 )
assume A7: x in Z ; :: thesis: ((#Z (n + 1)) * cos ) . x <> 0
x in (dom (n (#) ((#Z (n - 1)) * sin ))) /\ ((dom ((#Z (n + 1)) * cos )) \ (((#Z (n + 1)) * cos ) " {0 })) by A1, A7, RFUNCT_1:def 4;
then x in (dom ((#Z (n + 1)) * cos )) \ (((#Z (n + 1)) * cos ) " {0 }) by XBOOLE_0:def 4;
then x in dom (((#Z (n + 1)) * cos ) ^ ) by RFUNCT_1:def 8;
hence ((#Z (n + 1)) * cos ) . x <> 0 by RFUNCT_1:13; :: thesis: verum

end;

A9: Z c= dom ((#Z (n - 1)) * sin ) by VALUED_1:def 5, A3;
A10: for x being Real holds (#Z (n - 1)) * sin is_differentiable_in x

proof

let x be Real; :: thesis: (#Z (n - 1)) * sin is_differentiable_in x
consider m being Nat such that
A11: n = m + 1 by A1, NAT_1:6;
set m = n - 1;
sin is_differentiable_in x by SIN_COS:69;
hence (#Z (n - 1)) * sin is_differentiable_in x by A11, TAYLOR_1:3; :: thesis: verum

end;

A14: (#Z (n - 1)) * sin is_differentiable_on Z

proof

for x being Real st x in Z holds
(#Z (n - 1)) * sin is_differentiable_in x by A10;
hence (#Z (n - 1)) * sin is_differentiable_on Z by A9, FDIFF_1:16; :: thesis: verum

end;

A15: n (#) ((#Z (n - 1)) * sin ) is_differentiable_on Z by A3, A14, FDIFF_1:28;
A16: for x being Real holds (#Z (n + 1)) * cos is_differentiable_in x

proof

let x be Real; :: thesis: (#Z (n + 1)) * cos is_differentiable_in x
set m = n + 1;
cos is_differentiable_in x by SIN_COS:68;
hence (#Z (n + 1)) * cos is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

A18: (#Z (n + 1)) * cos is_differentiable_on Z

proof

for x being Real st x in Z holds
(#Z (n + 1)) * cos is_differentiable_in x by A16;
hence (#Z (n + 1)) * cos is_differentiable_on Z by A5, FDIFF_1:16; :: thesis: verum

end;

A20: f | Z is continuous by FDIFF_1:33, A1, A6, A15, A18, FDIFF_2:21;
A21: f | A is continuous by A1, A20, FCONT_1:17;
A22: ( f is_integrable_on A & f | A is bounded ) by A1, A21, INTEGRA5:10, INTEGRA5:11;
A23: (#Z n) * tan is_differentiable_on Z by A1, FDIFF_8:20;
B1: for x being Real st x in Z holds
f . x = (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1)) )
assume B2: x in Z ; :: thesis: f . x = (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1))
((n (#) ((#Z (n - 1)) * sin )) / ((#Z (n + 1)) * cos )) . x = ((n (#) ((#Z (n - 1)) * sin )) . x) / (((#Z (n + 1)) * cos ) . x) by RFUNCT_1:def 4, A1, B2
.= (n * (((#Z (n - 1)) * sin ) . x)) / (((#Z (n + 1)) * cos ) . x) by VALUED_1:6
.= (n * ((#Z (n - 1)) . (sin . x))) / (((#Z (n + 1)) * cos ) . x) by FUNCT_1:22, A9, B2
.= (n * ((sin . x) #Z (n - 1))) / (((#Z (n + 1)) * cos ) . x) by TAYLOR_1:def 1
.= (n * ((sin . x) #Z (n - 1))) / ((#Z (n + 1)) . (cos . x)) by FUNCT_1:22, A5, B2
.= (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1)) by TAYLOR_1:def 1 ;
hence f . x = (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1)) by A1; :: thesis: verum

end;

A24: for x being Real st x in dom (((#Z n) * tan ) `| Z) holds
(((#Z n) * tan ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom (((#Z n) * tan ) `| Z) implies (((#Z n) * tan ) `| Z) . x = f . x )
assume x in dom (((#Z n) * tan ) `| Z) ; :: thesis: (((#Z n) * tan ) `| Z) . x = f . x
then A25: x in Z by A23, FDIFF_1:def 8;
then (((#Z n) * tan ) `| Z) . x = (n * ((sin . x) #Z (n - 1))) / ((cos . x) #Z (n + 1)) by A1, FDIFF_8:20
.= f . x by B1, A25 ;
hence (((#Z n) * tan ) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((#Z n) * tan ) `| Z) = dom f by A1, A23, FDIFF_1:def 8;
then ((#Z n) * tan ) `| Z = f by A24, PARTFUN1:34;
hence integral f,A = (((#Z n) * tan ) . (sup A)) - (((#Z n) * tan ) . (inf A)) by A1, A22, FDIFF_8:20, INTEGRA5:13; :: thesis: verum