let S, T, U be non trivial RealNormSpace; :: thesis: for R being REST of S,T
for L being bounded LinearOperator of T,U holds L * R is REST of S,U
let R be REST of S,T; :: thesis: for L being bounded LinearOperator of T,U holds L * R is REST of S,U
let L be bounded LinearOperator of T,U; :: thesis: L * R is REST of S,U
consider K being Real such that
A1: 0 <= K and
A2: for z being Point of T holds ||.(L . z).|| <= K * ||.z.|| by LOPBAN_1:def 9;
A3: 0 + K < 1 + K by XREAL_1:10;
A4: dom L = the carrier of T by FUNCT_2:def 1;
A5: R is total by NDIFF_1:def 5;
then A6: dom R = the carrier of S by PARTFUN1:def 4;
A7: rng R c= dom L by A4;
then dom (L * R) = dom R by RELAT_1:46
.= the carrier of S by A5, PARTFUN1:def 4 ;
then A8: L * R is total by PARTFUN1:def 4;

now

let ee be Real; :: thesis: ( ee > 0 implies ex d being Real st
( d > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d holds
(||.h.|| " ) * ||.((L * R) /. h).|| < ee ) ) )
assume A9: ee > 0 ; :: thesis: ex d being Real st
( d > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d holds
(||.h.|| " ) * ||.((L * R) /. h).|| < ee ) )
set e = ee / 2;
A10: ee / 2 > 0 by A9, XREAL_1:217;
A11: ee / 2 < ee by A9, XREAL_1:218;
set e1 = (ee / 2) / (1 + K);
A12: 0 / (1 + K) < (ee / 2) / (1 + K) by A1, A10, XREAL_1:76;
R is total by NDIFF_1:def 5;
then consider d being Real such that
A13: 0 < d and
A14: for h being Point of S st h <> 0. S & ||.h.|| < d holds
(||.h.|| " ) * ||.(R /. h).|| < (ee / 2) / (1 + K) by A12, NDIFF_1:26;

now

let h be Point of S; :: thesis: ( h <> 0. S & ||.h.|| < d implies (||.h.|| " ) * ||.((L * R) /. h).|| < ee )
assume that
A15: h <> 0. S and
A16: ||.h.|| < d ; :: thesis: (||.h.|| " ) * ||.((L * R) /. h).|| < ee
A17: L . (R /. h) = L /. (R /. h)
.= (L * R) /. h by A6, A7, PARTFUN2:10 ;
||.h.|| <> 0 by A15, NORMSP_1:def 2;
then ||.h.|| > 0 by NORMSP_1:8;
then A18: ||.h.|| " > 0 ;
A19: ||.(L . (R /. h)).|| <= K * ||.(R /. h).|| by A2;
0 <= ||.(R /. h).|| by NORMSP_1:8;
then K * ||.(R /. h).|| <= (K + 1) * ||.(R /. h).|| by A3, XREAL_1:66;
then ||.(L . (R /. h)).|| <= (K + 1) * ||.(R /. h).|| by A19, XXREAL_0:2;
then A20: (||.h.|| " ) * ||.(L . (R /. h)).|| <= (||.h.|| " ) * ((K + 1) * ||.(R /. h).||) by A18, XREAL_1:66;
(||.h.|| " ) * ||.(R /. h).|| < (ee / 2) / (1 + K) by A14, A15, A16;
then (K + 1) * ((||.h.|| " ) * ||.(R /. h).||) <= (K + 1) * ((ee / 2) / (1 + K)) by A1, XREAL_1:66;
then (K + 1) * ((||.h.|| " ) * ||.(R /. h).||) <= ee / 2 by A1, XCMPLX_1:88;
then (||.h.|| " ) * ||.(L . (R /. h)).|| <= ee / 2 by A20, XXREAL_0:2;
hence (||.h.|| " ) * ||.((L * R) /. h).|| < ee by A11, A17, XXREAL_0:2; :: thesis: verum

end;

hence ex d being Real st
( d > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d holds
(||.h.|| " ) * ||.((L * R) /. h).|| < ee ) ) by A13; :: thesis: verum

end;

hence L * R is REST of S,U by A8, NDIFF_1:26; :: thesis: verum