let S, T be non empty reflexive antisymmetric RelStr ; :: thesis: for f being Function of S,T st f is directed-sups-preserving holds
f is monotone
let f be Function of S,T; :: thesis: ( f is directed-sups-preserving implies f is monotone )
assume A1: f is directed-sups-preserving ; :: thesis: f is monotone
let x, y be Element of S; :: according to WAYBEL_1:def 2 :: thesis: ( not x <= y or f . x <= f . y )
assume A2: x <= y ; :: thesis: f . x <= f . y
( x <= y & y <= y ) by A2;
then A3: {x,y} is_<=_than y by YELLOW_0:8;
for b being Element of S st {x,y} is_<=_than b holds
y <= b by YELLOW_0:8;
then A4: ( y = sup {x,y} & ex_sup_of {x,y},S ) by A3, YELLOW_0:30;
for a, b being Element of S st a in {x,y} & b in {x,y} holds
ex z being Element of S st
( z in {x,y} & a <= z & b <= z )

proof

let a, b be Element of S; :: thesis: ( a in {x,y} & b in {x,y} implies ex z being Element of S st
( z in {x,y} & a <= z & b <= z ) )
assume A5: ( a in {x,y} & b in {x,y} ) ; :: thesis: ex z being Element of S st
( z in {x,y} & a <= z & b <= z )
take y ; :: thesis: ( y in {x,y} & a <= y & b <= y )
thus y in {x,y} by TARSKI:def 2; :: thesis: ( a <= y & b <= y )
thus ( a <= y & b <= y ) by A2, A5, TARSKI:def 2; :: thesis: verum

end;

then ( {x,y} is directed & not {x,y} is empty ) by WAYBEL_0:def 1;
then A6: f preserves_sup_of {x,y} by A1, WAYBEL_0:def 37;
then A7: sup (f .: {x,y}) = f . y by A4, WAYBEL_0:def 31;
A8: dom f = the carrier of S by FUNCT_2:def 1;
then A9: f . y = sup {(f . x),(f . y)} by A7, FUNCT_1:118;
f .: {x,y} = {(f . x),(f . y)} by A8, FUNCT_1:118;
then ex_sup_of {(f . x),(f . y)},T by A4, A6, WAYBEL_0:def 31;
then {(f . x),(f . y)} is_<=_than f . y by A9, YELLOW_0:def 9;
hence f . x <= f . y by YELLOW_0:8; :: thesis: verum