let n be Element of NAT ; :: thesis: for h being Real
for f being Function of REAL ,REAL st f is constant holds
for x being Real holds ((cdif f,h) . (n + 1)) . x = 0
let h be Real; :: thesis: for f being Function of REAL ,REAL st f is constant holds
for x being Real holds ((cdif f,h) . (n + 1)) . x = 0
let f be Function of REAL ,REAL ; :: thesis: ( f is constant implies for x being Real holds ((cdif f,h) . (n + 1)) . x = 0 )
defpred S₁[ Element of NAT ] means for x being Real holds ((cdif f,h) . ($1 + 1)) . x = 0 ;
assume A1: f is constant ; :: thesis: for x being Real holds ((cdif f,h) . (n + 1)) . x = 0
A2: for x being Real holds (f . (x + (h / 2))) - (f . (x - (h / 2))) = 0

proof

let x be Real; :: thesis: (f . (x + (h / 2))) - (f . (x - (h / 2))) = 0
x - (h / 2) in REAL ;
then A3: x - (h / 2) in dom f by FUNCT_2:def 1;
x + (h / 2) in REAL ;
then x + (h / 2) in dom f by FUNCT_2:def 1;
then f . (x + (h / 2)) = f . (x - (h / 2)) by A1, A3, FUNCT_1:def 16;
hence (f . (x + (h / 2))) - (f . (x - (h / 2))) = 0 ; :: thesis: verum

end;

A4: S₁[ 0 ]

proof

let x be Real; :: thesis: ((cdif f,h) . (0 + 1)) . x = 0
thus ((cdif f,h) . (0 + 1)) . x = (cD ((cdif f,h) . 0 ),h) . x by Def8
.= (cD f,h) . x by Def8
.= (f . (x + (h / 2))) - (f . (x - (h / 2))) by Th5
.= 0 by A2 ; :: thesis: verum

end;

A5: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A6: for x being Real holds ((cdif f,h) . (k + 1)) . x = 0 ; :: thesis: S₁[k + 1]
let x be Real; :: thesis: ((cdif f,h) . ((k + 1) + 1)) . x = 0
A7: ((cdif f,h) . (k + 1)) . (x - (h / 2)) = 0 by A6;
A8: (cdif f,h) . (k + 1) is Function of REAL ,REAL by Th19;
((cdif f,h) . (k + 2)) . x = ((cdif f,h) . ((k + 1) + 1)) . x
.= (cD ((cdif f,h) . (k + 1)),h) . x by Def8
.= (((cdif f,h) . (k + 1)) . (x + (h / 2))) - (((cdif f,h) . (k + 1)) . (x - (h / 2))) by A8, Th5
.= 0 by A6, A7 ;
hence ((cdif f,h) . ((k + 1) + 1)) . x = 0 ; :: thesis: verum

end;

for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A4, A5);
hence for x being Real holds ((cdif f,h) . (n + 1)) . x = 0 ; :: thesis: verum