let G be non empty join-commutative join-associative Robbins ComplLattStr ; :: thesis: ( G is with_idempotent_element implies G is Huntington )
assume G is with_idempotent_element ; :: thesis: G is Huntington
then consider C being Element of G such that
A1: C + C = C by Def13;
assume not G is Huntington ; :: thesis: contradiction
then consider B, A being Element of G such that
A2: (- ((- B) + (- A))) + (- (B + (- A))) <> A by Def12;
A3: C = - ((- C) + (- (C + (- C)))) by A1, Def5;

A4: now

let x be Element of G; :: thesis: C + x = - ((- ((C + (- C)) + x)) + (- (C + x)))
thus C + x = - ((- ((- C) + (C + x))) + (- (C + (C + x)))) by Def5
.= - ((- (((- C) + C) + x)) + (- (C + (C + x)))) by LATTICES:def 5
.= - ((- ((C + (- C)) + x)) + (- (C + x))) by A1, LATTICES:def 5 ; :: thesis: verum

end;

A5: - (C + (- ((C + (- C)) + (- C)))) = - C by A3, Def5;
A6: C = - ((- (C + C)) + (- (((- C) + (- (C + (- C)))) + C))) by A3, Def5
.= - ((- C) + (- ((C + (- C)) + (- (C + (- C)))))) by A1, LATTICES:def 5 ;
set D = (C + (- C)) + (- C);
- ((- C) + (- ((C + (- C)) + (- C)))) = - ((- ((- ((C + (- C)) + (- C))) + C)) + (- ((C + C) + ((- C) + (- C))))) by A1, A5, LATTICES:def 5
.= - ((- ((- ((C + (- C)) + (- C))) + C)) + (- (C + (C + ((- C) + (- C)))))) by LATTICES:def 5
.= - ((- ((- ((C + (- C)) + (- C))) + C)) + (- (((C + (- C)) + (- C)) + C))) by LATTICES:def 5
.= C by Def5 ;
then - (C + (- C)) = - ((C + (- C)) + (- C)) by A5, Def5;
then A7: C = C + (- (C + (- C))) by A4, A5, A6;

A8: now

let x be Element of G; :: thesis: x = (- (C + (- C))) + x
thus x = - ((- ((C + (- (C + (- C)))) + x)) + (- (((- C) + (- (C + (- C)))) + x))) by A3, A7, Def5
.= - ((- (C + ((- (C + (- C))) + x))) + (- (((- C) + (- (C + (- C)))) + x))) by LATTICES:def 5
.= - ((- (C + ((- (C + (- C))) + x))) + (- ((- C) + ((- (C + (- C))) + x)))) by LATTICES:def 5
.= (- (C + (- C))) + x by Def5 ; :: thesis: verum

end;

A9: now

let x be Element of G; :: thesis: - (C + (- C)) = - ((- (- x)) + (- x))
thus - (C + (- C)) = - ((- ((- x) + (- (C + (- C))))) + (- (x + (- (C + (- C)))))) by Def5
.= - ((- (- x)) + (- (x + (- (C + (- C)))))) by A8
.= - ((- (- x)) + (- x)) by A8 ; :: thesis: verum

end;

A10: now

let x be Element of G; :: thesis: - (- x) = - (- (x + (- (- x))))
thus - (- x) = - ((- ((- x) + (- (- x)))) + (- (x + (- (- x))))) by Def5
.= - ((- (C + (- C))) + (- (x + (- (- x))))) by A9
.= - (- (x + (- (- x)))) by A8 ; :: thesis: verum

end;

A11: now

let x be Element of G; :: thesis: - x = - (- (- x))
thus - x = - ((- ((- (- (- x))) + (- x))) + (- ((- (- x)) + (- x)))) by Def5
.= - ((- ((- (- (- x))) + (- x))) + (- (C + (- C)))) by A9
.= - (- ((- (- (- x))) + (- x))) by A8
.= - (- (- x)) by A10 ; :: thesis: verum

end;

A12: now

let x, y be Element of G; :: thesis: y = - (- y)
thus y = - ((- ((- x) + y)) + (- (x + y))) by Def5
.= - (- (- ((- ((- x) + y)) + (- (x + y))))) by A11
.= - (- y) by Def5 ; :: thesis: verum

end;

now

let x, y be Element of G; :: thesis: (- ((- x) + y)) + (- (x + y)) = - y
thus (- ((- x) + y)) + (- (x + y)) = - (- ((- ((- x) + y)) + (- (x + y)))) by A12
.= - y by Def5 ; :: thesis: verum

end;

then (- ((- B) + (- A))) + (- (B + (- A))) = - (- A)
.= A by A12 ;
hence contradiction by A2; :: thesis: verum