let f be PartFunc of COMPLEX ,COMPLEX ; :: thesis: for x0 being Complex st f is_differentiable_in x0 holds
f is_continuous_in x0
let x0 be Complex; :: thesis: ( f is_differentiable_in x0 implies f is_continuous_in x0 )
assume A1: f is_differentiable_in x0 ; :: thesis: f is_continuous_in x0
then consider N being Neighbourhood of x0 such that
A2: N c= dom f and
ex L being C_LINEAR ex R being C_REST st
for x being Complex st x in N holds
(f /. x) - (f /. x0) = (L /. (x - x0)) + (R /. (x - x0)) by Def6;
A3: x0 in N by Th7;

now

consider g being Real such that
A4: 0 < g and
A5: { y where y is Complex : |.(y - x0).| < g } c= N by Def5;
reconsider s2 = NAT --> x0 as Complex_Sequence ;
let s1 be Complex_Sequence; :: thesis: ( rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) implies ( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) )
assume that
A6: rng s1 c= dom f and
A7: s1 is convergent and
A8: lim s1 = x0 and
A9: for n being Element of NAT holds s1 . n <> x0 ; :: thesis: ( f /* s1 is convergent & f /. x0 = lim (f /* s1) )
consider l being Element of NAT such that
A10: for m being Element of NAT st l <= m holds
|.((s1 . m) - x0).| < g by A7, A8, A4, COMSEQ_2:def 5;
A11: lim s2 = s2 . 0 by CFCONT_1:50
.= x0 by FUNCOP_1:13 ;
deffunc H₁( Element of NAT ) -> Element of COMPLEX = (s1 . $1) - (s2 . $1);
consider s3 being Complex_Sequence such that
A12: for n being Element of NAT holds s3 . n = H₁(n) from FUNCT_2:sch 4();
A13: s3 = s1 - s2 by A12, CFCONT_1:2;
A14: s2 is convergent by CFCONT_1:48;
then A15: s3 is convergent by A7, A13, COMSEQ_2:25;
lim s3 = lim (s1 - s2) by A12, CFCONT_1:2
.= x0 - x0 by A7, A8, A14, A11, COMSEQ_2:26
.= 0c ;
then A16: lim (s3 ^\ l) = 0c by A15, CFCONT_1:43;
reconsider c = s2 ^\ l as V8() Complex_Sequence ;

A17: now

given n being Element of NAT such that A18: s3 . n = 0c ; :: thesis: contradiction
(s1 . n) - (s2 . n) = 0c by A12, A18;
hence contradiction by A9, FUNCOP_1:13; :: thesis: verum

end;

A19: now

given n being Element of NAT such that A20: (s3 ^\ l) . n = 0c ; :: thesis: contradiction
s3 . (n + l) = 0c by A20, NAT_1:def 3;
hence contradiction by A17; :: thesis: verum

end;

then A21: s3 ^\ l is non-empty by COMSEQ_1:4;
s3 ^\ l is convergent by A15, CFCONT_1:43;
then reconsider h = s3 ^\ l as convergent_to_0 Complex_Sequence by A16, A21, Def1;

now

let n be Element of NAT ; :: thesis: (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (f /* (h + c)) . n
thus (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (((f /* (h + c)) - (f /* c)) . n) + ((f /* c) . n) by VALUED_1:1
.= (((f /* (h + c)) . n) - ((f /* c) . n)) + ((f /* c) . n) by CFCONT_1:2
.= (f /* (h + c)) . n ; :: thesis: verum

end;

then A22: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (h + c) by FUNCT_2:113;

now

let n be Element of NAT ; :: thesis: (h + c) . n = (s1 ^\ l) . n
thus (h + c) . n = (((s1 - s2) + s2) ^\ l) . n by A13, Th18
.= ((s1 - s2) + s2) . (n + l) by NAT_1:def 3
.= ((s1 - s2) . (n + l)) + (s2 . (n + l)) by VALUED_1:1
.= ((s1 . (n + l)) - (s2 . (n + l))) + (s2 . (n + l)) by CFCONT_1:2
.= (s1 ^\ l) . n by NAT_1:def 3 ; :: thesis: verum

end;

then A23: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (s1 ^\ l) by A22, FUNCT_2:113
.= (f /* s1) ^\ l by A6, VALUED_0:27 ;
A24: rng c = {x0}

proof

thus rng c c= {x0} :: according to XBOOLE_0:def 10 :: thesis: {x0} c= rng c

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng c or y in {x0} )
assume y in rng c ; :: thesis: y in {x0}
then consider n being Element of NAT such that
A25: y = (s2 ^\ l) . n by FUNCT_2:190;
y = s2 . (n + l) by A25, NAT_1:def 3;
then y = x0 by FUNCOP_1:13;
hence y in {x0} by TARSKI:def 1; :: thesis: verum

end;

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in {x0} or y in rng c )
assume y in {x0} ; :: thesis: y in rng c
then A26: y = x0 by TARSKI:def 1;
c . 0 = s2 . (0 + l) by NAT_1:def 3
.= y by A26, FUNCOP_1:13 ;
hence y in rng c by FUNCT_2:6; :: thesis: verum

end;

A27: now

let p be Real; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((f /* c) . m) - (f /. x0)).| < p )
assume A28: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((f /* c) . m) - (f /. x0)).| < p
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
|.(((f /* c) . m) - (f /. x0)).| < p
thus for m being Element of NAT st n <= m holds
|.(((f /* c) . m) - (f /. x0)).| < p :: thesis: verum

proof

let m be Element of NAT ; :: thesis: ( n <= m implies |.(((f /* c) . m) - (f /. x0)).| < p )
assume n <= m ; :: thesis: |.(((f /* c) . m) - (f /. x0)).| < p
{x0} c= dom f by A2, A3, ZFMISC_1:37;
then |.(((f /* c) . m) - (f /. x0)).| = |.((f /. (c . m)) - (f /. x0)).| by A24, FUNCT_2:186
.= |.((f /. (s2 . (m + l))) - (f /. x0)).| by NAT_1:def 3
.= |.((f /. x0) - (f /. x0)).| by FUNCOP_1:13
.= 0 by ABSVALUE:7 ;
hence |.(((f /* c) . m) - (f /. x0)).| < p by A28; :: thesis: verum

end;

end;

then A29: f /* c is convergent by COMSEQ_2:def 4;

now

let n be Element of NAT ; :: thesis: (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) . n = ((f /* (h + c)) - (f /* c)) . n
A30: h . n <> 0 by A19;
thus (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) . n = (h . n) * (((h " ) (#) ((f /* (h + c)) - (f /* c))) . n) by VALUED_1:5
.= (h . n) * (((h " ) . n) * (((f /* (h + c)) - (f /* c)) . n)) by VALUED_1:5
.= (h . n) * (((h . n) " ) * (((f /* (h + c)) - (f /* c)) . n)) by VALUED_1:10
.= ((h . n) * ((h . n) " )) * (((f /* (h + c)) - (f /* c)) . n)
.= 1 * (((f /* (h + c)) - (f /* c)) . n) by A30, XCMPLX_0:def 7
.= ((f /* (h + c)) - (f /* c)) . n ; :: thesis: verum

end;

then A31: h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c))) = (f /* (h + c)) - (f /* c) by FUNCT_2:113;
rng (h + c) c= N

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (h + c) or y in N )
assume A32: y in rng (h + c) ; :: thesis: y in N
then consider n being Element of NAT such that
A33: y = (h + c) . n by FUNCT_2:190;
reconsider y1 = y as Complex by A32;
(h + c) . n = (((s1 - s2) + s2) ^\ l) . n by A13, Th18
.= ((s1 - s2) + s2) . (n + l) by NAT_1:def 3
.= ((s1 - s2) . (n + l)) + (s2 . (n + l)) by VALUED_1:1
.= ((s1 . (n + l)) - (s2 . (n + l))) + (s2 . (n + l)) by CFCONT_1:2
.= s1 . (l + n) ;
then |.(((h + c) . n) - x0).| < g by A10, NAT_1:12;
then y1 in { z where z is Complex : |.(z - x0).| < g } by A33;
hence y in N by A5; :: thesis: verum

end;

then A34: (h " ) (#) ((f /* (h + c)) - (f /* c)) is convergent by A1, A2, A24, Th22;
then A35: (f /* (h + c)) - (f /* c) is convergent by A31, COMSEQ_2:29;
then A36: ((f /* (h + c)) - (f /* c)) + (f /* c) is convergent by A29, COMSEQ_2:13;
hence f /* s1 is convergent by A23, CFCONT_1:44; :: thesis: f /. x0 = lim (f /* s1)
lim (h (#) ((h " ) (#) ((f /* (h + c)) - (f /* c)))) = 0c * (lim ((h " ) (#) ((f /* (h + c)) - (f /* c)))) by A16, A34, COMSEQ_2:30
.= 0 ;
then lim (((f /* (h + c)) - (f /* c)) + (f /* c)) = 0c + (lim (f /* c)) by A31, A35, A29, COMSEQ_2:14
.= f /. x0 by A27, A29, COMSEQ_2:def 5 ;
hence f /. x0 = lim (f /* s1) by A36, A23, CFCONT_1:45; :: thesis: verum

end;

hence f is_continuous_in x0 by A2, A3, CFCONT_1:53; :: thesis: verum