let f be PartFunc of REAL ,REAL ; :: thesis: ( f is Lipschitzian implies f is continuous )
set X = dom f;
assume f is Lipschitzian ; :: thesis: f is continuous
then consider r being real number such that
A1: 0 < r and
A2: for x1, x2 being real number st x1 in dom f & x2 in dom f holds
abs ((f . x1) - (f . x2)) <= r * (abs (x1 - x2)) by Def3;

now

let x0 be real number ; :: thesis: ( x0 in dom f implies f is_continuous_in x0 )
assume A3: x0 in dom f ; :: thesis: f is_continuous_in x0
for r being real number st 0 < r holds
ex s being real number st
( 0 < s & ( for x1 being real number st x1 in dom f & abs (x1 - x0) < s holds
abs ((f . x1) - (f . x0)) < r ) )

proof

let g be real number ; :: thesis: ( 0 < g implies ex s being real number st
( 0 < s & ( for x1 being real number st x1 in dom f & abs (x1 - x0) < s holds
abs ((f . x1) - (f . x0)) < g ) ) )
assume A4: 0 < g ; :: thesis: ex s being real number st
( 0 < s & ( for x1 being real number st x1 in dom f & abs (x1 - x0) < s holds
abs ((f . x1) - (f . x0)) < g ) )
set s = g / r;
take s9 = g / r; :: thesis: ( 0 < s9 & ( for x1 being real number st x1 in dom f & abs (x1 - x0) < s9 holds
abs ((f . x1) - (f . x0)) < g ) )

A5: now

let x1 be real number ; :: thesis: ( x1 in dom f & abs (x1 - x0) < g / r implies abs ((f . x1) - (f . x0)) < g )
assume that
A6: x1 in dom f and
A7: abs (x1 - x0) < g / r ; :: thesis: abs ((f . x1) - (f . x0)) < g
r * (abs (x1 - x0)) < (g / r) * r by A1, A7, XREAL_1:70;
then A8: r * (abs (x1 - x0)) < g by A1, XCMPLX_1:88;
abs ((f . x1) - (f . x0)) <= r * (abs (x1 - x0)) by A2, A3, A6;
hence abs ((f . x1) - (f . x0)) < g by A8, XXREAL_0:2; :: thesis: verum

end;

s9 = g * (r " ) by XCMPLX_0:def 9;
hence ( 0 < s9 & ( for x1 being real number st x1 in dom f & abs (x1 - x0) < s9 holds
abs ((f . x1) - (f . x0)) < g ) ) by A1, A4, A5, XREAL_1:131; :: thesis: verum

end;

hence f is_continuous_in x0 by Th3; :: thesis: verum

end;

hence f is continuous by Def2; :: thesis: verum