let s be Real_Sequence; :: thesis: ( ( for n being Element of NAT st n >= 1 holds
( s . n = 1 / (((2 * n) - 1) * ((2 * n) + 1)) & s . 0 = 0 ) ) implies for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1) )
assume A1: for n being Element of NAT st n >= 1 holds
( s . n = 1 / (((2 * n) - 1) * ((2 * n) + 1)) & s . 0 = 0 ) ; :: thesis: for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1)
defpred S₁[ Nat] means (Partial_Sums s) . $1 = $1 / ((2 * $1) + 1);
(Partial_Sums s) . (1 + 0 ) = ((Partial_Sums s) . 0 ) + (s . (1 + 0 )) by SERIES_1:def 1
.= (s . 0 ) + (s . 1) by SERIES_1:def 1
.= 0 + (s . 1) by A1
.= 1 / (((2 * 1) - 1) * ((2 * 1) + 1)) by A1
.= 1 / ((2 * 1) + 1) ;
then A2: S₁[1] ;
A3: for n being Nat st n >= 1 & S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( n >= 1 & S₁[n] implies S₁[n + 1] )
assume A4: ( n >= 1 & (Partial_Sums s) . n = n / ((2 * n) + 1) ) ; :: thesis: S₁[n + 1]
A5: n + 1 >= 1 by NAT_1:11;
( (2 * n) + 3 >= 3 & (2 * n) + 1 >= 1 ) by NAT_1:11;
then A6: ( (2 * n) + 3 > 0 & (2 * n) + 1 > 0 ) by XXREAL_0:2;
n in NAT by ORDINAL1:def 13;
then (Partial_Sums s) . (n + 1) = (n / ((2 * n) + 1)) + (s . (n + 1)) by A4, SERIES_1:def 1
.= (n / ((2 * n) + 1)) + (1 / (((2 * (n + 1)) - 1) * ((2 * (n + 1)) + 1))) by A1, A5
.= (n / ((2 * n) + 1)) + ((1 / ((2 * n) + 1)) * (1 / ((2 * n) + 3))) by XCMPLX_1:103
.= (n * (1 / ((2 * n) + 1))) + ((1 / ((2 * n) + 1)) * (1 / ((2 * n) + 3))) by XCMPLX_1:100
.= (n + (1 / ((2 * n) + 3))) * (1 / ((2 * n) + 1))
.= (((n * ((2 * n) + 3)) + 1) / ((2 * n) + 3)) * (1 / ((2 * n) + 1)) by A6, XCMPLX_1:114
.= (((n + 1) * ((2 * n) + 1)) / ((2 * n) + 3)) * (1 / ((2 * n) + 1))
.= (((2 * n) + 1) * ((n + 1) / ((2 * n) + 3))) * (1 / ((2 * n) + 1)) by XCMPLX_1:75
.= (n + 1) / ((2 * (n + 1)) + 1) by A6, XCMPLX_1:108 ;
hence S₁[n + 1] ; :: thesis: verum

end;

for n being Nat st n >= 1 holds
S₁[n] from NAT_1:sch 8(A2, A3);
hence for n being Element of NAT st n >= 1 holds
(Partial_Sums s) . n = n / ((2 * n) + 1) ; :: thesis: verum