let f be PartFunc of REAL ,REAL ; :: thesis: for x0 being Real st f is_left_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ) ) holds
( f ^ is_left_differentiable_in x0 & Ldiff (f ^ ),x0 = - ((Ldiff f,x0) / ((f . x0) ^2 )) )
let x0 be Real; :: thesis: ( f is_left_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ) ) implies ( f ^ is_left_differentiable_in x0 & Ldiff (f ^ ),x0 = - ((Ldiff f,x0) / ((f . x0) ^2 )) ) )
assume A1: f is_left_differentiable_in x0 ; :: thesis: ( for r0 being Real holds
( not r0 > 0 or ex g being Real st
( g in dom f & g in [.(x0 - r0),x0.] & not f . g <> 0 ) ) or ( f ^ is_left_differentiable_in x0 & Ldiff (f ^ ),x0 = - ((Ldiff f,x0) / ((f . x0) ^2 )) ) )
then consider r2 being Real such that
A2: 0 < r2 and
A3: [.(x0 - r2),x0.] c= dom f by Def4;
given r0 being Real such that A4: r0 > 0 and
A5: for g being Real st g in dom f & g in [.(x0 - r0),x0.] holds
f . g <> 0 ; :: thesis: ( f ^ is_left_differentiable_in x0 & Ldiff (f ^ ),x0 = - ((Ldiff f,x0) / ((f . x0) ^2 )) )
set r3 = min r0,r2;
A6: 0 < min r0,r2 by A4, A2, XXREAL_0:15;
then A7: x0 - (min r0,r2) <= x0 by XREAL_1:45;
min r0,r2 <= r2 by XXREAL_0:17;
then A8: x0 - r2 <= x0 - (min r0,r2) by XREAL_1:15;
then x0 - r2 <= x0 by A7, XXREAL_0:2;
then A9: x0 in [.(x0 - r2),x0.] by XXREAL_1:1;
x0 - (min r0,r2) in { g where g is Real : ( x0 - r2 <= g & g <= x0 ) } by A7, A8;
then x0 - (min r0,r2) in [.(x0 - r2),x0.] by RCOMP_1:def 1;
then [.(x0 - (min r0,r2)),x0.] c= [.(x0 - r2),x0.] by A9, XXREAL_2:def 12;
then A10: [.(x0 - (min r0,r2)),x0.] c= dom f by A3, XBOOLE_1:1;
min r0,r2 <= r0 by XXREAL_0:17;
then A11: x0 - r0 <= x0 - (min r0,r2) by XREAL_1:15;
then x0 - r0 <= x0 by A7, XXREAL_0:2;
then A12: x0 in [.(x0 - r0),x0.] by XXREAL_1:1;
x0 - (min r0,r2) in { g where g is Real : ( x0 - r0 <= g & g <= x0 ) } by A7, A11;
then x0 - (min r0,r2) in [.(x0 - r0),x0.] by RCOMP_1:def 1;
then A13: [.(x0 - (min r0,r2)),x0.] c= [.(x0 - r0),x0.] by A12, XXREAL_2:def 12;
A14: [.(x0 - (min r0,r2)),x0.] c= dom (f ^ )

proof

