let n be Ordinal; :: thesis: for T being connected admissible TermOrder of n
for L being non trivial right_complementable almost_left_invertible associative commutative well-unital distributive add-associative right_zeroed doubleLoopStr
for f, p, g being Polynomial of n,L
for b, b' being bag of n st b < b',T & f reduces_to g,p,b,T holds
f . b' = g . b'
let T be connected admissible TermOrder of n; :: thesis: for L being non trivial right_complementable almost_left_invertible associative commutative well-unital distributive add-associative right_zeroed doubleLoopStr
for f, p, g being Polynomial of n,L
for b, b' being bag of n st b < b',T & f reduces_to g,p,b,T holds
f . b' = g . b'
let L be non trivial right_complementable almost_left_invertible associative commutative well-unital distributive add-associative right_zeroed doubleLoopStr ; :: thesis: for f, p, g being Polynomial of n,L
for b, b' being bag of n st b < b',T & f reduces_to g,p,b,T holds
f . b' = g . b'
let f, p, g be Polynomial of n,L; :: thesis: for b, b' being bag of n st b < b',T & f reduces_to g,p,b,T holds
f . b' = g . b'
let b, b' be bag of n; :: thesis: ( b < b',T & f reduces_to g,p,b,T implies f . b' = g . b' )
assume A1: b < b',T ; :: thesis: ( not f reduces_to g,p,b,T or f . b' = g . b' )
assume f reduces_to g,p,b,T ; :: thesis: f . b' = g . b'
then consider s being bag of n such that
A2: s + (HT p,T) = b and
A3: g = f - (((f . b) / (HC p,T)) * (s *' p)) by Def5;

A4: now

assume b' in Support (s *' p) ; :: thesis: contradiction
then A5: b' <= b,T by A2, Th16;
b <= b',T by A1, TERMORD:def 3;
then b = b' by A5, TERMORD:7;
hence contradiction by A1, TERMORD:def 3; :: thesis: verum

end;

A6: b' is Element of Bags n by PRE_POLY:def 12;
A7: (((f . b) / (HC p,T)) * (s *' p)) . b' = ((f . b) / (HC p,T)) * ((s *' p) . b') by POLYNOM7:def 10
.= ((f . b) / (HC p,T)) * (0. L) by A6, A4, POLYNOM1:def 9
.= 0. L by VECTSP_1:39 ;
(f - (((f . b) / (HC p,T)) * (s *' p))) . b' = (f + (- (((f . b) / (HC p,T)) * (s *' p)))) . b' by POLYNOM1:def 23
.= (f . b') + ((- (((f . b) / (HC p,T)) * (s *' p))) . b') by POLYNOM1:def 21
.= (f . b') + (- (0. L)) by A7, POLYNOM1:def 22
.= (f . b') + (0. L) by RLVECT_1:25
.= f . b' by RLVECT_1:def 7 ;
hence f . b' = g . b' by A3; :: thesis: verum