let V be RealLinearSpace; :: thesis: for W1, W2 being Subspace of V st V = W1 + W2 & ex v being VECTOR of V st
for v1, v2, u1, u2 being VECTOR of V st v = v1 + v2 & v = u1 + u2 & v1 in W1 & u1 in W1 & v2 in W2 & u2 in W2 holds
( v1 = u1 & v2 = u2 ) holds
V is_the_direct_sum_of W1,W2
let W1, W2 be Subspace of V; :: thesis: ( V = W1 + W2 & ex v being VECTOR of V st
for v1, v2, u1, u2 being VECTOR of V st v = v1 + v2 & v = u1 + u2 & v1 in W1 & u1 in W1 & v2 in W2 & u2 in W2 holds
( v1 = u1 & v2 = u2 ) implies V is_the_direct_sum_of W1,W2 )
assume A1: V = W1 + W2 ; :: thesis: ( for v being VECTOR of V ex v1, v2, u1, u2 being VECTOR of V st
( v = v1 + v2 & v = u1 + u2 & v1 in W1 & u1 in W1 & v2 in W2 & u2 in W2 & not ( v1 = u1 & v2 = u2 ) ) or V is_the_direct_sum_of W1,W2 )
given v being VECTOR of V such that A2: for v1, v2, u1, u2 being VECTOR of V st v = v1 + v2 & v = u1 + u2 & v1 in W1 & u1 in W1 & v2 in W2 & u2 in W2 holds
( v1 = u1 & v2 = u2 ) ; :: thesis: V is_the_direct_sum_of W1,W2
A3: the carrier of ((0). V) = {(0. V)} by RLSUB_1:def 3;
assume not V is_the_direct_sum_of W1,W2 ; :: thesis: contradiction
then W1 /\ W2 <> (0). V by A1, Def4;
then ( the carrier of (W1 /\ W2) <> the carrier of ((0). V) & (0). V is Subspace of W1 /\ W2 ) by RLSUB_1:38, RLSUB_1:51;
then ( the carrier of (W1 /\ W2) <> {(0. V)} & {(0. V)} c= the carrier of (W1 /\ W2) ) by A3, RLSUB_1:def 2;
then {(0. V)} c< the carrier of (W1 /\ W2) by XBOOLE_0:def 8;
then consider x being set such that
A4: x in the carrier of (W1 /\ W2) and
A5: not x in {(0. V)} by XBOOLE_0:6;
A6: x in W1 /\ W2 by A4, STRUCT_0:def 5;
then A7: ( x in W1 & x in W2 ) by Th7;
A8: x <> 0. V by A5, TARSKI:def 1;
x in V by A6, RLSUB_1:17;
then reconsider u = x as VECTOR of V by STRUCT_0:def 5;
consider v1, v2 being VECTOR of V such that
A9: ( v1 in W1 & v2 in W2 ) and
A10: v = v1 + v2 by A1, Lm13;
A11: v = (v1 + v2) + (0. V) by A10, RLVECT_1:10
.= (v1 + v2) + (u - u) by RLVECT_1:28
.= ((v1 + v2) + u) - u by RLVECT_1:def 6
.= ((v1 + u) + v2) - u by RLVECT_1:def 6
.= (v1 + u) + (v2 - u) by RLVECT_1:def 6 ;
( v1 + u in W1 & v2 - u in W2 ) by A7, A9, RLSUB_1:28, RLSUB_1:31;
then v2 - u = v2 by A2, A9, A10, A11
.= v2 - (0. V) by RLVECT_1:26 ;
hence contradiction by A8, RLVECT_1:37; :: thesis: verum