assume not [.(x0 - (min r0,r2)),x0.] c= dom (f ^ ) ; :: thesis: contradiction
then consider x being set such that
A15: x in [.(x0 - (min r0,r2)),x0.] and
A16: not x in dom (f ^ ) by TARSKI:def 3;
reconsider x = x as Real by A15;
A17: not x in (dom f) \ (f " {0 }) by A16, RFUNCT_1:def 8;

now

per cases ( not x in dom f or x in f " {0 } ) by A17, XBOOLE_0:def 5;

suppose not x in dom f ; :: thesis: contradiction

hence contradiction by A10, A15; :: thesis: verum

end;

suppose A18: x in f " {0 } ; :: thesis: contradiction

then f . x in {0 } by FUNCT_1:def 13;
then A19: f . x = 0 by TARSKI:def 1;
x in dom f by A18, FUNCT_1:def 13;
hence contradiction by A5, A13, A15, A19; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum

end;

A20: x0 in [.(x0 - (min r0,r2)),x0.] by A7, XXREAL_1:1;
for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f ^ ) & ( for n being Element of NAT holds h . n < 0 ) holds
( (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) is convergent & lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = - ((Ldiff f,x0) / ((f . x0) ^2 )) )

proof

let h be convergent_to_0 Real_Sequence; :: thesis: for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f ^ ) & ( for n being Element of NAT holds h . n < 0 ) holds
( (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) is convergent & lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = - ((Ldiff f,x0) / ((f . x0) ^2 )) )
let c be V8() Real_Sequence; :: thesis: ( rng c = {x0} & rng (h + c) c= dom (f ^ ) & ( for n being Element of NAT holds h . n < 0 ) implies ( (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) is convergent & lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = - ((Ldiff f,x0) / ((f . x0) ^2 )) ) )
assume that
A21: rng c = {x0} and
A22: rng (h + c) c= dom (f ^ ) and
A23: for n being Element of NAT holds h . n < 0 ; :: thesis: ( (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) is convergent & lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = - ((Ldiff f,x0) / ((f . x0) ^2 )) )
A24: lim h = 0 by FDIFF_1:def 1;
A25: for m being Element of NAT holds c . m = x0

proof

let m be Element of NAT ; :: thesis: c . m = x0
c . m in rng c by VALUED_0:28;
hence c . m = x0 by A21, TARSKI:def 1; :: thesis: verum

end;

