let T be TopSpace; :: thesis: LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is B_Lattice
set L = LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #);
LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is Lattice-like
proof
thus for a, b being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds a "\/" b = b "\/" a :: according to LATTICES:def 4,LATTICES:def 10 :: thesis: ( LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-associative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-absorbing & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-commutative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-associative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-absorbing )
proof
let a, b be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: a "\/" b = b "\/" a
reconsider A = a, B = b as Element of Closed_Domains_of T ;
thus a "\/" b = B \/ A by Def6
.= b "\/" a by Def6 ; :: thesis: verum
end;
thus for a, b, c being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds a "\/" (b "\/" c) = (a "\/" b) "\/" c :: according to LATTICES:def 5 :: thesis: ( LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-absorbing & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-commutative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-associative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-absorbing )
proof
let a, b, c be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: a "\/" (b "\/" c) = (a "\/" b) "\/" c
reconsider A = a, B = b, C = c as Element of Closed_Domains_of T ;
A1: b "\/" c = B \/ C by Def6;
A2: a "\/" b = A \/ B by Def6;
thus a "\/" (b "\/" c) = A \/ (B \/ C) by A1, Def6
.= (A \/ B) \/ C by XBOOLE_1:4
.= (a "\/" b) "\/" c by A2, Def6 ; :: thesis: verum
end;
thus for a, b being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds (a "/\" b) "\/" b = b :: according to LATTICES:def 8 :: thesis: ( LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-commutative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-associative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-absorbing )
proof
let a, b be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: (a "/\" b) "\/" b = b
reconsider A = a, B = b as Element of Closed_Domains_of T ;
A3: a "/\" b = Cl (Int (A /\ B)) by Def7;
B in { D where D is Subset of T : D is closed_condensed } ;
then ex D being Subset of T st
( D = B & D is closed_condensed ) ;
then A4: B = Cl (Int B) by TOPS_1:def 7;
Cl (Int (A /\ B)) = Cl ((Int A) /\ (Int B)) by TOPS_1:46;
then A5: ( Cl (Int (A /\ B)) c= (Cl (Int A)) /\ B & (Cl (Int A)) /\ B c= B ) by A4, PRE_TOPC:51, XBOOLE_1:17;
thus (a "/\" b) "\/" b = (Cl (Int (A /\ B))) \/ B by A3, Def6
.= b by A5, XBOOLE_1:1, XBOOLE_1:12 ; :: thesis: verum
end;
thus for a, b being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds a "/\" b = b "/\" a :: according to LATTICES:def 6 :: thesis: ( LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is meet-associative & LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-absorbing )
proof
let a, b be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: a "/\" b = b "/\" a
reconsider A = a, B = b as Element of Closed_Domains_of T ;
thus a "/\" b = Cl (Int (B /\ A)) by Def7
.= b "/\" a by Def7 ; :: thesis: verum
end;
thus for a, b, c being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds a "/\" (b "/\" c) = (a "/\" b) "/\" c :: according to LATTICES:def 7 :: thesis: LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is join-absorbing
proof
let a, b, c be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: a "/\" (b "/\" c) = (a "/\" b) "/\" c
reconsider A = a, B = b, C = c as Element of Closed_Domains_of T ;
( A in { D where D is Subset of T : D is closed_condensed } & B in { E where E is Subset of T : E is closed_condensed } & C in { F where F is Subset of T : F is closed_condensed } ) ;
then A6: ( ex D being Subset of T st
( D = A & D is closed_condensed ) & ex E being Subset of T st
( E = B & E is closed_condensed ) & ex F being Subset of T st
( F = C & F is closed_condensed ) ) ;
A7: b "/\" c = Cl (Int (B /\ C)) by Def7;
A8: a "/\" b = Cl (Int (A /\ B)) by Def7;
thus a "/\" (b "/\" c) = Cl (Int (A /\ (Cl (Int (B /\ C))))) by A7, Def7
.= Cl (Int ((Cl (Int (A /\ B))) /\ C)) by A6, Th28
.= (a "/\" b) "/\" c by A8, Def7 ; :: thesis: verum
end;
thus for a, b being Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) holds a "/\" (a "\/" b) = a :: according to LATTICES:def 9 :: thesis: verum
proof
let a, b be Element of LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #); :: thesis: a "/\" (a "\/" b) = a
reconsider A = a, B = b as Element of Closed_Domains_of T ;
A9: a "\/" b = A \/ B by Def6;
A in { D where D is Subset of T : D is closed_condensed } ;
then A10: ex D being Subset of T st
( D = A & D is closed_condensed ) ;
thus a "/\" (a "\/" b) = Cl (Int (A /\ (A \/ B))) by A9, Def7
.= Cl (Int A) by XBOOLE_1:21
.= a by A10, TOPS_1:def 7 ; :: thesis: verum
end;
end;
then reconsider L = LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) as Lattice ;
L is Boolean
proof
thus L is lower-bounded :: according to LATTICES:def 15,LATTICES:def 20 :: thesis: ( L is upper-bounded & L is complemented & L is distributive )
proof
A11: {} T is closed_condensed by Th18;
then {} T in { D where D is Subset of T : D is closed_condensed } ;
then reconsider c = {} T as Element of L ;
take c ; :: according to LATTICES:def 13 :: thesis: for b1 being Element of the carrier of L holds
( c "/\" b1 = c & b1 "/\" c = c )
let a be Element of L; :: thesis: ( c "/\" a = c & a "/\" c = c )
reconsider C = c, A = a as Element of Closed_Domains_of T ;
thus c "/\" a = Cl (Int (C /\ A)) by Def7
.= c by A11, TOPS_1:def 7 ; :: thesis: a "/\" c = c
hence a "/\" c = c ; :: thesis: verum
end;
thus L is upper-bounded :: thesis: ( L is complemented & L is distributive )
proof
[#] T is closed_condensed by Th19;
then [#] T in { D where D is Subset of T : D is closed_condensed } ;
then reconsider c = [#] T as Element of L ;
take c ; :: according to LATTICES:def 14 :: thesis: for b1 being Element of the carrier of L holds
( c "\/" b1 = c & b1 "\/" c = c )
let a be Element of L; :: thesis: ( c "\/" a = c & a "\/" c = c )
reconsider C = c, A = a as Element of Closed_Domains_of T ;
thus c "\/" a = C \/ A by Def6
.= c by XBOOLE_1:12 ; :: thesis: a "\/" c = c
hence a "\/" c = c ; :: thesis: verum
end;
thus L is complemented :: thesis: L is distributive
proof
let b be Element of L; :: according to LATTICES:def 19 :: thesis: ex b1 being Element of the carrier of L st b1 is_a_complement_of b
reconsider B = b as Element of Closed_Domains_of T ;
B in { D where D is Subset of T : D is closed_condensed } ;
then consider D being Subset of T such that
A12: ( D = B & D is closed_condensed ) ;
A13: ( D is condensed & D is closed ) by A12, TOPS_1:106;
then Cl (B ` ) is closed_condensed by A12, Th16, Th24;
then Cl (B ` ) in { K where K is Subset of T : K is closed_condensed } ;
then reconsider a = Cl (B ` ) as Element of L ;
take a ; :: thesis: a is_a_complement_of b
[#] T is closed_condensed by Th19;
then [#] T in { K where K is Subset of T : K is closed_condensed } ;
then reconsider c = [#] T as Element of L ;
A14: for v being Element of L holds the L_meet of L . c,v = v
proof
let v be Element of L; :: thesis: the L_meet of L . c,v = v
reconsider V = v as Element of Closed_Domains_of T ;
V in { K where K is Subset of T : K is closed_condensed } ;
then A15: ex D being Subset of T st
( D = V & D is closed_condensed ) ;
thus the L_meet of L . c,v = Cl (Int (([#] T) /\ V)) by Def7
.= Cl (Int V) by XBOOLE_1:28
.= v by A15, TOPS_1:def 7 ; :: thesis: verum
end;
thus a "\/" b = (Cl (B ` )) \/ B by Def6
.= (Cl (D ` )) \/ (Cl D) by A12, A13, PRE_TOPC:52
.= Cl ((B ` ) \/ B) by A12, PRE_TOPC:50
.= Cl ([#] T) by PRE_TOPC:18
.= c by TOPS_1:27
.= Top L by A14, LATTICE2:25 ; :: according to LATTICES:def 18 :: thesis: ( b "\/" a = Top L & a "/\" b = Bottom L & b "/\" a = Bottom L )
hence b "\/" a = Top L ; :: thesis: ( a "/\" b = Bottom L & b "/\" a = Bottom L )
{} T is closed_condensed by Th18;
then {} T in { K where K is Subset of T : K is closed_condensed } ;
then reconsider c = {} T as Element of L ;
A16: for v being Element of L holds the L_join of L . c,v = v
proof
let v be Element of L; :: thesis: the L_join of L . c,v = v
reconsider V = v as Element of Closed_Domains_of T ;
thus the L_join of L . c,v = ({} T) \/ V by Def6
.= (([#] T) ` ) \/ ((V ` ) ` ) by XBOOLE_1:37
.= (([#] T) /\ (V ` )) ` by XBOOLE_1:54
.= (V ` ) ` by XBOOLE_1:28
.= v ; :: thesis: verum
end;
thus a "/\" b = Cl (Int (B /\ (Cl (B ` )))) by Def7
.= Cl ({} T) by Th8
.= c by PRE_TOPC:52
.= Bottom L by A16, LATTICE2:22 ; :: thesis: b "/\" a = Bottom L
hence b "/\" a = Bottom L ; :: thesis: verum
end;
thus L is distributive :: thesis: verum
proof
let a, b, c be Element of L; :: according to LATTICES:def 11 :: thesis: a "/\" (b "\/" c) = (a "/\" b) "\/" (a "/\" c)
reconsider A = a, B = b, C = c as Element of Closed_Domains_of T ;
A17: ( A in { D where D is Subset of T : D is closed_condensed } & B in { E where E is Subset of T : E is closed_condensed } & C in { F where F is Subset of T : F is closed_condensed } ) ;
then consider D being Subset of T such that
A18: ( D = A & D is closed_condensed ) ;
consider E being Subset of T such that
A19: ( E = B & E is closed_condensed ) by A17;
consider F being Subset of T such that
A20: ( F = C & F is closed_condensed ) by A17;
( D is closed & E is closed & F is closed ) by A18, A19, A20, TOPS_1:106;
then A21: ( D /\ E is closed & D /\ F is closed ) by TOPS_1:35;
A22: b "\/" c = B \/ C by Def6;
A23: a "/\" b = Cl (Int (A /\ B)) by Def7;
A24: a "/\" c = Cl (Int (A /\ C)) by Def7;
thus a "/\" (b "\/" c) = Cl (Int (A /\ (B \/ C))) by A22, Def7
.= Cl (Int ((A /\ B) \/ (A /\ C))) by XBOOLE_1:23
.= (Cl (Int (A /\ B))) \/ (Cl (Int (A /\ C))) by A18, A19, A21, Th6
.= (a "/\" b) "\/" (a "/\" c) by A23, A24, Def6 ; :: thesis: verum
end;
end;
hence LattStr(# (Closed_Domains_of T),(CLD-Union T),(CLD-Meet T) #) is B_Lattice ; :: thesis: verum