let T, S, U be non trivial RealNormSpace; :: thesis: for R being REST of T,U st R /. (0. T) = 0. U holds
for L being bounded LinearOperator of S,T holds R * L is REST of S,U
let R be REST of T,U; :: thesis: ( R /. (0. T) = 0. U implies for L being bounded LinearOperator of S,T holds R * L is REST of S,U )
assume A1: R /. (0. T) = 0. U ; :: thesis: for L being bounded LinearOperator of S,T holds R * L is REST of S,U
let L be bounded LinearOperator of S,T; :: thesis: R * L is REST of S,U
consider K being Real such that
A2: 0 <= K and
A3: for h being Point of S holds ||.(L . h).|| <= K * ||.h.|| by LOPBAN_1:def 9;
A4: 0 + K < 1 + K by XREAL_1:10;
A5: dom L = the carrier of S by FUNCT_2:def 1;
R is total by NDIFF_1:def 5;
then dom R = the carrier of T by PARTFUN1:def 4;
then A6: rng L c= dom R ;
then dom (R * L) = dom L by RELAT_1:46
.= the carrier of S by FUNCT_2:def 1 ;
then A7: R * L is total by PARTFUN1:def 4;

now

let e be Real; :: thesis: ( e > 0 implies ex d1 being Real st
( d1 > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d1 holds
(||.h.|| " ) * ||.((R * L) /. h).|| < e ) ) )
assume A8: e > 0 ; :: thesis: ex d1 being Real st
( d1 > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d1 holds
(||.h.|| " ) * ||.((R * L) /. h).|| < e ) )
set e1 = e / (1 + K);
A9: 0 / (1 + K) < e / (1 + K) by A2, A8, XREAL_1:76;
then consider d being Real such that
A10: 0 < d and
A11: for h being Point of T st ||.h.|| < d holds
||.(R /. h).|| <= (e / (1 + K)) * ||.h.|| by A1, Th7;
set d1 = d / (1 + K);
A12: 0 / (1 + K) < d / (1 + K) by A2, A10, XREAL_1:76;

now

let h be Point of S; :: thesis: ( h <> 0. S & ||.h.|| < d / (1 + K) implies (||.h.|| " ) * ||.((R * L) /. h).|| < e )
assume that
A13: h <> 0. S and
A14: ||.h.|| < d / (1 + K) ; :: thesis: (||.h.|| " ) * ||.((R * L) /. h).|| < e
A15: R /. (L . h) = R /. (L /. h)
.= (R * L) /. h by A5, A6, PARTFUN2:10 ;
A16: ||.h.|| <> 0 by A13, NORMSP_1:def 2;
then A17: ||.h.|| > 0 by NORMSP_1:8;
then A18: ||.h.|| " > 0 ;
A19: ||.(L . h).|| <= K * ||.h.|| by A3;
K * ||.h.|| < (K + 1) * ||.h.|| by A4, A17, XREAL_1:70;
then A20: ||.(L . h).|| < (K + 1) * ||.h.|| by A19, XXREAL_0:2;
(K + 1) * ||.h.|| < (K + 1) * (d / (1 + K)) by A2, A14, XREAL_1:70;
then ||.(L . h).|| < (K + 1) * (d / (1 + K)) by A20, XXREAL_0:2;
then ||.(L . h).|| < d by A2, XCMPLX_1:88;
then A21: ||.(R /. (L . h)).|| <= (e / (1 + K)) * ||.(L . h).|| by A11;
(e / (1 + K)) * ||.(L . h).|| < (e / (1 + K)) * ((K + 1) * ||.h.||) by A9, A20, XREAL_1:70;
then ||.(R /. (L . h)).|| < (e / (1 + K)) * ((K + 1) * ||.h.||) by A21, XXREAL_0:2;
then (||.h.|| " ) * ||.((R * L) /. h).|| < (||.h.|| " ) * (((e / (1 + K)) * (K + 1)) * ||.h.||) by A15, A18, XREAL_1:70;
then (||.h.|| " ) * ||.((R * L) /. h).|| < ((||.h.|| * (||.h.|| " )) * (e / (1 + K))) * (K + 1) ;
then (||.h.|| " ) * ||.((R * L) /. h).|| < (1 * (e / (1 + K))) * (K + 1) by A16, XCMPLX_0:def 7;
hence (||.h.|| " ) * ||.((R * L) /. h).|| < e by A2, XCMPLX_1:88; :: thesis: verum

end;

hence ex d1 being Real st
( d1 > 0 & ( for h being Point of S st h <> 0. S & ||.h.|| < d1 holds
(||.h.|| " ) * ||.((R * L) /. h).|| < e ) ) by A12; :: thesis: verum

end;

hence R * L is REST of S,U by A7, NDIFF_1:26; :: thesis: verum