consider 00 being Element of F₁();
defpred S₁[ Element of NAT , set , set ] means ( ( $1 < F₃() - 1 implies P₁[$1 + 1,$2,$3] ) & ( not $1 < F₃() - 1 implies $3 = 00 ) );
A2: for n being Element of NAT
for x being Element of F₁() ex y being Element of F₁() st S₁[n,x,y]

proof

let n be Element of NAT ; :: thesis: for x being Element of F₁() ex y being Element of F₁() st S₁[n,x,y]
let x be Element of F₁(); :: thesis: ex y being Element of F₁() st S₁[n,x,y]
( n < F₃() - 1 implies ex y being Element of F₁() st S₁[n,x,y] )

proof

assume A3: n < F₃() - 1 ; :: thesis: ex y being Element of F₁() st S₁[n,x,y]
then n + 1 < F₃() by XREAL_1:22;
then consider y being Element of F₁() such that
A4: P₁[n + 1,x,y] by A1, NAT_1:11;
take y ; :: thesis: S₁[n,x,y]
thus ( n < F₃() - 1 implies P₁[n + 1,x,y] ) by A4; :: thesis: ( not n < F₃() - 1 implies y = 00 )
thus ( not n < F₃() - 1 implies y = 00 ) by A3; :: thesis: verum

end;

hence ex y being Element of F₁() st S₁[n,x,y] ; :: thesis: verum

end;

consider f being Function of NAT ,F₁() such that
A5: ( f . 0 = F₂() & ( for n being Element of NAT holds S₁[n,f . n,f . (n + 1)] ) ) from RECDEF_1:sch 2(A2);
defpred S₂[ set , set ] means for r being Real st r = $1 holds
$2 = f . (r - 1);
A6: for x being set st x in REAL holds
ex y being set st S₂[x,y]

proof

let x be set ; :: thesis: ( x in REAL implies ex y being set st S₂[x,y] )
assume x in REAL ; :: thesis: ex y being set st S₂[x,y]
then reconsider r = x as Real ;
take f . (r - 1) ; :: thesis: S₂[x,f . (r - 1)]
thus S₂[x,f . (r - 1)] ; :: thesis: verum

end;

consider g being Function such that
A7: ( dom g = REAL & ( for x being set st x in REAL holds
S₂[x,g . x] ) ) from CLASSES1:sch 1(A6);
A8: dom (g | (Seg F₃())) = Seg F₃() by A7, RELAT_1:91, XBOOLE_1:1;
then reconsider p = g | (Seg F₃()) as FinSequence by FINSEQ_1:def 2;
rng p c= F₁()

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng p or x in F₁() )
assume x in rng p ; :: thesis: x in F₁()
then consider y being set such that
A9: y in dom p and
A10: x = p . y by FUNCT_1:def 5;
reconsider y = y as Element of NAT by A9;
A11: f . (y - 1) in F₁()

proof

y <> 0 by A8, A9, FINSEQ_1:3;
then consider k being Nat such that
A12: y = k + 1 by NAT_1:6;
reconsider k = k as Element of NAT by ORDINAL1:def 13;
f . k in F₁() ;
hence f . (y - 1) in F₁() by A12; :: thesis: verum

end;

p . y = g . y by A9, FUNCT_1:70;
hence x in F₁() by A7, A10, A11; :: thesis: verum

end;

then reconsider p = p as FinSequence of F₁() by FINSEQ_1:def 4;
take p ; :: thesis: ( len p = F₃() & ( p . 1 = F₂() or F₃() = 0 ) & ( for n being Element of NAT st 1 <= n & n < F₃() holds
P₁[n,p . n,p . (n + 1)] ) )
F₃() in NAT by ORDINAL1:def 13;
hence len p = F₃() by A8, FINSEQ_1:def 3; :: thesis: ( ( p . 1 = F₂() or F₃() = 0 ) & ( for n being Element of NAT st 1 <= n & n < F₃() holds
P₁[n,p . n,p . (n + 1)] ) )
( not F₃() <> 0 or p . 1 = F₂() or F₃() = 0 )

proof

assume F₃() <> 0 ; :: thesis: ( p . 1 = F₂() or F₃() = 0 )
then consider k being Nat such that
A13: F₃() = k + 1 by NAT_1:6;
0 <= k by NAT_1:2;
then 0 + 1 <= k + 1 by XREAL_1:9;
then 1 in Seg F₃() by A13, FINSEQ_1:3;
then p . 1 = g . 1 by FUNCT_1:72
.= f . (1 - 1) by A7
.= F₂() by A5 ;
hence ( p . 1 = F₂() or F₃() = 0 ) ; :: thesis: verum

end;

hence ( p . 1 = F₂() or F₃() = 0 ) ; :: thesis: for n being Element of NAT st 1 <= n & n < F₃() holds
P₁[n,p . n,p . (n + 1)]
let n be Element of NAT ; :: thesis: ( 1 <= n & n < F₃() implies P₁[n,p . n,p . (n + 1)] )
assume that
A14: 1 <= n and
A15: n < F₃() ; :: thesis: P₁[n,p . n,p . (n + 1)]
0 <> n by A14;
then consider k being Nat such that
A16: n = k + 1 by NAT_1:6;
A17: for n being Element of NAT st n < F₃() holds
p . (n + 1) = f . n

proof

let n be Element of NAT ; :: thesis: ( n < F₃() implies p . (n + 1) = f . n )
assume n < F₃() ; :: thesis: p . (n + 1) = f . n
then ( 1 <= n + 1 & n + 1 <= F₃() ) by NAT_1:11, NAT_1:13;
then A18: n + 1 in Seg F₃() by FINSEQ_1:3;
g . (n + 1) = f . ((n + 1) - 1) by A7
.= f . n ;
hence p . (n + 1) = f . n by A18, FUNCT_1:72; :: thesis: verum

end;

reconsider k = k as Element of NAT by ORDINAL1:def 13;
k <= k + 1 by NAT_1:11;
then A19: k < F₃() by A15, A16, XXREAL_0:2;
k < F₃() - 1 by A15, A16, XREAL_1:22;
then P₁[k + 1,f . k,f . (k + 1)] by A5;
then P₁[k + 1,f . k,p . ((k + 1) + 1)] by A17, A15, A16;
hence P₁[n,p . n,p . (n + 1)] by A17, A16, A19; :: thesis: verum