let n be Ordinal; :: thesis: for L being non trivial left_add-cancelable right_complementable add-associative right_zeroed associative well-unital distributive domRing-like left_zeroed doubleLoopStr
for p being Polynomial of n,L
for a being Element of L
for x being Function of n,L holds eval (a * p),x = a * (eval p,x)
let L be non trivial left_add-cancelable right_complementable add-associative right_zeroed associative well-unital distributive domRing-like left_zeroed doubleLoopStr ; :: thesis: for p being Polynomial of n,L
for a being Element of L
for x being Function of n,L holds eval (a * p),x = a * (eval p,x)
let p be Polynomial of n,L; :: thesis: for a being Element of L
for x being Function of n,L holds eval (a * p),x = a * (eval p,x)
let a be Element of L; :: thesis: for x being Function of n,L holds eval (a * p),x = a * (eval p,x)
let x be Function of n,L; :: thesis: eval (a * p),x = a * (eval p,x)
consider y being FinSequence of the carrier of L such that
A1: ( len y = len (SgmX (BagOrder n),(Support (a * p))) & eval (a * p),x = Sum y & ( for i being Element of NAT st 1 <= i & i <= len y holds
y /. i = (((a * p) * (SgmX (BagOrder n),(Support (a * p)))) /. i) * (eval (((SgmX (BagOrder n),(Support (a * p))) /. i) @ ),x) ) ) by POLYNOM2:def 4;
consider z being FinSequence of the carrier of L such that
A2: ( len z = len (SgmX (BagOrder n),(Support p)) & eval p,x = Sum z & ( for i being Element of NAT st 1 <= i & i <= len z holds
z /. i = ((p * (SgmX (BagOrder n),(Support p))) /. i) * (eval (((SgmX (BagOrder n),(Support p)) /. i) @ ),x) ) ) by POLYNOM2:def 4;
A3: BagOrder n linearly_orders Support (a * p) by POLYNOM2:20;

per cases ( a = 0. L or a <> 0. L ) ;

suppose A4: a = 0. L ; :: thesis: eval (a * p),x = a * (eval p,x)

A5: now

let b be bag of ; :: thesis: (a * p) . b = 0. L
thus (a * p) . b = a * (p . b) by Def10
.= 0. L by A4, BINOM:1 ; :: thesis: verum

end;

now

assume Support (a * p) <> {} ; :: thesis: contradiction
then reconsider sp = Support (a * p) as non empty Subset of (Bags n) ;
consider c being Element of sp;
c in sp ;
then (a * p) . c <> 0. L by POLYNOM1:def 9;
hence contradiction by A5; :: thesis: verum

end;

then rng (SgmX (BagOrder n),(Support (a * p))) = {} by A3, TRIANG_1:def 2;
then SgmX (BagOrder n),(Support (a * p)) = {} by RELAT_1:64;
then len y = 0 by A1;
then y = <*> the carrier of L ;
then Sum y = 0. L by RLVECT_1:60
.= a * (Sum z) by A4, BINOM:1 ;
hence eval (a * p),x = a * (eval p,x) by A1, A2; :: thesis: verum

end;

suppose A6: a <> 0. L ; :: thesis: eval (a * p),x = a * (eval p,x)

A7: for u being set st u in Support p holds
u in Support (a * p)

proof

