let V be RealLinearSpace; :: thesis: for A, B being finite Subset of V
for v being VECTOR of V st v in Lin (A \/ B) & not v in Lin B holds
ex w being VECTOR of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
let A, B be finite Subset of V; :: thesis: for v being VECTOR of V st v in Lin (A \/ B) & not v in Lin B holds
ex w being VECTOR of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
let v be VECTOR of V; :: thesis: ( v in Lin (A \/ B) & not v in Lin B implies ex w being VECTOR of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) ) )
assume that
A1: v in Lin (A \/ B) and
A2: not v in Lin B ; :: thesis: ex w being VECTOR of V st
( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
consider L being Linear_Combination of A \/ B such that
A3: v = Sum L by A1, RLVECT_3:17;
A4: Carrier L c= A \/ B by RLVECT_2:def 8;

now

assume A5: for w being VECTOR of V st w in A holds
L . w = 0 ; :: thesis: contradiction

now

let x be set ; :: thesis: ( x in Carrier L implies not x in A )
assume A6: ( x in Carrier L & x in A ) ; :: thesis: contradiction
then ex u being VECTOR of V st
( x = u & L . u <> 0 ) by Th3;
hence contradiction by A5, A6; :: thesis: verum

end;

then Carrier L misses A by XBOOLE_0:3;
then Carrier L c= B by A4, XBOOLE_1:73;
then L is Linear_Combination of B by RLVECT_2:def 8;
hence contradiction by A2, A3, RLVECT_3:17; :: thesis: verum

end;

then consider w being VECTOR of V such that
A7: w in A and
A8: L . w <> 0 ;
take w ; :: thesis: ( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) )
set a = L . w;
consider F being FinSequence of the carrier of V such that
A9: F is one-to-one and
A10: rng F = Carrier L and
A11: Sum L = Sum (L (#) F) by RLVECT_2:def 10;
A12: w in Carrier L by A8, Th3;
then A13: F = ((F -| w) ^ <*w*>) ^ (F |-- w) by A10, FINSEQ_4:66;
reconsider Fw1 = F -| w as FinSequence of the carrier of V by A10, A12, FINSEQ_4:53;
reconsider Fw2 = F |-- w as FinSequence of the carrier of V by A10, A12, FINSEQ_4:65;
F = Fw1 ^ (<*w*> ^ Fw2) by A13, FINSEQ_1:45;
then L (#) F = (L (#) Fw1) ^ (L (#) (<*w*> ^ Fw2)) by RLVECT_3:41
.= (L (#) Fw1) ^ ((L (#) <*w*>) ^ (L (#) Fw2)) by RLVECT_3:41
.= ((L (#) Fw1) ^ (L (#) <*w*>)) ^ (L (#) Fw2) by FINSEQ_1:45
.= ((L (#) Fw1) ^ <*((L . w) * w)*>) ^ (L (#) Fw2) by RLVECT_2:42 ;
then A14: Sum (L (#) F) = Sum ((L (#) Fw1) ^ (<*((L . w) * w)*> ^ (L (#) Fw2))) by FINSEQ_1:45
.= (Sum (L (#) Fw1)) + (Sum (<*((L . w) * w)*> ^ (L (#) Fw2))) by RLVECT_1:58
.= (Sum (L (#) Fw1)) + ((Sum <*((L . w) * w)*>) + (Sum (L (#) Fw2))) by RLVECT_1:58
.= (Sum (L (#) Fw1)) + ((Sum (L (#) Fw2)) + ((L . w) * w)) by RLVECT_1:61
.= ((Sum (L (#) Fw1)) + (Sum (L (#) Fw2))) + ((L . w) * w) by RLVECT_1:def 6
.= (Sum ((L (#) Fw1) ^ (L (#) Fw2))) + ((L . w) * w) by RLVECT_1:58
.= (Sum (L (#) (Fw1 ^ Fw2))) + ((L . w) * w) by RLVECT_3:41 ;
set Fw = Fw1 ^ Fw2;
consider K being Linear_Combination of V such that
A15: ( Carrier K = (rng (Fw1 ^ Fw2)) /\ (Carrier L) & L (#) (Fw1 ^ Fw2) = K (#) (Fw1 ^ Fw2) ) by Th8;
F just_once_values w by A9, A10, A12, FINSEQ_4:10;
then A16: Fw1 ^ Fw2 = F - {w} by FINSEQ_4:69;
then A17: rng (Fw1 ^ Fw2) = (rng F) \ {w} by FINSEQ_3:72;
A18: rng (Fw1 ^ Fw2) = (Carrier L) \ {w} by A10, A16, FINSEQ_3:72;
A19: Carrier K = rng (Fw1 ^ Fw2) by A10, A15, A17, XBOOLE_1:28;
A20: (Carrier L) \ {w} c= (A \/ B) \ {w} by A4, XBOOLE_1:33;
then reconsider K = K as Linear_Combination of (A \/ B) \ {w} by A18, A19, RLVECT_2:def 8;
( Fw1 is one-to-one & Fw2 is one-to-one & rng Fw1 misses rng Fw2 ) by A9, A10, A12, FINSEQ_4:67, FINSEQ_4:68, FINSEQ_4:72;
then Fw1 ^ Fw2 is one-to-one by FINSEQ_3:98;
then Sum (K (#) (Fw1 ^ Fw2)) = Sum K by A19, RLVECT_2:def 10;
then ((L . w) " ) * v = (((L . w) " ) * (Sum K)) + (((L . w) " ) * ((L . w) * w)) by A3, A11, A14, A15, RLVECT_1:def 9
.= (((L . w) " ) * (Sum K)) + ((((L . w) " ) * (L . w)) * w) by RLVECT_1:def 9
.= (((L . w) " ) * (Sum K)) + (1 * w) by A8, XCMPLX_0:def 7
.= (((L . w) " ) * (Sum K)) + w by RLVECT_1:def 9 ;
then A21: w = (((L . w) " ) * v) - (((L . w) " ) * (Sum K)) by RLSUB_2:78
.= ((L . w) " ) * (v - (Sum K)) by RLVECT_1:48
.= ((L . w) " ) * ((- (Sum K)) + v) by RLVECT_1:def 12 ;
v in {v} by TARSKI:def 1;
then v in Lin {v} by RLVECT_3:18;
then consider Lv being Linear_Combination of {v} such that
A22: v = Sum Lv by RLVECT_3:17;
A23: w = ((L . w) " ) * ((Sum (- K)) + (Sum Lv)) by A21, A22, RLVECT_3:3
.= ((L . w) " ) * (Sum ((- K) + Lv)) by RLVECT_3:1
.= Sum (((L . w) " ) * ((- K) + Lv)) by RLVECT_3:2 ;
A24: (L . w) " <> 0 by A8, XCMPLX_1:203;
set LC = ((L . w) " ) * ((- K) + Lv);
A25: Carrier (((L . w) " ) * ((- K) + Lv)) = Carrier ((- K) + Lv) by A24, RLVECT_2:65;
A26: Carrier Lv c= {v} by RLVECT_2:def 8;
Carrier ((- K) + Lv) c= (Carrier (- K)) \/ (Carrier Lv) by RLVECT_2:58;
then A27: Carrier ((- K) + Lv) c= (Carrier K) \/ (Carrier Lv) by RLVECT_2:75;
(Carrier K) \/ (Carrier Lv) c= ((A \/ B) \ {w}) \/ {v} by A18, A19, A20, A26, XBOOLE_1:13;
then Carrier ((- K) + Lv) c= ((A \/ B) \ {w}) \/ {v} by A27, XBOOLE_1:1;
then ((L . w) " ) * ((- K) + Lv) is Linear_Combination of ((A \/ B) \ {w}) \/ {v} by A25, RLVECT_2:def 8;
hence ( w in A & w in Lin (((A \/ B) \ {w}) \/ {v}) ) by A7, A23, RLVECT_3:17; :: thesis: verum