let R be domRing; :: thesis: for V being RightMod of R
for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let V be RightMod of R; :: thesis: for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let A, B be Subset of V; :: thesis: Lin (A \/ B) = (Lin A) + (Lin B)
( Lin A is Submodule of Lin (A \/ B) & Lin B is Submodule of Lin (A \/ B) ) by Th15, XBOOLE_1:7;
then A1: (Lin A) + (Lin B) is Submodule of Lin (A \/ B) by RMOD_3:40;

now

let v be Vector of V; :: thesis: ( v in Lin (A \/ B) implies v in (Lin A) + (Lin B) )
assume v in Lin (A \/ B) ; :: thesis: v in (Lin A) + (Lin B)
then consider l being Linear_Combination of A \/ B such that
A2: v = Sum l by Th9;
set C = (Carrier l) /\ A;
set D = (Carrier l) \ A;
defpred S₁[ set ] means $1 in (Carrier l) /\ A;
deffunc H₁( set ) -> set = l . $1;
deffunc H₂( set ) -> Element of the carrier of R = 0. R;
A3: for x being set st x in the carrier of V holds
( ( S₁[x] implies H₁(x) in the carrier of R ) & ( not S₁[x] implies H₂(x) in the carrier of R ) )

proof

now

let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) /\ A implies l . x in the carrier of R ) & ( not x in (Carrier l) /\ A implies 0. R in the carrier of R ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) /\ A implies l . x in the carrier of R ) & ( not x in (Carrier l) /\ A implies 0. R in the carrier of R ) )
then reconsider v = x as Vector of V ;
for f being Function of the carrier of V,the carrier of R holds f . v in the carrier of R ;
hence ( x in (Carrier l) /\ A implies l . x in the carrier of R ) ; :: thesis: ( not x in (Carrier l) /\ A implies 0. R in the carrier of R )
assume not x in (Carrier l) /\ A ; :: thesis: 0. R in the carrier of R
thus 0. R in the carrier of R ; :: thesis: verum

end;

hence for x being set st x in the carrier of V holds
( ( S₁[x] implies H₁(x) in the carrier of R ) & ( not S₁[x] implies H₂(x) in the carrier of R ) ) ; :: thesis: verum

end;

consider f being Function of the carrier of V,the carrier of R such that
A4: for x being set st x in the carrier of V holds
( ( S₁[x] implies f . x = H₁(x) ) & ( not S₁[x] implies f . x = H₂(x) ) ) from FUNCT_2:sch 5(A3);
reconsider f = f as Element of Funcs the carrier of V,the carrier of R by FUNCT_2:11;
defpred S₂[ set ] means $1 in (Carrier l) \ A;
A5: for x being set st x in the carrier of V holds
( ( S₂[x] implies H₁(x) in the carrier of R ) & ( not S₂[x] implies H₂(x) in the carrier of R ) )

proof

now

let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) \ A implies l . x in the carrier of R ) & ( not x in (Carrier l) \ A implies 0. R in the carrier of R ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) \ A implies l . x in the carrier of R ) & ( not x in (Carrier l) \ A implies 0. R in the carrier of R ) )
then reconsider v = x as Vector of V ;
for g being Function of the carrier of V,the carrier of R holds g . v in the carrier of R ;
hence ( x in (Carrier l) \ A implies l . x in the carrier of R ) ; :: thesis: ( not x in (Carrier l) \ A implies 0. R in the carrier of R )
assume not x in (Carrier l) \ A ; :: thesis: 0. R in the carrier of R
thus 0. R in the carrier of R ; :: thesis: verum

end;

hence for x being set st x in the carrier of V holds
( ( S₂[x] implies H₁(x) in the carrier of R ) & ( not S₂[x] implies H₂(x) in the carrier of R ) ) ; :: thesis: verum

end;

