let s be Complex_Sequence; :: thesis: ( s is convergent & lim s <> 0c & s is non-empty implies s " is convergent )
assume that
A1: s is convergent and
A2: lim s <> 0c and
A3: s is non-empty ; :: thesis: s " is convergent
consider n1 being Element of NAT such that
A4: for m being Element of NAT st n1 <= m holds
|.(lim s).| / 2 < |.(s . m).| by A1, A2, Th33;
take g = (lim s) " ; :: according to COMSEQ_2:def 4 :: thesis: for p being Real st 0 < p holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((s " ) . m) - g).| < p
let p be Real; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((s " ) . m) - g).| < p )
assume A5: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((s " ) . m) - g).| < p
A6: 0 < |.(lim s).| by A2, COMPLEX1:133;
then 0 * 0 < |.(lim s).| * |.(lim s).| by XREAL_1:98;
then 0 < (|.(lim s).| * |.(lim s).|) / 2 by XREAL_1:217;
then 0 * 0 < p * ((|.(lim s).| * |.(lim s).|) / 2) by A5, XREAL_1:98;
then consider n2 being Element of NAT such that
A7: for m being Element of NAT st n2 <= m holds
|.((s . m) - (lim s)).| < p * ((|.(lim s).| * |.(lim s).|) / 2) by A1, Def5;
take n = n1 + n2; :: thesis: for m being Element of NAT st n <= m holds
|.(((s " ) . m) - g).| < p
let m be Element of NAT ; :: thesis: ( n <= m implies |.(((s " ) . m) - g).| < p )
assume A8: n <= m ; :: thesis: |.(((s " ) . m) - g).| < p
n1 <= n1 + n2 by NAT_1:12;
then n1 <= m by A8, XXREAL_0:2;
then A9: |.(lim s).| / 2 < |.(s . m).| by A4;
A10: 0 < |.(lim s).| / 2 by A6, XREAL_1:217;
then 0 * 0 < p * (|.(lim s).| / 2) by A5, XREAL_1:98;
then A11: (p * (|.(lim s).| / 2)) / |.(s . m).| < (p * (|.(lim s).| / 2)) / (|.(lim s).| / 2) by A9, A10, XREAL_1:78;
A12: 0 <> |.(lim s).| / 2 by A2, COMPLEX1:133;
A13: (p * (|.(lim s).| / 2)) / (|.(lim s).| / 2) = (p * (|.(lim s).| / 2)) * ((|.(lim s).| / 2) " ) by XCMPLX_0:def 9
.= p * ((|.(lim s).| / 2) * ((|.(lim s).| / 2) " ))
.= p * 1 by A12, XCMPLX_0:def 7
.= p ;
A14: 0 <> |.(lim s).| by A2, COMPLEX1:133;
A15: (p * ((|.(lim s).| * |.(lim s).|) / 2)) / (|.(s . m).| * |.(lim s).|) = (p * ((2 " ) * (|.(lim s).| * |.(lim s).|))) * ((|.(s . m).| * |.(lim s).|) " ) by XCMPLX_0:def 9
.= (p * (2 " )) * ((|.(lim s).| * |.(lim s).|) * ((|.(lim s).| * |.(s . m).|) " ))
.= (p * (2 " )) * ((|.(lim s).| * |.(lim s).|) * ((|.(lim s).| " ) * (|.(s . m).| " ))) by XCMPLX_1:205
.= (p * (2 " )) * ((|.(lim s).| * (|.(lim s).| * (|.(lim s).| " ))) * (|.(s . m).| " ))
.= (p * (2 " )) * ((|.(lim s).| * 1) * (|.(s . m).| " )) by A14, XCMPLX_0:def 7
.= (p * (|.(lim s).| / 2)) * (|.(s . m).| " )
.= (p * (|.(lim s).| / 2)) / |.(s . m).| by XCMPLX_0:def 9 ;
A16: s . m <> 0c by A3, COMSEQ_1:3;
then (s . m) * (lim s) <> 0c by A2, XCMPLX_1:6;
then 0 < |.((s . m) * (lim s)).| by COMPLEX1:133;
then A17: 0 < |.(s . m).| * |.(lim s).| by COMPLEX1:151;
n2 <= n by NAT_1:12;
then n2 <= m by A8, XXREAL_0:2;
then |.((s . m) - (lim s)).| < p * ((|.(lim s).| * |.(lim s).|) / 2) by A7;
then A18: |.((s . m) - (lim s)).| / (|.(s . m).| * |.(lim s).|) < (p * ((|.(lim s).| * |.(lim s).|) / 2)) / (|.(s . m).| * |.(lim s).|) by A17, XREAL_1:76;
|.(((s " ) . m) - ((lim s) " )).| = |.(((s . m) " ) - ((lim s) " )).| by VALUED_1:10
.= |.((s . m) - (lim s)).| / (|.(s . m).| * |.(lim s).|) by A2, A16, Th1 ;
hence |.(((s " ) . m) - g).| < p by A18, A15, A11, A13, XXREAL_0:2; :: thesis: verum