let V be RealLinearSpace; :: thesis: for A being Subset of V st A is linearly-independent holds
for v being VECTOR of V st v in A holds
for B being Subset of V st B = A \ {v} holds
not v in Lin B
let A be Subset of V; :: thesis: ( A is linearly-independent implies for v being VECTOR of V st v in A holds
for B being Subset of V st B = A \ {v} holds
not v in Lin B )
assume A1: A is linearly-independent ; :: thesis: for v being VECTOR of V st v in A holds
for B being Subset of V st B = A \ {v} holds
not v in Lin B
let v be VECTOR of V; :: thesis: ( v in A implies for B being Subset of V st B = A \ {v} holds
not v in Lin B )
assume A2: v in A ; :: thesis: for B being Subset of V st B = A \ {v} holds
not v in Lin B
let B be Subset of V; :: thesis: ( B = A \ {v} implies not v in Lin B )
assume A3: B = A \ {v} ; :: thesis: not v in Lin B
assume v in Lin B ; :: thesis: contradiction
then consider L being Linear_Combination of B such that
A4: v = Sum L by RLVECT_3:17;
v in {v} by TARSKI:def 1;
then v in Lin {v} by RLVECT_3:18;
then consider K being Linear_Combination of {v} such that
A5: v = Sum K by RLVECT_3:17;
A6: 0. V = (Sum L) + (- (Sum K)) by A4, A5, RLVECT_1:16
.= (Sum L) + (Sum (- K)) by RLVECT_3:3
.= Sum (L + (- K)) by RLVECT_3:1
.= Sum (L - K) by RLVECT_2:def 15 ;
A7: {v} is Subset of A by A2, SUBSET_1:63;
then A8: ( {v} c= A & B c= A ) by A3, XBOOLE_1:36;
{v} is linearly-independent by A1, A7, RLVECT_3:6;
then v <> 0. V by RLVECT_3:9;
then not Carrier L is empty by A4, RLVECT_2:52;
then consider w being set such that
A9: w in Carrier L by XBOOLE_0:def 1;
A10: Carrier (L - K) c= (Carrier L) \/ (Carrier K) by RLVECT_2:80;
A11: ( Carrier L c= B & Carrier K c= {v} ) by RLVECT_2:def 8;
then A12: (Carrier L) \/ (Carrier K) c= B \/ {v} by XBOOLE_1:13;
B \/ {v} c= A \/ A by A8, XBOOLE_1:13;
then (Carrier L) \/ (Carrier K) c= A by A12, XBOOLE_1:1;
then Carrier (L - K) c= A by A10, XBOOLE_1:1;
then A13: L - K is Linear_Combination of A by RLVECT_2:def 8;
A14: for x being VECTOR of V st x in Carrier L holds
K . x = 0

proof

let x be VECTOR of V; :: thesis: ( x in Carrier L implies K . x = 0 )
assume x in Carrier L ; :: thesis: K . x = 0
then not x in Carrier K by A3, A11, XBOOLE_0:def 5;
hence K . x = 0 by RLVECT_2:28; :: thesis: verum

end;

now

let x be set ; :: thesis: ( x in Carrier L implies x in Carrier (L - K) )
assume that
A15: x in Carrier L and
A16: not x in Carrier (L - K) ; :: thesis: contradiction
reconsider x = x as VECTOR of V by A15;
A17: L . x <> 0 by A15, RLVECT_2:28;
(L - K) . x = (L . x) - (K . x) by RLVECT_2:79
.= (L . x) - 0 by A14, A15
.= L . x ;
hence contradiction by A16, A17, RLVECT_2:28; :: thesis: verum

end;

then not Carrier (L - K) is empty by A9;
hence contradiction by A1, A6, A13, RLVECT_3:def 1; :: thesis: verum