let V be RealLinearSpace; :: thesis: for A, B being Subset of V holds Lin (A \/ B) = (Lin A) + (Lin B)
let A, B be Subset of V; :: thesis: Lin (A \/ B) = (Lin A) + (Lin B)
( Lin A is Subspace of Lin (A \/ B) & Lin B is Subspace of Lin (A \/ B) ) by Th23, XBOOLE_1:7;
then A1: (Lin A) + (Lin B) is Subspace of Lin (A \/ B) by Lm6;
now
let v be VECTOR of V; :: thesis: ( v in Lin (A \/ B) implies v in (Lin A) + (Lin B) )
assume v in Lin (A \/ B) ; :: thesis: v in (Lin A) + (Lin B)
then consider l being Linear_Combination of A \/ B such that
A2: v = Sum l by Th17;
set C = (Carrier l) /\ A;
set D = (Carrier l) \ A;
defpred S1[ set ] means $1 in (Carrier l) /\ A;
deffunc H1( set ) -> set = l . $1;
deffunc H2( set ) -> Element of NAT = 0 ;
A3: for x being set st x in the carrier of V holds
( ( S1[x] implies H1(x) in REAL ) & ( not S1[x] implies H2(x) in REAL ) )
proof
now
let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) /\ A implies l . x in REAL ) & ( not x in (Carrier l) /\ A implies 0 in REAL ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) /\ A implies l . x in REAL ) & ( not x in (Carrier l) /\ A implies 0 in REAL ) )
then reconsider v = x as VECTOR of V ;
for f being Function of the carrier of V,REAL holds f . v in REAL ;
hence ( x in (Carrier l) /\ A implies l . x in REAL ) ; :: thesis: ( not x in (Carrier l) /\ A implies 0 in REAL )
assume not x in (Carrier l) /\ A ; :: thesis: 0 in REAL
thus 0 in REAL ; :: thesis: verum
end;
hence for x being set st x in the carrier of V holds
( ( S1[x] implies H1(x) in REAL ) & ( not S1[x] implies H2(x) in REAL ) ) ; :: thesis: verum
end;
consider f being Function of the carrier of V,REAL such that
A4: for x being set st x in the carrier of V holds
( ( S1[x] implies f . x = H1(x) ) & ( not S1[x] implies f . x = H2(x) ) ) from FUNCT_2:sch 5(A3);
reconsider f = f as Element of Funcs the carrier of V,REAL by FUNCT_2:11;
defpred S2[ set ] means $1 in (Carrier l) \ A;
A5: for x being set st x in the carrier of V holds
( ( S2[x] implies H1(x) in REAL ) & ( not S2[x] implies H2(x) in REAL ) )
proof
now
let x be set ; :: thesis: ( x in the carrier of V implies ( ( x in (Carrier l) \ A implies l . x in REAL ) & ( not x in (Carrier l) \ A implies 0 in REAL ) ) )
assume x in the carrier of V ; :: thesis: ( ( x in (Carrier l) \ A implies l . x in REAL ) & ( not x in (Carrier l) \ A implies 0 in REAL ) )
then reconsider v = x as VECTOR of V ;
for g being Function of the carrier of V,REAL holds g . v in REAL ;
hence ( x in (Carrier l) \ A implies l . x in REAL ) ; :: thesis: ( not x in (Carrier l) \ A implies 0 in REAL )
assume not x in (Carrier l) \ A ; :: thesis: 0 in REAL
thus 0 in REAL ; :: thesis: verum
end;
hence for x being set st x in the carrier of V holds
( ( S2[x] implies H1(x) in REAL ) & ( not S2[x] implies H2(x) in REAL ) ) ; :: thesis: verum
end;
consider g being Function of the carrier of V,REAL such that
A6: for x being set st x in the carrier of V holds
( ( S2[x] implies g . x = H1(x) ) & ( not S2[x] implies g . x = H2(x) ) ) from FUNCT_2:sch 5(A5);
reconsider g = g as Element of Funcs the carrier of V,REAL by FUNCT_2:11;
reconsider C = (Carrier l) /\ A as finite Subset of V ;
for u being VECTOR of V st not u in C holds
f . u = 0 by A4;
then reconsider f = f as Linear_Combination of V by RLVECT_2:def 5;
A7: Carrier f c= C
proof
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in C )
assume x in Carrier f ; :: thesis: x in C
then A8: ex u being VECTOR of V st
( x = u & f . u <> 0 ) ;
assume not x in C ; :: thesis: contradiction
hence contradiction by A4, A8; :: thesis: verum
end;
C c= A by XBOOLE_1:17;
then Carrier f c= A by A7, XBOOLE_1:1;
then reconsider f = f as Linear_Combination of A by RLVECT_2:def 8;
reconsider D = (Carrier l) \ A as finite Subset of V ;
for u being VECTOR of V st not u in D holds
g . u = 0 by A6;
then reconsider g = g as Linear_Combination of V by RLVECT_2:def 5;
A9: Carrier g c= D
proof
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier g or x in D )
assume x in Carrier g ; :: thesis: x in D
then A10: ex u being VECTOR of V st
( x = u & g . u <> 0 ) ;
assume not x in D ; :: thesis: contradiction
hence contradiction by A6, A10; :: thesis: verum
end;
D c= B
proof
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in D or x in B )
assume x in D ; :: thesis: x in B
then ( x in Carrier l & not x in A & Carrier l c= A \/ B ) by RLVECT_2:def 8, XBOOLE_0:def 5;
hence x in B by XBOOLE_0:def 3; :: thesis: verum
end;
then Carrier g c= B by A9, XBOOLE_1:1;
then reconsider g = g as Linear_Combination of B by RLVECT_2:def 8;
l = f + g
proof
let v be VECTOR of V; :: according to RLVECT_2:def 11 :: thesis: l . v = (f + g) . v
now
per cases ( v in C or not v in C ) ;
suppose A11: v in C ; :: thesis: (f + g) . v = l . v
thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 12
.= (l . v) + (g . v) by A4, A11
.= (l . v) + 0 by A6, A12
.= l . v ; :: thesis: verum
end;
suppose A13: not v in C ; :: thesis: l . v = (f + g) . v
now
per cases ( v in Carrier l or not v in Carrier l ) ;
suppose A14: v in Carrier l ; :: thesis: (f + g) . v = l . v
thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 12
.= 0 + (g . v) by A4, A13
.= l . v by A6, A15 ; :: thesis: verum
end;
suppose A16: not v in Carrier l ; :: thesis: (f + g) . v = l . v
then A17: ( not v in C & not v in D ) by XBOOLE_0:def 4, XBOOLE_0:def 5;
thus (f + g) . v = (f . v) + (g . v) by RLVECT_2:def 12
.= 0 + (g . v) by A4, A17
.= 0 + 0 by A6, A17
.= l . v by A16 ; :: thesis: verum
end;
end;
end;
hence l . v = (f + g) . v ; :: thesis: verum
end;
end;
end;
hence l . v = (f + g) . v ; :: thesis: verum
end;
then A18: v = (Sum f) + (Sum g) by A2, Th1;
( Sum f in Lin A & Sum g in Lin B ) by Th17;
hence v in (Lin A) + (Lin B) by A18, RLSUB_2:5; :: thesis: verum
end;
then Lin (A \/ B) is Subspace of (Lin A) + (Lin B) by RLSUB_1:37;
hence Lin (A \/ B) = (Lin A) + (Lin B) by A1, RLSUB_1:34; :: thesis: verum