let Z be open Subset of REAL ; :: thesis: for f, f1 being PartFunc of REAL ,REAL st Z c= dom f & f = ln * (((#Z 2) * (exp_R + f1)) / exp_R ) & ( for x being Real st x in Z holds
f1 . x = 1 ) holds
( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) ) )
let f, f1 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom f & f = ln * (((#Z 2) * (exp_R + f1)) / exp_R ) & ( for x being Real st x in Z holds
f1 . x = 1 ) implies ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) ) ) )
assume that
A1: Z c= dom f and
A2: f = ln * (((#Z 2) * (exp_R + f1)) / exp_R ) and
A3: for x being Real st x in Z holds
f1 . x = 1 ; :: thesis: ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) ) )
for y being set st y in Z holds
y in dom (((#Z 2) * (exp_R + f1)) / exp_R ) by A1, A2, FUNCT_1:21;
then A4: Z c= dom (((#Z 2) * (exp_R + f1)) / exp_R ) by TARSKI:def 3;
then Z c= (dom ((#Z 2) * (exp_R + f1))) /\ ((dom exp_R ) \ (exp_R " {0 })) by RFUNCT_1:def 4;
then A5: Z c= dom ((#Z 2) * (exp_R + f1)) by XBOOLE_1:18;
then A6: (#Z 2) * (exp_R + f1) is_differentiable_on Z by A3, Th29;
for y being set st y in Z holds
y in dom (exp_R + f1) by A5, FUNCT_1:21;
then A7: Z c= dom (exp_R + f1) by TARSKI:def 3;
A8: for x being Real st x in Z holds
(((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0 )
A9: exp_R . x > 0 by SIN_COS:59;
assume A10: x in Z ; :: thesis: (((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0
then (exp_R + f1) . x = (exp_R . x) + (f1 . x) by A7, VALUED_1:def 1
.= (exp_R . x) + 1 by A3, A10 ;
then (exp_R + f1) . x > 0 by SIN_COS:59, XREAL_1:36;
then A11: ((exp_R + f1) . x) #Z 2 > 0 by PREPOWER:49;
(((#Z 2) * (exp_R + f1)) / exp_R ) . x = (((#Z 2) * (exp_R + f1)) . x) * ((exp_R . x) " ) by A4, A10, RFUNCT_1:def 4
.= (((#Z 2) * (exp_R + f1)) . x) * (1 / (exp_R . x)) by XCMPLX_1:217
.= (((#Z 2) * (exp_R + f1)) . x) / (exp_R . x) by XCMPLX_1:100
.= ((#Z 2) . ((exp_R + f1) . x)) / (exp_R . x) by A5, A10, FUNCT_1:22
.= (((exp_R + f1) . x) #Z 2) / (exp_R . x) by TAYLOR_1:def 1 ;
hence (((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0 by A11, A9, XREAL_1:141; :: thesis: verum

end;

( exp_R is_differentiable_on Z & ( for x being Real st x in Z holds
exp_R . x <> 0 ) ) by FDIFF_1:34, SIN_COS:59, TAYLOR_1:16;
then A12: ((#Z 2) * (exp_R + f1)) / exp_R is_differentiable_on Z by A6, FDIFF_2:21;
A13: for x being Real st x in Z holds
ln * (((#Z 2) * (exp_R + f1)) / exp_R ) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * (((#Z 2) * (exp_R + f1)) / exp_R ) is_differentiable_in x )
assume x in Z ; :: thesis: ln * (((#Z 2) * (exp_R + f1)) / exp_R ) is_differentiable_in x
then ( ((#Z 2) * (exp_R + f1)) / exp_R is_differentiable_in x & (((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0 ) by A12, A8, FDIFF_1:16;
hence ln * (((#Z 2) * (exp_R + f1)) / exp_R ) is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A14: f is_differentiable_on Z by A1, A2, FDIFF_1:16;
for x being Real st x in Z holds
(f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1)

proof

let x be Real; :: thesis: ( x in Z implies (f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) )
A15: exp_R . x > 0 by SIN_COS:59;
A16: exp_R is_differentiable_in x by SIN_COS:70;
A17: (exp_R . x) + 1 > 0 by SIN_COS:59, XREAL_1:36;
assume A18: x in Z ; :: thesis: (f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1)
then A19: (exp_R + f1) . x = (exp_R . x) + (f1 . x) by A7, VALUED_1:def 1
.= (exp_R . x) + 1 by A3, A18 ;
A20: ((#Z 2) * (exp_R + f1)) . x = (#Z 2) . ((exp_R + f1) . x) by A5, A18, FUNCT_1:22
.= ((exp_R . x) + 1) #Z (1 + 1) by A19, TAYLOR_1:def 1
.= (((exp_R . x) + 1) #Z 1) * (((exp_R . x) + 1) #Z 1) by A17, PREPOWER:54
.= ((exp_R . x) + 1) * (((exp_R . x) + 1) #Z 1) by PREPOWER:45
.= ((exp_R . x) + 1) * ((exp_R . x) + 1) by PREPOWER:45 ;
A21: ( ((#Z 2) * (exp_R + f1)) / exp_R is_differentiable_in x & (((#Z 2) * (exp_R + f1)) / exp_R ) . x > 0 ) by A12, A8, A18, FDIFF_1:16;
(#Z 2) * (exp_R + f1) is_differentiable_in x by A6, A18, FDIFF_1:16;
then A22: diff (((#Z 2) * (exp_R + f1)) / exp_R ),x = (((diff ((#Z 2) * (exp_R + f1)),x) * (exp_R . x)) - ((diff exp_R ,x) * (((#Z 2) * (exp_R + f1)) . x))) / ((exp_R . x) ^2 ) by A15, A16, FDIFF_2:14
.= ((((((#Z 2) * (exp_R + f1)) `| Z) . x) * (exp_R . x)) - ((diff exp_R ,x) * (((#Z 2) * (exp_R + f1)) . x))) / ((exp_R . x) ^2 ) by A6, A18, FDIFF_1:def 8
.= ((((2 * (exp_R . x)) * ((exp_R . x) + 1)) * (exp_R . x)) - ((diff exp_R ,x) * (((#Z 2) * (exp_R + f1)) . x))) / ((exp_R . x) ^2 ) by A3, A5, A18, Th29
.= ((((2 * (exp_R . x)) * ((exp_R . x) + 1)) * (exp_R . x)) - ((exp_R . x) * (((#Z 2) * (exp_R + f1)) . x))) / ((exp_R . x) ^2 ) by SIN_COS:70
.= ((((2 * (exp_R . x)) * ((exp_R . x) + 1)) - (((#Z 2) * (exp_R + f1)) . x)) * (exp_R . x)) / ((exp_R . x) * (exp_R . x))
.= (((exp_R . x) - 1) * ((exp_R . x) + 1)) / (exp_R . x) by A15, A20, XCMPLX_1:92 ;
A23: (((#Z 2) * (exp_R + f1)) / exp_R ) . x = (((#Z 2) * (exp_R + f1)) . x) * ((exp_R . x) " ) by A4, A18, RFUNCT_1:def 4
.= (((#Z 2) * (exp_R + f1)) . x) * (1 / (exp_R . x)) by XCMPLX_1:217
.= (((exp_R . x) + 1) * ((exp_R . x) + 1)) / (exp_R . x) by A20, XCMPLX_1:100 ;
(f `| Z) . x = diff (ln * (((#Z 2) * (exp_R + f1)) / exp_R )),x by A2, A14, A18, FDIFF_1:def 8
.= ((((exp_R . x) + 1) * ((exp_R . x) - 1)) / (exp_R . x)) / ((((exp_R . x) + 1) * ((exp_R . x) + 1)) / (exp_R . x)) by A21, A22, A23, TAYLOR_1:20
.= (((exp_R . x) + 1) * ((exp_R . x) - 1)) / (((exp_R . x) + 1) * ((exp_R . x) + 1)) by A15, XCMPLX_1:55
.= ((exp_R . x) - 1) / ((exp_R . x) + 1) by A17, XCMPLX_1:92 ;
hence (f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) ; :: thesis: verum

end;

hence ( f is_differentiable_on Z & ( for x being Real st x in Z holds
(f `| Z) . x = ((exp_R . x) - 1) / ((exp_R . x) + 1) ) ) by A1, A2, A13, FDIFF_1:16; :: thesis: verum