let P, R be Relation; :: thesis: ( P is symmetric & R is symmetric implies ( P \/ R is symmetric & P /\ R is symmetric & P \ R is symmetric ) )
assume that
A1: P is symmetric and
A2: R is symmetric ; :: thesis: ( P \/ R is symmetric & P /\ R is symmetric & P \ R is symmetric )
A3: P is_symmetric_in field P by A1, Def11;
A4: R is_symmetric_in field R by A2, Def11;

now

let a, b be set ; :: thesis: ( a in field (P \/ R) & b in field (P \/ R) & [a,b] in P \/ R implies [b,a] in P \/ R )
assume that
( a in field (P \/ R) & b in field (P \/ R) ) and
A5: [a,b] in P \/ R ; :: thesis: [b,a] in P \/ R

A6: now

assume A7: [a,b] in P ; :: thesis: [b,a] in P \/ R
then ( a in field P & b in field P ) by RELAT_1:30;
then [b,a] in P by A3, A7, Def3;
hence [b,a] in P \/ R by XBOOLE_0:def 3; :: thesis: verum

end;

now

assume A8: [a,b] in R ; :: thesis: [b,a] in P \/ R
then ( a in field R & b in field R ) by RELAT_1:30;
then [b,a] in R by A4, A8, Def3;
hence [b,a] in P \/ R by XBOOLE_0:def 3; :: thesis: verum

end;

hence [b,a] in P \/ R by A5, A6, XBOOLE_0:def 3; :: thesis: verum

end;

then P \/ R is_symmetric_in field (P \/ R) by Def3;
hence P \/ R is symmetric by Def11; :: thesis: ( P /\ R is symmetric & P \ R is symmetric )

now

let a, b be set ; :: thesis: ( a in field (P /\ R) & b in field (P /\ R) & [a,b] in P /\ R implies [b,a] in P /\ R )
A9: field (P /\ R) c= (field P) /\ (field R) by RELAT_1:34;
assume A10: ( a in field (P /\ R) & b in field (P /\ R) & [a,b] in P /\ R ) ; :: thesis: [b,a] in P /\ R
then A11: ( a in field P & a in field R ) by A9, XBOOLE_0:def 4;
A12: ( b in field P & b in field R ) by A9, A10, XBOOLE_0:def 4;
A13: ( [a,b] in P & [a,b] in R ) by A10, XBOOLE_0:def 4;
then A14: [b,a] in P by A3, A11, A12, Def3;
[b,a] in R by A4, A11, A12, A13, Def3;
hence [b,a] in P /\ R by A14, XBOOLE_0:def 4; :: thesis: verum

end;

then P /\ R is_symmetric_in field (P /\ R) by Def3;
hence P /\ R is symmetric by Def11; :: thesis: P \ R is symmetric

now

let a, b be set ; :: thesis: ( a in field (P \ R) & b in field (P \ R) & [a,b] in P \ R implies [b,a] in P \ R )
assume that
( a in field (P \ R) & b in field (P \ R) ) and
A15: [a,b] in P \ R ; :: thesis: [b,a] in P \ R
A16: ( [a,b] in P & not [a,b] in R ) by A15, XBOOLE_0:def 5;
then ( a in field P & b in field P ) by RELAT_1:30;
then A17: [b,a] in P by A3, A16, Def3;
A18: ( not b in field R or not a in field R or not [b,a] in R ) by A4, A16, Def3;
( ( not b in field R or not a in field R ) implies not [b,a] in R ) by RELAT_1:30;
hence [b,a] in P \ R by A17, A18, XBOOLE_0:def 5; :: thesis: verum

end;

then P \ R is_symmetric_in field (P \ R) by Def3;
hence P \ R is symmetric by Def11; :: thesis: verum