let L be Semilattice; :: thesis: for l being Element of L holds
( l is prime iff for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a ) )
let l be Element of L; :: thesis: ( l is prime iff for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a ) )
thus ( l is prime implies for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a ) ) :: thesis: ( ( for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a ) ) implies l is prime )

proof

assume A1: for x, y being Element of L holds
( not l >= x "/\" y or l >= x or l >= y ) ; :: according to WAYBEL_6:def 6 :: thesis: for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a )
let A be non empty finite Subset of L; :: thesis: ( l >= inf A implies ex a being Element of L st
( a in A & l >= a ) )
A2: A is finite ;
defpred S₁[ set ] means ( not $1 is empty & l >= "/\" $1,L implies ex k being Element of L st
( k in $1 & l >= k ) );
A3: S₁[ {} ] ;

A4: now

let x, B be set ; :: thesis: ( x in A & B c= A & S₁[B] implies S₁[B \/ {x}] )
assume that
A5: ( x in A & B c= A ) and
A6: S₁[B] ; :: thesis: S₁[B \/ {x}]
thus S₁[B \/ {x}] :: thesis: verum

proof

assume A7: ( not B \/ {x} is empty & l >= "/\" (B \/ {x}),L ) ; :: thesis: ex k being Element of L st
( k in B \/ {x} & l >= k )
reconsider C = B as finite Subset of L by A5, XBOOLE_1:1;
reconsider a = x as Element of L by A5;

per cases ( B = {} or B <> {} ) ;

suppose B = {} ; :: thesis: ex k being Element of L st
( k in B \/ {x} & l >= k )

then ( "/\" (B \/ {a}),L = a & a in B \/ {a} ) by TARSKI:def 1, YELLOW_0:39;
hence ex k being Element of L st
( k in B \/ {x} & l >= k ) by A7; :: thesis: verum

end;

suppose A8: B <> {} ; :: thesis: ex k being Element of L st
( k in B \/ {x} & l >= k )

then ( ex_inf_of C,L & ex_inf_of {a},L ) by YELLOW_0:55;
then A9: ( "/\" (B \/ {x}),L = (inf C) "/\" (inf {a}) & inf {a} = a ) by YELLOW_0:39, YELLOW_2:4;

hereby :: thesis: verum

per cases ( inf C <= l or a <= l ) by A1, A7, A9;

suppose inf C <= l ; :: thesis: ex k being Element of L st
( k in B \/ {x} & l >= k )

then consider b being Element of L such that
A10: ( b in B & b <= l ) by A6, A8;
b in B \/ {x} by A10, XBOOLE_0:def 3;
hence ex k being Element of L st
( k in B \/ {x} & l >= k ) by A10; :: thesis: verum

end;

suppose A11: a <= l ; :: thesis: ex k being Element of L st
( k in B \/ {x} & l >= k )

a in {a} by TARSKI:def 1;
then a in B \/ {x} by XBOOLE_0:def 3;
hence ex k being Element of L st
( k in B \/ {x} & l >= k ) by A11; :: thesis: verum

end;

end;

end;

end;

end;

end;

end;

S₁[A] from FINSET_1:sch 2(A2, A3, A4);
hence ( l >= inf A implies ex a being Element of L st
( a in A & l >= a ) ) ; :: thesis: verum

end;

assume A12: for A being non empty finite Subset of L st l >= inf A holds
ex a being Element of L st
( a in A & l >= a ) ; :: thesis: l is prime
let a, b be Element of L; :: according to WAYBEL_6:def 6 :: thesis: ( not a "/\" b <= l or a <= l or b <= l )
assume A13: a "/\" b <= l ; :: thesis: ( a <= l or b <= l )
set A = {a,b};
inf {a,b} = a "/\" b by YELLOW_0:40;
then consider k being Element of L such that
A14: ( k in {a,b} & l >= k ) by A12, A13;
thus ( a <= l or b <= l ) by A14, TARSKI:def 2; :: thesis: verum