let R be RelStr ; :: thesis: ( R is well_founded iff well_founded-Part R = the carrier of R )
set r = the InternalRel of R;
set c = the carrier of R;
set wfp = well_founded-Part R;
the carrier of R c= the carrier of R ;
then reconsider cs = the carrier of R as Subset of R ;
set IT = { S where S is Subset of R : ( S is well_founded & S is lower ) } ;
A1: well_founded-Part R = union { S where S is Subset of R : ( S is well_founded & S is lower ) } by Def4;

hereby :: thesis: ( well_founded-Part R = the carrier of R implies R is well_founded )

assume A2: R is well_founded ; :: thesis: well_founded-Part R = the carrier of R
A3: cs is lower

proof

let x, y be set ; :: according to WELLFND1:def 1 :: thesis: ( x in cs & [y,x] in the InternalRel of R implies y in cs )
thus ( x in cs & [y,x] in the InternalRel of R implies y in cs ) by ZFMISC_1:106; :: thesis: verum

end;

the InternalRel of R is_well_founded_in cs by A2, Def2;
then cs is well_founded by Def3;
then cs in { S where S is Subset of R : ( S is well_founded & S is lower ) } by A3;
then cs c= well_founded-Part R by A1, ZFMISC_1:92;
hence well_founded-Part R = the carrier of R by XBOOLE_0:def 10; :: thesis: verum

end;

assume A4: well_founded-Part R = the carrier of R ; :: thesis: R is well_founded
let Y be set ; :: according to WELLORD1:def 3,WELLFND1:def 2 :: thesis: ( not Y c= the carrier of R or Y = {} or ex b₁ being set st
( b₁ in Y & the InternalRel of R -Seg b₁ misses Y ) )
assume A5: ( Y c= the carrier of R & Y <> {} ) ; :: thesis: ex b₁ being set st
( b₁ in Y & the InternalRel of R -Seg b₁ misses Y )
then consider y being set such that
A6: y in Y by XBOOLE_0:def 1;
consider YY being set such that
A7: ( y in YY & YY in { S where S is Subset of R : ( S is well_founded & S is lower ) } ) by A1, A4, A5, A6, TARSKI:def 4;
consider S being Subset of R such that
A8: ( YY = S & S is well_founded & S is lower ) by A7;
A9: the InternalRel of R is_well_founded_in S by A8, Def3;
set YS = Y /\ S;
( Y /\ S c= S & Y /\ S <> {} ) by A6, A7, A8, XBOOLE_0:def 4, XBOOLE_1:17;
then consider a being set such that
A10: ( a in Y /\ S & the InternalRel of R -Seg a misses Y /\ S ) by A9, WELLORD1:def 3;
A11: (the InternalRel of R -Seg a) /\ (Y /\ S) = {} by A10, XBOOLE_0:def 7;
A12: ( a in Y & a in S ) by A10, XBOOLE_0:def 4;
then (the InternalRel of R -Seg a) /\ Y = ((the InternalRel of R -Seg a) /\ S) /\ Y by A8, Th5, XBOOLE_1:28
.= (the InternalRel of R -Seg a) /\ (Y /\ S) by XBOOLE_1:16 ;
then the InternalRel of R -Seg a misses Y by A11, XBOOLE_0:def 7;
hence ex b₁ being set st
( b₁ in Y & the InternalRel of R -Seg b₁ misses Y ) by A12; :: thesis: verum