let Z be open Subset of REAL ; :: thesis: ( Z c= dom (arccot * cot ) & ( for x being Real st x in Z holds
( cot . x > - 1 & cot . x < 1 ) ) implies ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) ) )
assume that
A1: Z c= dom (arccot * cot ) and
A2: for x being Real st x in Z holds
( cot . x > - 1 & cot . x < 1 ) ; :: thesis: ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) )
dom (arccot * cot ) c= dom cot by RELAT_1:44;
then A3: Z c= dom cot by A1, XBOOLE_1:1;
A4: for x being Real st x in Z holds
arccot * cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies arccot * cot is_differentiable_in x )
assume A5: x in Z ; :: thesis: arccot * cot is_differentiable_in x
then sin . x <> 0 by A3, FDIFF_8:2;
then A6: cot is_differentiable_in x by FDIFF_7:47;
( cot . x > - 1 & cot . x < 1 ) by A2, A5;
hence arccot * cot is_differentiable_in x by A6, SIN_COS9:86; :: thesis: verum

end;

then A7: arccot * cot is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1

proof

let x be Real; :: thesis: ( x in Z implies ((arccot * cot ) `| Z) . x = 1 )
assume A8: x in Z ; :: thesis: ((arccot * cot ) `| Z) . x = 1
then A9: ( cot . x > - 1 & cot . x < 1 ) by A2;
A10: cot . x = (cos . x) / (sin . x) by A3, A8, RFUNCT_1:def 4;
A11: sin . x <> 0 by A3, A8, FDIFF_8:2;
then A12: cot is_differentiable_in x by FDIFF_7:47;
A13: (sin . x) ^2 <> 0 by A11, SQUARE_1:74;
((arccot * cot ) `| Z) . x = diff (arccot * cot ),x by A7, A8, FDIFF_1:def 8
.= - ((diff cot ,x) / (1 + ((cot . x) ^2 ))) by A12, A9, SIN_COS9:86
.= - ((- (1 / ((sin . x) ^2 ))) / (1 + ((cot . x) ^2 ))) by A11, FDIFF_7:47
.= (1 / ((sin . x) ^2 )) / (1 + ((cot . x) ^2 ))
.= 1 / (((sin . x) ^2 ) * (1 + (((cos . x) / (sin . x)) * ((cos . x) / (sin . x))))) by A10, XCMPLX_1:79
.= 1 / (((sin . x) ^2 ) * (1 + (((cos . x) ^2 ) / ((sin . x) ^2 )))) by XCMPLX_1:77
.= 1 / (((sin . x) ^2 ) + ((((sin . x) ^2 ) * ((cos . x) ^2 )) / ((sin . x) ^2 )))
.= 1 / (((sin . x) ^2 ) + ((cos . x) ^2 )) by A13, XCMPLX_1:90
.= 1 / 1 by SIN_COS:31
.= 1 ;
hence ((arccot * cot ) `| Z) . x = 1 ; :: thesis: verum

end;

hence ( arccot * cot is_differentiable_on Z & ( for x being Real st x in Z holds
((arccot * cot ) `| Z) . x = 1 ) ) by A1, A4, FDIFF_1:16; :: thesis: verum