let n be Element of NAT ; :: thesis: for h being Real
for f being Function of REAL ,REAL st f is constant holds
for x being Real holds ((bdif f,h) . (n + 1)) . x = 0
let h be Real; :: thesis: for f being Function of REAL ,REAL st f is constant holds
for x being Real holds ((bdif f,h) . (n + 1)) . x = 0
let f be Function of REAL ,REAL ; :: thesis: ( f is constant implies for x being Real holds ((bdif f,h) . (n + 1)) . x = 0 )
assume A1: f is constant ; :: thesis: for x being Real holds ((bdif f,h) . (n + 1)) . x = 0
A2: for x being Real holds (f . x) - (f . (x - h)) = 0

proof

let x be Real; :: thesis: (f . x) - (f . (x - h)) = 0
x - h in REAL ;
then A3: x - h in dom f by FUNCT_2:def 1;
x in REAL ;
then x in dom f by FUNCT_2:def 1;
then f . x = f . (x - h) by A1, A3, FUNCT_1:def 16;
hence (f . x) - (f . (x - h)) = 0 ; :: thesis: verum

end;

for x being Real holds ((bdif f,h) . (n + 1)) . x = 0

proof

defpred S₁[ Element of NAT ] means for x being Real holds ((bdif f,h) . ($1 + 1)) . x = 0 ;
A4: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A5: for x being Real holds ((bdif f,h) . (k + 1)) . x = 0 ; :: thesis: S₁[k + 1]
let x be Real; :: thesis: ((bdif f,h) . ((k + 1) + 1)) . x = 0
A6: ((bdif f,h) . (k + 1)) . (x - h) = 0 by A5;
A7: (bdif f,h) . (k + 1) is Function of REAL ,REAL by Th12;
((bdif f,h) . (k + 2)) . x = ((bdif f,h) . ((k + 1) + 1)) . x
.= (bD ((bdif f,h) . (k + 1)),h) . x by Def7
.= (((bdif f,h) . (k + 1)) . x) - (((bdif f,h) . (k + 1)) . (x - h)) by A7, Th4
.= 0 by A5, A6 ;
hence ((bdif f,h) . ((k + 1) + 1)) . x = 0 ; :: thesis: verum

end;

A8: S₁[ 0 ]

proof

let x be Real; :: thesis: ((bdif f,h) . (0 + 1)) . x = 0
thus ((bdif f,h) . (0 + 1)) . x = (bD ((bdif f,h) . 0 ),h) . x by Def7
.= (bD f,h) . x by Def7
.= (f . x) - (f . (x - h)) by Th4
.= 0 by A2 ; :: thesis: verum

end;

for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A8, A4);
hence for x being Real holds ((bdif f,h) . (n + 1)) . x = 0 ; :: thesis: verum

end;

hence for x being Real holds ((bdif f,h) . (n + 1)) . x = 0 ; :: thesis: verum