let R be non empty right_complementable Abelian add-associative right_zeroed associative well-unital distributive doubleLoopStr ; :: thesis: for a being Element of R
for V being non empty right_complementable Abelian add-associative right_zeroed VectSp-like VectSpStr of R
for F, G being FinSequence of the carrier of V st len F = len G & ( for k being Element of NAT
for v being Element of V st k in dom F & v = G . k holds
F . k = a * v ) holds
Sum F = a * (Sum G)
let a be Element of R; :: thesis: for V being non empty right_complementable Abelian add-associative right_zeroed VectSp-like VectSpStr of R
for F, G being FinSequence of the carrier of V st len F = len G & ( for k being Element of NAT
for v being Element of V st k in dom F & v = G . k holds
F . k = a * v ) holds
Sum F = a * (Sum G)
let V be non empty right_complementable Abelian add-associative right_zeroed VectSp-like VectSpStr of R; :: thesis: for F, G being FinSequence of the carrier of V st len F = len G & ( for k being Element of NAT
for v being Element of V st k in dom F & v = G . k holds
F . k = a * v ) holds
Sum F = a * (Sum G)
let F, G be FinSequence of the carrier of V; :: thesis: ( len F = len G & ( for k being Element of NAT
for v being Element of V st k in dom F & v = G . k holds
F . k = a * v ) implies Sum F = a * (Sum G) )
defpred S₁[ Element of NAT ] means for H, I being FinSequence of the carrier of V st len H = len I & len H = $1 & ( for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ) holds
Sum H = a * (Sum I);
A1: S₁[ 0 ]

proof

let H, I be FinSequence of the carrier of V; :: thesis: ( len H = len I & len H = 0 & ( for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ) implies Sum H = a * (Sum I) )
assume that
A2: ( len H = len I & len H = 0 ) and
for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ; :: thesis: Sum H = a * (Sum I)
( H = <*> the carrier of V & I = <*> the carrier of V ) by A2, FINSEQ_1:32;
then ( Sum H = 0. V & Sum I = 0. V ) by RLVECT_1:60;
hence Sum H = a * (Sum I) by VECTSP_1:59; :: thesis: verum

end;

A3: for n being Element of NAT st S₁[n] holds
S₁[n + 1]

proof

let n be Element of NAT ; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume A4: for H, I being FinSequence of the carrier of V st len H = len I & len H = n & ( for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ) holds
Sum H = a * (Sum I) ; :: thesis: S₁[n + 1]
let H, I be FinSequence of the carrier of V; :: thesis: ( len H = len I & len H = n + 1 & ( for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ) implies Sum H = a * (Sum I) )
assume that
A5: len H = len I and
A6: len H = n + 1 and
A7: for k being Element of NAT
for v being Element of V st k in dom H & v = I . k holds
H . k = a * v ; :: thesis: Sum H = a * (Sum I)
reconsider p = H | (Seg n), q = I | (Seg n) as FinSequence of the carrier of V by FINSEQ_1:23;
A8: n <= n + 1 by NAT_1:12;
then A9: ( len p = n & len q = n ) by A5, A6, FINSEQ_1:21;

A10: now

let k be Element of NAT ; :: thesis: for v being Element of V st k in dom p & v = q . k holds
p . k = a * v
let v be Element of V; :: thesis: ( k in dom p & v = q . k implies p . k = a * v )
assume that
A11: k in dom p and
A12: v = q . k ; :: thesis: p . k = a * v
A13: dom p c= dom H by A6, A8, A9, FINSEQ_3:32;
dom q = dom p by A9, FINSEQ_3:31;
then I . k = q . k by A11, FUNCT_1:70;
then H . k = a * v by A7, A11, A12, A13;
hence p . k = a * v by A11, FUNCT_1:70; :: thesis: verum

end;

n + 1 in Seg (n + 1) by FINSEQ_1:6;
then A14: ( n + 1 in dom H & dom H = dom I ) by A5, A6, FINSEQ_1:def 3, FINSEQ_3:31;
then reconsider v1 = H . (n + 1), v2 = I . (n + 1) as Element of V by FINSEQ_2:13;
A15: v1 = a * v2 by A7, A14;
A16: ( p = H | (dom p) & q = I | (dom q) ) by A5, A6, A8, FINSEQ_1:21;
hence Sum H = (Sum p) + v1 by A6, A9, RLVECT_1:55
.= (a * (Sum q)) + (a * v2) by A4, A9, A10, A15
.= a * ((Sum q) + v2) by VECTSP_1:def 26
.= a * (Sum I) by A5, A6, A9, A16, RLVECT_1:55 ;
:: thesis: verum

end;

for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A1, A3);
hence ( len F = len G & ( for k being Element of NAT
for v being Element of V st k in dom F & v = G . k holds
F . k = a * v ) implies Sum F = a * (Sum G) ) ; :: thesis: verum