let S, T be non empty with_suprema Poset; :: thesis: for f being Function of S,T st f is directed-sups-preserving holds
f is monotone
let f be Function of S,T; :: thesis: ( f is directed-sups-preserving implies f is monotone )
assume A1: f is directed-sups-preserving ; :: thesis: f is monotone
let x, y be Element of S; :: according to ORDERS_3:def 5 :: thesis: ( not x <= y or for b₁, b₂ being Element of the carrier of T holds
( not b₁ = f . x or not b₂ = f . y or b₁ <= b₂ ) )
assume A2: x <= y ; :: thesis: for b₁, b₂ being Element of the carrier of T holds
( not b₁ = f . x or not b₂ = f . y or b₁ <= b₂ )
let afx, bfy be Element of T; :: thesis: ( not afx = f . x or not bfy = f . y or afx <= bfy )
assume A3: ( afx = f . x & bfy = f . y ) ; :: thesis: afx <= bfy
A4: y = y "\/" x by A2, YELLOW_0:24;
( x <= y & y <= y ) by A2;
then A5: {x,y} is_<=_than y by YELLOW_0:8;
for b being Element of S st {x,y} is_<=_than b holds
y <= b by YELLOW_0:8;
then A6: ex_sup_of {x,y},S by A5, YELLOW_0:30;
for a, b being Element of S st a in {x,y} & b in {x,y} holds
ex z being Element of S st
( z in {x,y} & a <= z & b <= z )

proof

let a, b be Element of S; :: thesis: ( a in {x,y} & b in {x,y} implies ex z being Element of S st
( z in {x,y} & a <= z & b <= z ) )
assume A7: ( a in {x,y} & b in {x,y} ) ; :: thesis: ex z being Element of S st
( z in {x,y} & a <= z & b <= z )
take y ; :: thesis: ( y in {x,y} & a <= y & b <= y )
thus y in {x,y} by TARSKI:def 2; :: thesis: ( a <= y & b <= y )
thus ( a <= y & b <= y ) by A2, A7, TARSKI:def 2; :: thesis: verum

end;

then ( {x,y} is directed & not {x,y} is empty ) by WAYBEL_0:def 1;
then f preserves_sup_of {x,y} by A1, WAYBEL_0:def 37;
then A8: sup (f .: {x,y}) = f . (sup {x,y}) by A6, WAYBEL_0:def 31
.= f . y by A4, YELLOW_0:41 ;
dom f = the carrier of S by FUNCT_2:def 1;
then f . y = sup {(f . x),(f . y)} by A8, FUNCT_1:118
.= (f . y) "\/" (f . x) by YELLOW_0:41 ;
hence afx <= bfy by A3, YELLOW_0:22; :: thesis: verum