let R be Ring; :: thesis: for V being RightMod of R
for W1, W2 being Submodule of V holds
( V is_the_direct_sum_of W1,W2 iff for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} )
let V be RightMod of R; :: thesis: for W1, W2 being Submodule of V holds
( V is_the_direct_sum_of W1,W2 iff for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} )
let W1, W2 be Submodule of V; :: thesis: ( V is_the_direct_sum_of W1,W2 iff for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} )
set VW1 = the carrier of W1;
set VW2 = the carrier of W2;
A1: ( the carrier of W1 is Coset of W1 & the carrier of W2 is Coset of W2 ) by RMOD_2:86;
thus ( V is_the_direct_sum_of W1,W2 implies for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} ) :: thesis: ( ( for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} ) implies V is_the_direct_sum_of W1,W2 )

proof

assume A2: V is_the_direct_sum_of W1,W2 ; :: thesis: for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v}
let C1 be Coset of W1; :: thesis: for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v}
let C2 be Coset of W2; :: thesis: ex v being Vector of V st C1 /\ C2 = {v}
consider v1 being Vector of V such that
A3: C1 = v1 + W1 by RMOD_2:def 6;
consider v2 being Vector of V such that
A4: C2 = v2 + W2 by RMOD_2:def 6;
A5: RightModStr(# the carrier of V,the U7 of V,the U2 of V,the rmult of V #) = W1 + W2 by A2, Def4;
v1 in (Omega). V by RLVECT_1:3;
then consider v11, v12 being Vector of V such that
A6: v11 in W1 and
A7: v12 in W2 and
A8: v1 = v11 + v12 by A5, Th5;
v2 in (Omega). V by RLVECT_1:3;
then consider v21, v22 being Vector of V such that
A9: v21 in W1 and
A10: v22 in W2 and
A11: v2 = v21 + v22 by A5, Th5;
take v = v12 + v21; :: thesis: C1 /\ C2 = {v}
{v} = C1 /\ C2

proof

thus A12: {v} c= C1 /\ C2 :: according to XBOOLE_0:def 10 :: thesis: C1 /\ C2 c= {v}

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in {v} or x in C1 /\ C2 )
assume x in {v} ; :: thesis: x in C1 /\ C2
then A13: x = v by TARSKI:def 1;
v12 = v1 - v11 by A8, Lm15;
then v12 in C1 by A3, A6, RMOD_2:75;
then C1 = v12 + W1 by RMOD_2:90;
then A14: x in C1 by A9, A13;
v21 = v2 - v22 by A11, Lm15;
then v21 in C2 by A4, A10, RMOD_2:75;
then ( C2 = v21 + W2 & v = v21 + v12 ) by RMOD_2:90;
then x in C2 by A7, A13;
hence x in C1 /\ C2 by A14, XBOOLE_0:def 4; :: thesis: verum

end;

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in C1 /\ C2 or x in {v} )
assume A15: x in C1 /\ C2 ; :: thesis: x in {v}
then C1 meets C2 by XBOOLE_0:4;
then reconsider C = C1 /\ C2 as Coset of W1 /\ W2 by Th48;
W1 /\ W2 = (0). V by A2, Def4;
then A16: ex u being Vector of V st C = {u} by RMOD_2:85;
v in {v} by TARSKI:def 1;
hence x in {v} by A12, A15, A16, TARSKI:def 1; :: thesis: verum
thus verum ; :: thesis: verum

end;

hence C1 /\ C2 = {v} ; :: thesis: verum

end;

assume A17: for C1 being Coset of W1
for C2 being Coset of W2 ex v being Vector of V st C1 /\ C2 = {v} ; :: thesis: V is_the_direct_sum_of W1,W2
A18: ( W1 + W2 is Submodule of (Omega). V & RightModStr(# the carrier of V,the U7 of V,the U2 of V,the rmult of V #) = (Omega). V ) by Lm5;
the carrier of V = the carrier of (W1 + W2)

proof

thus the carrier of V c= the carrier of (W1 + W2) :: according to XBOOLE_0:def 10 :: thesis: the carrier of (W1 + W2) c= the carrier of V

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in the carrier of V or x in the carrier of (W1 + W2) )
assume x in the carrier of V ; :: thesis: x in the carrier of (W1 + W2)
then reconsider u = x as Vector of V ;
consider C1 being Coset of W1 such that
A19: u in C1 by RMOD_2:81;
consider v being Vector of V such that
A20: C1 /\ the carrier of W2 = {v} by A1, A17;
A21: v in {v} by TARSKI:def 1;
then v in the carrier of W2 by A20, XBOOLE_0:def 4;
then A22: v in W2 by STRUCT_0:def 5;
v in C1 by A20, A21, XBOOLE_0:def 4;
then consider v1 being Vector of V such that
A23: v1 in W1 and
A24: u - v1 = v by A19, RMOD_2:92;
u = v1 + v by A24, Lm15;
then x in W1 + W2 by A22, A23, Th5;
hence x in the carrier of (W1 + W2) by STRUCT_0:def 5; :: thesis: verum

end;

thus the carrier of (W1 + W2) c= the carrier of V by RMOD_2:def 2; :: thesis: verum

end;

hence RightModStr(# the carrier of V,the U7 of V,the U2 of V,the rmult of V #) = W1 + W2 by A18, RMOD_2:39; :: according to RMOD_3:def 4 :: thesis: W1 /\ W2 = (0). V
consider v being Vector of V such that
A25: the carrier of W1 /\ the carrier of W2 = {v} by A1, A17;
( 0. V in W1 & 0. V in W2 ) by RMOD_2:25;
then ( 0. V in the carrier of W1 & 0. V in the carrier of W2 ) by STRUCT_0:def 5;
then A26: 0. V in {v} by A25, XBOOLE_0:def 4;
the carrier of ((0). V) = {(0. V)} by RMOD_2:def 3
.= the carrier of W1 /\ the carrier of W2 by A25, A26, TARSKI:def 1
.= the carrier of (W1 /\ W2) by Def2 ;
hence W1 /\ W2 = (0). V by RMOD_2:37; :: thesis: verum