let u be set ; :: thesis: ( u in Support p implies u in Support (a * p) )
assume A8: u in Support p ; :: thesis: u in Support (a * p)
then A9: p . u <> 0. L by POLYNOM1:def 9;
reconsider u' = u as Element of Bags n by A8;
a * (p . u') <> 0. L by A6, A9, VECTSP_2:def 5;
then (a * p) . u' <> 0. L by Def10;
hence u in Support (a * p) by POLYNOM1:def 9; :: thesis: verum

end;

A10: for u being set st u in Support (a * p) holds
u in Support p

proof

let u be set ; :: thesis: ( u in Support (a * p) implies u in Support p )
assume A11: u in Support (a * p) ; :: thesis: u in Support p
then reconsider u' = u as Element of Bags n ;
(a * p) . u <> 0. L by A11, POLYNOM1:def 9;
then a * (p . u') <> 0. L by Def10;
then p . u' <> 0. L by BINOM:2;
hence u in Support p by POLYNOM1:def 9; :: thesis: verum

end;

then A12: Support (a * p) = Support p by A7, TARSKI:2;
A13: len z = len y by A1, A2, A7, A10, TARSKI:2;
then A14: dom z = Seg (len y) by FINSEQ_1:def 3
.= dom y by FINSEQ_1:def 3 ;

now

let i be set ; :: thesis: ( i in dom z implies y /. i = a * (z /. i) )
assume A15: i in dom z ; :: thesis: y /. i = a * (z /. i)
then i in Seg (len z) by FINSEQ_1:def 3;
then i in { k where k is Element of NAT : ( 1 <= k & k <= len z ) } by FINSEQ_1:def 1;
then consider k being Element of NAT such that
A16: ( i = k & 1 <= k & k <= len z ) ;
A17: a * (z /. k) = a * (((p * (SgmX (BagOrder n),(Support p))) /. k) * (eval (((SgmX (BagOrder n),(Support p)) /. k) @ ),x)) by A2, A16
.= (a * ((p * (SgmX (BagOrder n),(Support (a * p)))) /. k)) * (eval (((SgmX (BagOrder n),(Support (a * p))) /. k) @ ),x) by A12, GROUP_1:def 4 ;
A18: dom z = Seg (len (SgmX (BagOrder n),(Support (a * p)))) by A1, A14, FINSEQ_1:def 3
.= dom (SgmX (BagOrder n),(Support (a * p))) by FINSEQ_1:def 3 ;
A19: dom p = Bags n by FUNCT_2:def 1;

now

let u be set ; :: thesis: ( u in rng (SgmX (BagOrder n),(Support (a * p))) implies u in dom p )
assume u in rng (SgmX (BagOrder n),(Support (a * p))) ; :: thesis: u in dom p
then u in Support (a * p) by A3, TRIANG_1:def 2;
hence u in dom p by A19; :: thesis: verum

end;

then rng (SgmX (BagOrder n),(Support (a * p))) c= dom p by TARSKI:def 3;
then reconsider q = p * (SgmX (BagOrder n),(Support (a * p))) as FinSequence by FINSEQ_1:20;
for u being set st u in rng q holds
u in the carrier of L

proof

let u be set ; :: thesis: ( u in rng q implies u in the carrier of L )
assume u in rng q ; :: thesis: u in the carrier of L
then A20: u in rng p by FUNCT_1:25;
rng p c= the carrier of L by RELAT_1:def 19;
hence u in the carrier of L by A20; :: thesis: verum

end;

then rng q c= the carrier of L by TARSKI:def 3;
then reconsider q = q as FinSequence of the carrier of L by FINSEQ_1:def 4;
(SgmX (BagOrder n),(Support (a * p))) . k = (SgmX (BagOrder n),(Support (a * p))) /. k by A15, A16, A18, PARTFUN1:def 8;
then k in dom q by A15, A16, A18, A19, FUNCT_1:21;
then A21: (p * (SgmX (BagOrder n),(Support (a * p)))) /. k = q . k by PARTFUN1:def 8
.= p . ((SgmX (BagOrder n),(Support (a * p))) . k) by A15, A16, A18, FUNCT_1:23
.= p . ((SgmX (BagOrder n),(Support (a * p))) /. k) by A15, A16, A18, PARTFUN1:def 8 ;
reconsider c = (SgmX (BagOrder n),(Support (a * p))) /. k as Element of Bags n ;
reconsider c = c as bag of ;
A22: (a * p) . ((SgmX (BagOrder n),(Support (a * p))) /. k) = (a * p) . c
.= a * ((p * (SgmX (BagOrder n),(Support (a * p)))) /. k) by A21, Def10 ;
A23: dom (a * p) = Bags n by FUNCT_2:def 1;

now

let u be set ; :: thesis: ( u in rng (SgmX (BagOrder n),(Support (a * p))) implies u in dom (a * p) )
assume u in rng (SgmX (BagOrder n),(Support (a * p))) ; :: thesis: u in dom (a * p)
then u in Support (a * p) by A3, TRIANG_1:def 2;
hence u in dom (a * p) by A23; :: thesis: verum

end;

then rng (SgmX (BagOrder n),(Support (a * p))) c= dom (a * p) by TARSKI:def 3;
then reconsider r = (a * p) * (SgmX (BagOrder n),(Support (a * p))) as FinSequence by FINSEQ_1:20;
for u being set st u in rng r holds
u in the carrier of L

proof

let u be set ; :: thesis: ( u in rng r implies u in the carrier of L )
assume u in rng r ; :: thesis: u in the carrier of L
then A24: u in rng (a * p) by FUNCT_1:25;
rng (a * p) c= the carrier of L by RELAT_1:def 19;
hence u in the carrier of L by A24; :: thesis: verum

end;

then rng r c= the carrier of L by TARSKI:def 3;
then reconsider r = r as FinSequence of the carrier of L by FINSEQ_1:def 4;
(SgmX (BagOrder n),(Support (a * p))) . k = (SgmX (BagOrder n),(Support (a * p))) /. k by A15, A16, A18, PARTFUN1:def 8;
then k in dom r by A15, A16, A18, A23, FUNCT_1:21;
then ((a * p) * (SgmX (BagOrder n),(Support (a * p)))) /. k = r . k by PARTFUN1:def 8
.= (a * p) . ((SgmX (BagOrder n),(Support (a * p))) . k) by A15, A16, A18, FUNCT_1:23
.= a * ((p * (SgmX (BagOrder n),(Support (a * p)))) /. k) by A15, A16, A18, A22, PARTFUN1:def 8 ;
hence y /. i = a * (z /. i) by A1, A13, A16, A17; :: thesis: verum

end;

then y = a * z by A14, POLYNOM1:def 2;
hence eval (a * p),x = a * (eval p,x) by A1, A2, BINOM:4; :: thesis: verum

end;

end;