let X be non empty compact Subset of (TOP-REAL 2); :: thesis: ( (LSeg (SW-corner X),(W-min X)) /\ X = {(W-min X)} & (LSeg (W-max X),(NW-corner X)) /\ X = {(W-max X)} )

now

let x be set ; :: thesis: ( ( x in (LSeg (SW-corner X),(W-min X)) /\ X implies x = W-min X ) & ( x = W-min X implies x in (LSeg (SW-corner X),(W-min X)) /\ X ) )

hereby :: thesis: ( x = W-min X implies x in (LSeg (SW-corner X),(W-min X)) /\ X )

assume A1: x in (LSeg (SW-corner X),(W-min X)) /\ X ; :: thesis: x = W-min X
then A2: ( x in LSeg (SW-corner X),(W-min X) & x in X ) by XBOOLE_0:def 4;
reconsider p = x as Point of (TOP-REAL 2) by A1;
(SW-corner X) `1 = (W-min X) `1 by Th85;
then A3: p `1 = (W-min X) `1 by A2, GOBOARD7:5;
(SW-corner X) `2 <= (W-min X) `2 by Th87;
then A4: p `2 <= (W-min X) `2 by A2, TOPREAL1:10;
A5: SW-corner X in LSeg (SW-corner X),(NW-corner X) by RLTOPSP1:69;
W-min X in W-most X by Th91;
then W-min X in LSeg (SW-corner X),(NW-corner X) by XBOOLE_0:def 4;
then LSeg (SW-corner X),(W-min X) c= LSeg (SW-corner X),(NW-corner X) by A5, TOPREAL1:12;
then p in W-most X by A2, XBOOLE_0:def 4;
then (W-min X) `2 <= p `2 by Th88;
then A6: p `2 = (W-min X) `2 by A4, XXREAL_0:1;
p = |[(p `1 ),(p `2 )]| by EUCLID:57;
hence x = W-min X by A3, A6, EUCLID:57; :: thesis: verum

end;

assume A7: x = W-min X ; :: thesis: x in (LSeg (SW-corner X),(W-min X)) /\ X
W-min X in W-most X by Th91;
then A8: W-min X in X by XBOOLE_0:def 4;
W-min X in LSeg (SW-corner X),(W-min X) by RLTOPSP1:69;
hence x in (LSeg (SW-corner X),(W-min X)) /\ X by A7, A8, XBOOLE_0:def 4; :: thesis: verum

end;

hence (LSeg (SW-corner X),(W-min X)) /\ X = {(W-min X)} by TARSKI:def 1; :: thesis: (LSeg (W-max X),(NW-corner X)) /\ X = {(W-max X)}

now

let x be set ; :: thesis: ( ( x in (LSeg (W-max X),(NW-corner X)) /\ X implies x = W-max X ) & ( x = W-max X implies x in (LSeg (W-max X),(NW-corner X)) /\ X ) )

hereby :: thesis: ( x = W-max X implies x in (LSeg (W-max X),(NW-corner X)) /\ X )

assume A9: x in (LSeg (W-max X),(NW-corner X)) /\ X ; :: thesis: x = W-max X
then A10: ( x in LSeg (W-max X),(NW-corner X) & x in X ) by XBOOLE_0:def 4;
reconsider p = x as Point of (TOP-REAL 2) by A9;
(NW-corner X) `1 = (W-max X) `1 by Th85;
then A11: p `1 = (W-max X) `1 by A10, GOBOARD7:5;
(W-max X) `2 <= (NW-corner X) `2 by Th87;
then A12: (W-max X) `2 <= p `2 by A10, TOPREAL1:10;
A13: NW-corner X in LSeg (SW-corner X),(NW-corner X) by RLTOPSP1:69;
W-max X in W-most X by Th91;
then W-max X in LSeg (SW-corner X),(NW-corner X) by XBOOLE_0:def 4;
then LSeg (W-max X),(NW-corner X) c= LSeg (SW-corner X),(NW-corner X) by A13, TOPREAL1:12;
then p in W-most X by A10, XBOOLE_0:def 4;
then p `2 <= (W-max X) `2 by Th88;
then A14: p `2 = (W-max X) `2 by A12, XXREAL_0:1;
p = |[(p `1 ),(p `2 )]| by EUCLID:57;
hence x = W-max X by A11, A14, EUCLID:57; :: thesis: verum

end;

assume A15: x = W-max X ; :: thesis: x in (LSeg (W-max X),(NW-corner X)) /\ X
W-max X in W-most X by Th91;
then A16: W-max X in X by XBOOLE_0:def 4;
W-max X in LSeg (W-max X),(NW-corner X) by RLTOPSP1:69;
hence x in (LSeg (W-max X),(NW-corner X)) /\ X by A15, A16, XBOOLE_0:def 4; :: thesis: verum

end;

hence (LSeg (W-max X),(NW-corner X)) /\ X = {(W-max X)} by TARSKI:def 1; :: thesis: verum