A26: (dom f) \ (f " {0 }) c= dom f by XBOOLE_1:36;
rng (h + c) c= (dom f) \ (f " {0 }) by A22, RFUNCT_1:def 8;
then A27: rng (h + c) c= dom f by A26, XBOOLE_1:1;
then A28: lim ((h " ) (#) ((f /* (h + c)) - (f /* c))) = Ldiff f,x0 by A1, A21, A23, Th9;
Ldiff f,x0 = Ldiff f,x0 ;
then A29: (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent by A1, A21, A23, A27, Th9;
then A30: - ((h " ) (#) ((f /* (h + c)) - (f /* c))) is convergent by SEQ_2:23;
x0 in dom (f ^ ) by A20, A14;
then A31: x0 in (dom f) \ (f " {0 }) by RFUNCT_1:def 8;
rng c c= (dom f) \ (f " {0 })

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng c or x in (dom f) \ (f " {0 }) )
assume x in rng c ; :: thesis: x in (dom f) \ (f " {0 })
hence x in (dom f) \ (f " {0 }) by A21, A31, TARSKI:def 1; :: thesis: verum

end;

then A32: rng c c= dom (f ^ ) by RFUNCT_1:def 8;
then A33: f /* c is non-zero by RFUNCT_2:26;

now

let n be Element of NAT ; :: thesis: (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n
A34: h . n <> 0 by A23;
thus (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) . n = ((h (#) (h " )) (#) ((f /* (h + c)) - (f /* c))) . n by SEQ_1:22
.= ((h (#) (h " )) . n) * (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:12
.= ((h . n) * ((h " ) . n)) * (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:12
.= ((h . n) * ((h . n) " )) * (((f /* (h + c)) - (f /* c)) . n) by VALUED_1:10
.= 1 * (((f /* (h + c)) - (f /* c)) . n) by A34, XCMPLX_0:def 7
.= ((f /* (h + c)) - (f /* c)) . n ; :: thesis: verum

end;

then A35: h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c))) = (f /* (h + c)) - (f /* c) by FUNCT_2:113;
A36: f /* (h + c) is non-zero by A22, RFUNCT_2:26;
then A37: (f /* (h + c)) (#) (f /* c) is non-zero by A33, SEQ_1:43;

now

let n be Element of NAT ; :: thesis: ((f /* c) + ((f /* (h + c)) - (f /* c))) . n = (f /* (h + c)) . n
thus ((f /* c) + ((f /* (h + c)) - (f /* c))) . n = ((f /* c) . n) + (((f /* (h + c)) - (f /* c)) . n) by SEQ_1:11
.= ((f /* c) . n) + (((f /* (h + c)) . n) - ((f /* c) . n)) by RFUNCT_2:6
.= (f /* (h + c)) . n ; :: thesis: verum

end;

then A38: (f /* c) + ((f /* (h + c)) - (f /* c)) = f /* (h + c) by FUNCT_2:113;
dom (f ^ ) = (dom f) \ (f " {0 }) by RFUNCT_1:def 8;
then A39: dom (f ^ ) c= dom f by XBOOLE_1:36;
A40: for g being real number st 0 < g holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f /* c) . m) - (f . x0)) < g

proof

let g be real number ; :: thesis: ( 0 < g implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f /* c) . m) - (f . x0)) < g )
assume A41: 0 < g ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f /* c) . m) - (f . x0)) < g
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
abs (((f /* c) . m) - (f . x0)) < g
let m be Element of NAT ; :: thesis: ( n <= m implies abs (((f /* c) . m) - (f . x0)) < g )
assume n <= m ; :: thesis: abs (((f /* c) . m) - (f . x0)) < g
abs (((f /* c) . m) - (f . x0)) = abs ((f . (c . m)) - (f . x0)) by A32, A39, FUNCT_2:185, XBOOLE_1:1
.= abs ((f . x0) - (f . x0)) by A25
.= 0 by ABSVALUE:def 1 ;
hence abs (((f /* c) . m) - (f . x0)) < g by A41; :: thesis: verum

end;

then A42: f /* c is convergent by SEQ_2:def 6;
then A43: lim (f /* c) = f . x0 by A40, SEQ_2:def 7;
A44: h is convergent by FDIFF_1:def 1;
then h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c))) is convergent by A29, SEQ_2:28;
then A45: f /* (h + c) is convergent by A42, A35, A38, SEQ_2:19;
lim (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) = (lim h) * (lim ((h " ) (#) ((f /* (h + c)) - (f /* c)))) by A44, A29, SEQ_2:29
.= 0 by A24 ;
then 0 = (lim (f /* (h + c))) - (f . x0) by A42, A43, A35, A45, SEQ_2:26;
then A46: lim ((f /* (h + c)) (#) (f /* c)) = (f . x0) ^2 by A42, A43, A45, SEQ_2:29;
A47: lim ((f /* (h + c)) (#) (f /* c)) <> 0

proof

assume not lim ((f /* (h + c)) (#) (f /* c)) <> 0 ; :: thesis: contradiction
then f . x0 = 0 by A46, XCMPLX_1:6;
hence contradiction by A5, A3, A12, A9; :: thesis: verum

end;

now

let n be Element of NAT ; :: thesis: ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) . n = ((- ((h " ) (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c))) . n
A48: ( (f /* (h + c)) . n <> 0 & (f /* c) . n <> 0 ) by A36, A33, SEQ_1:7;
thus ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) . n = ((h " ) . n) * ((((f ^ ) /* (h + c)) - ((f ^ ) /* c)) . n) by SEQ_1:12
.= ((h " ) . n) * ((((f ^ ) /* (h + c)) . n) - (((f ^ ) /* c) . n)) by RFUNCT_2:6
.= ((h " ) . n) * ((((f /* (h + c)) " ) . n) - (((f ^ ) /* c) . n)) by A22, RFUNCT_2:27
.= ((h " ) . n) * ((((f /* (h + c)) " ) . n) - (((f /* c) " ) . n)) by A32, RFUNCT_2:27
.= ((h " ) . n) * ((((f /* (h + c)) . n) " ) - (((f /* c) " ) . n)) by VALUED_1:10
.= ((h " ) . n) * ((((f /* (h + c)) . n) " ) - (((f /* c) . n) " )) by VALUED_1:10
.= ((h " ) . n) * ((1 / ((f /* (h + c)) . n)) - (((f /* c) . n) " )) by XCMPLX_1:217
.= ((h " ) . n) * ((1 / ((f /* (h + c)) . n)) - (1 / ((f /* c) . n))) by XCMPLX_1:217
.= ((h " ) . n) * (((1 * ((f /* c) . n)) - (1 * ((f /* (h + c)) . n))) / (((f /* (h + c)) . n) * ((f /* c) . n))) by A48, XCMPLX_1:131
.= ((h " ) . n) * ((- (((f /* (h + c)) . n) - ((f /* c) . n))) / (((f /* (h + c)) (#) (f /* c)) . n)) by SEQ_1:12
.= ((h " ) . n) * ((- (((f /* (h + c)) - (f /* c)) . n)) / (((f /* (h + c)) (#) (f /* c)) . n)) by RFUNCT_2:6
.= ((h " ) . n) * (- ((((f /* (h + c)) - (f /* c)) . n) / (((f /* (h + c)) (#) (f /* c)) . n))) by XCMPLX_1:188
.= - (((h " ) . n) * ((((f /* (h + c)) - (f /* c)) . n) / (((f /* (h + c)) (#) (f /* c)) . n)))
.= - ((((h " ) . n) * (((f /* (h + c)) - (f /* c)) . n)) / (((f /* (h + c)) (#) (f /* c)) . n)) by XCMPLX_1:75
.= - ((((h " ) (#) ((f /* (h + c)) - (f /* c))) . n) / (((f /* (h + c)) (#) (f /* c)) . n)) by SEQ_1:12
.= - ((((h " ) (#) ((f /* (h + c)) - (f /* c))) . n) * ((((f /* (h + c)) (#) (f /* c)) . n) " )) by XCMPLX_0:def 9
.= - ((((h " ) (#) ((f /* (h + c)) - (f /* c))) . n) * ((((f /* (h + c)) (#) (f /* c)) " ) . n)) by VALUED_1:10
.= - ((((h " ) (#) ((f /* (h + c)) - (f /* c))) /" ((f /* (h + c)) (#) (f /* c))) . n) by SEQ_1:12
.= (- (((h " ) (#) ((f /* (h + c)) - (f /* c))) /" ((f /* (h + c)) (#) (f /* c)))) . n by SEQ_1:14
.= ((- ((h " ) (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c))) . n by SEQ_1:56 ; :: thesis: verum

end;

then A49: (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) = (- ((h " ) (#) ((f /* (h + c)) - (f /* c)))) /" ((f /* (h + c)) (#) (f /* c)) by FUNCT_2:113;
A50: (f /* (h + c)) (#) (f /* c) is convergent by A42, A45, SEQ_2:28;
then lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = (lim (- ((h " ) (#) ((f /* (h + c)) - (f /* c))))) / ((f . x0) ^2 ) by A37, A46, A47, A30, A49, SEQ_2:38
.= (- (Ldiff f,x0)) / ((f . x0) ^2 ) by A29, A28, SEQ_2:24
.= - ((Ldiff f,x0) / ((f . x0) ^2 )) by XCMPLX_1:188 ;
hence ( (h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c)) is convergent & lim ((h " ) (#) (((f ^ ) /* (h + c)) - ((f ^ ) /* c))) = - ((Ldiff f,x0) / ((f . x0) ^2 )) ) by A37, A50, A47, A30, A49, SEQ_2:37; :: thesis: verum

end;

hence ( f ^ is_left_differentiable_in x0 & Ldiff (f ^ ),x0 = - ((Ldiff f,x0) / ((f . x0) ^2 )) ) by A6, A14, Th9; :: thesis: verum