let p, g be Real; :: thesis: ( p < g implies for f being PartFunc of REAL ,REAL st ].p,g.[ c= dom f & f is_differentiable_on ].p,g.[ & ( for x being Real st x in ].p,g.[ holds
diff f,x <= 0 ) holds
f | ].p,g.[ is non-increasing )
assume p < g ; :: thesis: for f being PartFunc of REAL ,REAL st ].p,g.[ c= dom f & f is_differentiable_on ].p,g.[ & ( for x being Real st x in ].p,g.[ holds
diff f,x <= 0 ) holds
f | ].p,g.[ is non-increasing
let f be PartFunc of REAL ,REAL ; :: thesis: ( ].p,g.[ c= dom f & f is_differentiable_on ].p,g.[ & ( for x being Real st x in ].p,g.[ holds
diff f,x <= 0 ) implies f | ].p,g.[ is non-increasing )
assume that
A0: ].p,g.[ c= dom f and
A1: f is_differentiable_on ].p,g.[ and
A2: for x being Real st x in ].p,g.[ holds
diff f,x <= 0 ; :: thesis: f | ].p,g.[ is non-increasing

now

let x1, x2 be Real; :: thesis: ( x1 in ].p,g.[ /\ (dom f) & x2 in ].p,g.[ /\ (dom f) & x1 < x2 implies f . x2 <= f . x1 )
assume that
A3: ( x1 in ].p,g.[ /\ (dom f) & x2 in ].p,g.[ /\ (dom f) ) and
A4: x1 < x2 ; :: thesis: f . x2 <= f . x1
A5: ( x1 in ].p,g.[ & x2 in ].p,g.[ ) by A3, XBOOLE_0:def 4;
reconsider Z = ].x1,x2.[ as open Subset of REAL ;
A6: [.x1,x2.] c= ].p,g.[ by A5, XXREAL_2:def 12;
A7: Z c= [.x1,x2.] by XXREAL_1:25;
then A8: Z c= ].p,g.[ by A6, XBOOLE_1:1;
A9: 0 <= x2 - x1 by A4, XREAL_1:52;
A10: 0 <> x2 - x1 by A4;
f | ].p,g.[ is continuous by A1, FDIFF_1:33;
then A11: f | [.x1,x2.] is continuous by A6, FCONT_1:17;
f is_differentiable_on Z by A1, A6, A7, FDIFF_1:34, XBOOLE_1:1;
then consider x0 being Real such that
A12: ( x0 in ].x1,x2.[ & diff f,x0 = ((f . x2) - (f . x1)) / (x2 - x1) ) by A4, A11, Th3, A6, A0, XBOOLE_1:1;
(((f . x2) - (f . x1)) / (x2 - x1)) * (x2 - x1) <= 0 * (x2 - x1) by A2, A8, A9, A12, XREAL_1:66;
then (f . x2) - (f . x1) <= 0 by A10, XCMPLX_1:88;
then f . x2 <= (f . x1) + 0 by XREAL_1:22;
hence f . x2 <= f . x1 ; :: thesis: verum

end;

hence f | ].p,g.[ is non-increasing by RFUNCT_2:46; :: thesis: verum