let r be real number ; :: thesis: for seq being Real_Sequence st 0 <= r & ( for n being Element of NAT holds seq . n = 1 / ((n * n) + r) ) holds
lim seq = 0
let seq be Real_Sequence; :: thesis: ( 0 <= r & ( for n being Element of NAT holds seq . n = 1 / ((n * n) + r) ) implies lim seq = 0 )
assume that
A1: 0 <= r and
A2: for n being Element of NAT holds seq . n = 1 / ((n * n) + r) ; :: thesis: lim seq = 0
A3: seq is convergent by A1, A2, Th47;

now

let p be real number ; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((seq . m) - 0 ) < p )
assume A4: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((seq . m) - 0 ) < p
then A5: 0 < p " ;
consider k1 being Element of NAT such that
A6: p " < k1 by Th10;
take n = k1; :: thesis: for m being Element of NAT st n <= m holds
abs ((seq . m) - 0 ) < p
let m be Element of NAT ; :: thesis: ( n <= m implies abs ((seq . m) - 0 ) < p )
assume A7: n <= m ; :: thesis: abs ((seq . m) - 0 ) < p
( 0 <= n & 0 <= m ) by NAT_1:2;
then A8: n * n <= m * m by A7, XREAL_1:68;
A9: k1 > 0 by A4, A6;
then k1 >= 1 + 0 by NAT_1:13;
then k1 <= k1 * k1 by XREAL_1:153;
then A10: k1 + r <= (k1 * k1) + r by XREAL_1:8;
(p " ) + 0 < k1 + r by A1, A6, XREAL_1:10;
then (p " ) + 0 < (k1 * k1) + r by A10, XXREAL_0:2;
then 1 / ((k1 * k1) + r) < 1 / (p " ) by A5, XREAL_1:78;
then A11: 1 / ((k1 * k1) + r) < 1 * ((p " ) " ) by XCMPLX_0:def 9;
B12: 0 < n ^2 by A9, SQUARE_1:74;
(n * n) + r <= (m * m) + r by A8, XREAL_1:8;
then 1 / ((m * m) + r) <= 1 / ((n * n) + r) by A1, B12, XREAL_1:120;
then A13: 1 / ((m * m) + r) < p by A11, XXREAL_0:2;
A14: seq . m = 1 / ((m * m) + r) by A2;
0 <= m * m by NAT_1:2;
hence abs ((seq . m) - 0 ) < p by A13, A14, A1, ABSVALUE:def 1; :: thesis: verum

end;

hence lim seq = 0 by A3, SEQ_2:def 7; :: thesis: verum