let X be ComplexUnitarySpace; :: thesis: for z being Complex
for seq being sequence of X st seq is Cauchy holds
z * seq is Cauchy
let z be Complex; :: thesis: for seq being sequence of X st seq is Cauchy holds
z * seq is Cauchy
let seq be sequence of X; :: thesis: ( seq is Cauchy implies z * seq is Cauchy )
assume A1: seq is Cauchy ; :: thesis: z * seq is Cauchy

A2: now

A3: 0 / |.z.| = 0 ;
assume A4: z <> 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
then A5: |.z.| > 0 by COMPLEX1:133;
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
then r / |.z.| > 0 by A5, A3, XREAL_1:76;
then consider m1 being Element of NAT such that
A6: for n, m being Element of NAT st n >= m1 & m >= m1 holds
dist (seq . n),(seq . m) < r / |.z.| by A1, Def8;
take k = m1; :: thesis: for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
let n, m be Element of NAT ; :: thesis: ( n >= k & m >= k implies dist ((z * seq) . n),((z * seq) . m) < r )
assume ( n >= k & m >= k ) ; :: thesis: dist ((z * seq) . n),((z * seq) . m) < r
then A7: dist (seq . n),(seq . m) < r / |.z.| by A6;
A8: |.z.| <> 0 by A4, COMPLEX1:133;
A9: |.z.| * (r / |.z.|) = |.z.| * ((|.z.| " ) * r) by XCMPLX_0:def 9
.= (|.z.| * (|.z.| " )) * r
.= 1 * r by A8, XCMPLX_0:def 7
.= r ;
dist (z * (seq . n)),(z * (seq . m)) = ||.((z * (seq . n)) - (z * (seq . m))).|| by CSSPACE:def 16
.= ||.(z * ((seq . n) - (seq . m))).|| by CLVECT_1:10
.= |.z.| * ||.((seq . n) - (seq . m)).|| by CSSPACE:45
.= |.z.| * (dist (seq . n),(seq . m)) by CSSPACE:def 16 ;
then dist (z * (seq . n)),(z * (seq . m)) < r by A5, A7, A9, XREAL_1:70;
then dist ((z * seq) . n),(z * (seq . m)) < r by CLVECT_1:def 15;
hence dist ((z * seq) . n),((z * seq) . m) < r by CLVECT_1:def 15; :: thesis: verum

end;

now

assume A10: z = 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
then consider m1 being Element of NAT such that
A11: for n, m being Element of NAT st n >= m1 & m >= m1 holds
dist (seq . n),(seq . m) < r by A1, Def8;
take k = m1; :: thesis: for n, m being Element of NAT st n >= k & m >= k holds
dist ((z * seq) . n),((z * seq) . m) < r
let n, m be Element of NAT ; :: thesis: ( n >= k & m >= k implies dist ((z * seq) . n),((z * seq) . m) < r )
assume ( n >= k & m >= k ) ; :: thesis: dist ((z * seq) . n),((z * seq) . m) < r
then A12: dist (seq . n),(seq . m) < r by A11;
dist (z * (seq . n)),(z * (seq . m)) = dist H₂(X),(0c * (seq . m)) by A10, CLVECT_1:2
.= dist H₂(X),H₂(X) by CLVECT_1:2
.= 0 by CSSPACE:53 ;
then dist (z * (seq . n)),(z * (seq . m)) < r by A12, CSSPACE:56;
then dist ((z * seq) . n),(z * (seq . m)) < r by CLVECT_1:def 15;
hence dist ((z * seq) . n),((z * seq) . m) < r by CLVECT_1:def 15; :: thesis: verum

end;

hence z * seq is Cauchy by A2, Def8; :: thesis: verum