let s be Real_Sequence; :: thesis: ( ( for n being Element of NAT holds s . n = n / ((n + 1) ! ) ) implies for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = 1 - (1 / ((n + 1) ! )) )
assume A1: for n being Element of NAT holds s . n = n / ((n + 1) ! ) ; :: thesis: for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = 1 - (1 / ((n + 1) ! ))
then A2: s . 0 = 0 / ((0 + 1) ! )
.= 0 ;
defpred S₁[ Nat] means (Partial_Sums s) . $1 = 1 - (1 / (($1 + 1) ! ));
(Partial_Sums s) . (1 + 0 ) = ((Partial_Sums s) . 0 ) + (s . (1 + 0 )) by SERIES_1:def 1
.= (s . 0 ) + (s . 1) by SERIES_1:def 1
.= 1 - (1 / ((1 + 1) ! )) by A1, A2, NEWTON:20 ;
then A3: S₁[1] ;
A4: for n being Nat st n >= 1 & S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( n >= 1 & S₁[n] implies S₁[n + 1] )
assume A5: ( n >= 1 & (Partial_Sums s) . n = 1 - (1 / ((n + 1) ! )) ) ; :: thesis: S₁[n + 1]
n + 2 >= 2 by NAT_1:11;
then A6: n + 2 > 0 by XXREAL_0:2;
n in NAT by ORDINAL1:def 13;
then (Partial_Sums s) . (n + 1) = (1 - (1 / ((n + 1) ! ))) + (s . (n + 1)) by A5, SERIES_1:def 1
.= (1 - (1 / ((n + 1) ! ))) + ((n + 1) / (((n + 1) + 1) ! )) by A1
.= (1 - ((1 * (n + 2)) / (((n + 1) ! ) * ((n + 1) + 1)))) + ((n + 1) / ((n + 2) ! )) by A6, XCMPLX_1:92
.= (1 - ((1 * (n + 2)) / (((n + 1) + 1) ! ))) + ((n + 1) / ((n + 2) ! )) by NEWTON:21
.= 1 - (((n + 2) / (((n + 1) + 1) ! )) - ((n + 1) / ((n + 2) ! )))
.= 1 - (((n + 2) - (n + 1)) / ((n + 2) ! )) by XCMPLX_1:121
.= 1 - (1 / (((n + 1) + 1) ! )) ;
hence S₁[n + 1] ; :: thesis: verum

end;

for n being Nat st n >= 1 holds
S₁[n] from NAT_1:sch 8(A3, A4);
hence for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = 1 - (1 / ((n + 1) ! )) ; :: thesis: verum