consider g being Function of the carrier of V,the carrier of R such that
A6: for x being set st x in the carrier of V holds
( ( S₂[x] implies g . x = H₁(x) ) & ( not S₂[x] implies g . x = H₂(x) ) ) from FUNCT_2:sch 5(A5);
reconsider g = g as Element of Funcs the carrier of V,the carrier of R by FUNCT_2:11;
reconsider C = (Carrier l) /\ A as finite Subset of V ;
for u being Vector of V st not u in C holds
f . u = 0. R by A4;
then reconsider f = f as Linear_Combination of V by Def4;
A7: Carrier f c= C

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in C )
assume x in Carrier f ; :: thesis: x in C
then A8: ex u being Vector of V st
( x = u & f . u <> 0. R ) ;
assume not x in C ; :: thesis: contradiction
hence contradiction by A4, A8; :: thesis: verum

end;

C c= A by XBOOLE_1:17;
then Carrier f c= A by A7, XBOOLE_1:1;
then reconsider f = f as Linear_Combination of A by Def7;
reconsider D = (Carrier l) \ A as finite Subset of V ;
for u being Vector of V st not u in D holds
g . u = 0. R by A6;
then reconsider g = g as Linear_Combination of V by Def4;
A9: Carrier g c= D

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier g or x in D )
assume x in Carrier g ; :: thesis: x in D
then A10: ex u being Vector of V st
( x = u & g . u <> 0. R ) ;
assume not x in D ; :: thesis: contradiction
hence contradiction by A6, A10; :: thesis: verum

end;

D c= B

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in D or x in B )
assume x in D ; :: thesis: x in B
then ( x in Carrier l & not x in A & Carrier l c= A \/ B ) by Def7, XBOOLE_0:def 5;
hence x in B by XBOOLE_0:def 3; :: thesis: verum

end;

then Carrier g c= B by A9, XBOOLE_1:1;
then reconsider g = g as Linear_Combination of B by Def7;
l = f + g

proof

let v be Vector of V; :: according to RMOD_4:def 10 :: thesis: l . v = (f + g) . v

now

per cases ( v in C or not v in C ) ;

suppose A11: v in C ; :: thesis: (f + g) . v = l . v

A12: now

assume v in D ; :: thesis: contradiction
then not v in A by XBOOLE_0:def 5;
hence contradiction by A11, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by Def11
.= (l . v) + (g . v) by A4, A11
.= (l . v) + (0. R) by A6, A12
.= l . v by RLVECT_1:10 ; :: thesis: verum

end;

suppose A13: not v in C ; :: thesis: l . v = (f + g) . v

now

per cases ( v in Carrier l or not v in Carrier l ) ;

suppose A14: v in Carrier l ; :: thesis: (f + g) . v = l . v

A15: now

assume not v in D ; :: thesis: contradiction
then ( not v in Carrier l or v in A ) by XBOOLE_0:def 5;
hence contradiction by A13, A14, XBOOLE_0:def 4; :: thesis: verum

end;

thus (f + g) . v = (f . v) + (g . v) by Def11
.= (0. R) + (g . v) by A4, A13
.= g . v by RLVECT_1:10
.= l . v by A6, A15 ; :: thesis: verum

end;

suppose A16: not v in Carrier l ; :: thesis: (f + g) . v = l . v

then A17: ( not v in C & not v in D ) by XBOOLE_0:def 4, XBOOLE_0:def 5;
thus (f + g) . v = (f . v) + (g . v) by Def11
.= (0. R) + (g . v) by A4, A17
.= (0. R) + (0. R) by A6, A17
.= 0. R by RLVECT_1:10
.= l . v by A16 ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

end;

end;

hence l . v = (f + g) . v ; :: thesis: verum

end;

then A18: v = (Sum f) + (Sum g) by A2, Th77;
( Sum f in Lin A & Sum g in Lin B ) by Th9;
hence v in (Lin A) + (Lin B) by A18, RMOD_3:5; :: thesis: verum

end;

then Lin (A \/ B) is Submodule of (Lin A) + (Lin B) by RMOD_2:36;
hence Lin (A \/ B) = (Lin A) + (Lin B) by A1, RMOD_2:33; :: thesis: verum