let X be BCI-algebra; :: thesis: for x, y, z being Element of X
for n being Element of NAT st x <= y holds
z,y to_power n <= z,x to_power n
let x, y, z be Element of X; :: thesis: for n being Element of NAT st x <= y holds
z,y to_power n <= z,x to_power n
let n be Element of NAT ; :: thesis: ( x <= y implies z,y to_power n <= z,x to_power n )
defpred S₁[ set ] means for m being Element of NAT st m = $1 & m <= n holds
z,y to_power m <= z,x to_power m;
assume A1: x <= y ; :: thesis: z,y to_power n <= z,x to_power n
A2: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A3: for m being Element of NAT st m = k & m <= n holds
z,y to_power m <= z,x to_power m ; :: thesis: S₁[k + 1]
(z,x to_power k) \ y <= (z,x to_power k) \ x by A1, BCIALG_1:5;
then (z,x to_power k) \ y <= z,x to_power (k + 1) by Th4;
then A4: ((z,x to_power k) \ y) \ (z,x to_power (k + 1)) = 0. X by BCIALG_1:def 11;
let m be Element of NAT ; :: thesis: ( m = k + 1 & m <= n implies z,y to_power m <= z,x to_power m )
assume that
A5: m = k + 1 and
A6: m <= n ; :: thesis: z,y to_power m <= z,x to_power m
k <= n by A5, A6, NAT_1:13;
then z,y to_power k <= z,x to_power k by A3;
then (z,y to_power k) \ y <= (z,x to_power k) \ y by BCIALG_1:5;
then z,y to_power (k + 1) <= (z,x to_power k) \ y by Th4;
then (z,y to_power (k + 1)) \ ((z,x to_power k) \ y) = 0. X by BCIALG_1:def 11;
then (z,y to_power (k + 1)) \ (z,x to_power (k + 1)) = 0. X by A4, BCIALG_1:3;
hence z,y to_power m <= z,x to_power m by A5, BCIALG_1:def 11; :: thesis: verum

end;

z \ z = 0. X by BCIALG_1:def 5;
then z <= z by BCIALG_1:def 11;
then z,y to_power 0 <= z by Th1;
then A7: S₁[ 0 ] by Th1;
for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A7, A2);
hence z,y to_power n <= z,x to_power n ; :: thesis: verum