let T, S be non trivial RealNormSpace; :: thesis: for f being PartFunc of S,T
for x0 being Point of S st f is_differentiable_in x0 holds
f is_continuous_in x0
let f be PartFunc of S,T; :: thesis: for x0 being Point of S st f is_differentiable_in x0 holds
f is_continuous_in x0
let x0 be Point of S; :: thesis: ( f is_differentiable_in x0 implies f is_continuous_in x0 )
assume A1: f is_differentiable_in x0 ; :: thesis: f is_continuous_in x0
then consider N being Neighbourhood of x0 such that
A2: ( N c= dom f & ex L being Point of (R_NormSpace_of_BoundedLinearOperators S,T) ex R being REST of S,T st
for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) ) by Def6;
A3: x0 in N by NFCONT_1:4;

now

let s1 be sequence of S; :: thesis: ( rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) implies ( f /* s1 is convergent & f /. x0 = lim (f /* s1) ) )
assume A4: ( rng s1 c= dom f & s1 is convergent & lim s1 = x0 & ( for n being Element of NAT holds s1 . n <> x0 ) ) ; :: thesis: ( f /* s1 is convergent & f /. x0 = lim (f /* s1) )
consider g being Real such that
A5: ( 0 < g & { y where y is Point of S : ||.(y - x0).|| < g } c= N ) by NFCONT_1:def 3;
reconsider s2 = NAT --> x0 as sequence of S by FUNCOP_1:57;
deffunc H₁( Element of NAT ) -> Element of the carrier of S = (s1 . $1) - (s2 . $1);
consider s3 being sequence of S such that
A6: for n being Element of NAT holds s3 . n = H₁(n) from FUNCT_2:sch 4();
A7: s2 is convergent by Th21;
A8: lim s2 = s2 . 0 by Th21
.= x0 by FUNCOP_1:13 ;
A9: s3 = s1 - s2 by A6, NORMSP_1:def 6;
then A10: s3 is convergent by A4, A7, NORMSP_1:35;
A11: lim s3 = x0 - x0 by A4, A7, A8, A9, NORMSP_1:43
.= 0. S by RLVECT_1:28 ;

A12: now

given n being Element of NAT such that A13: s3 . n = 0. S ; :: thesis: contradiction
(s1 . n) - (s2 . n) = 0. S by A6, A13;
then (s1 . n) - x0 = 0. S by FUNCOP_1:13;
hence contradiction by A4, RLVECT_1:35; :: thesis: verum

end;

consider l being Element of NAT such that
A14: for m being Element of NAT st l <= m holds
||.((s1 . m) - x0).|| < g by A4, A5, NORMSP_1:def 11;
A15: ( s3 ^\ l is convergent & lim (s3 ^\ l) = 0. S ) by A10, A11, LOPBAN_3:14;

now

given n being Element of NAT such that A16: (s3 ^\ l) . n = 0. S ; :: thesis: contradiction
s3 . (n + l) = 0. S by A16, NAT_1:def 3;
hence contradiction by A12; :: thesis: verum

end;

then s3 ^\ l is non-zero by Th7;
then reconsider h = s3 ^\ l as convergent_to_0 sequence of S by A15, Def4;
reconsider c = s2 ^\ l as V8() sequence of S ;
A17: rng c = {x0}

proof

thus rng c c= {x0} :: according to XBOOLE_0:def 10 :: thesis: {x0} c= rng c

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng c or y in {x0} )
assume y in rng c ; :: thesis: y in {x0}
then consider n being Element of NAT such that
A18: y = (s2 ^\ l) . n by NFCONT_1:6;
y = s2 . (n + l) by A18, NAT_1:def 3;
then y = x0 by FUNCOP_1:13;
hence y in {x0} by TARSKI:def 1; :: thesis: verum

end;

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in {x0} or y in rng c )
assume y in {x0} ; :: thesis: y in rng c
then A19: y = x0 by TARSKI:def 1;
c . 0 = s2 . (0 + l) by NAT_1:def 3
.= y by A19, FUNCOP_1:13 ;
hence y in rng c by NFCONT_1:6; :: thesis: verum

end;

rng (h + c) c= N

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in rng (h + c) or y in N )
assume A20: y in rng (h + c) ; :: thesis: y in N
then consider n being Element of NAT such that
A21: y = (h + c) . n by NFCONT_1:6;
(h + c) . n = (((s1 - s2) + s2) ^\ l) . n by A9, Th15
.= ((s1 - s2) + s2) . (n + l) by NAT_1:def 3
.= ((s1 - s2) . (n + l)) + (s2 . (n + l)) by NORMSP_1:def 5
.= ((s1 . (n + l)) - (s2 . (n + l))) + (s2 . (n + l)) by NORMSP_1:def 6
.= (s1 . (n + l)) - ((s2 . (n + l)) - (s2 . (n + l))) by RLVECT_1:43
.= (s1 . (n + l)) - (0. S) by RLVECT_1:28
.= s1 . (l + n) by RLVECT_1:26 ;
then A22: ||.(((h + c) . n) - x0).|| < g by A14, NAT_1:12;
reconsider y1 = y as Point of S by A20;
y1 in { z where z is Point of S : ||.(z - x0).|| < g } by A21, A22;
hence y in N by A5; :: thesis: verum

end;

then A23: ( (f /* (h + c)) - (f /* c) is convergent & lim ((f /* (h + c)) - (f /* c)) = 0. T ) by A1, A2, A17, Th39;

A24: now

let p be Real; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
||.(((f /* c) . m) - (f /. x0)).|| < p )
assume A25: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
||.(((f /* c) . m) - (f /. x0)).|| < p
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
||.(((f /* c) . m) - (f /. x0)).|| < p
let m be Element of NAT ; :: thesis: ( n <= m implies ||.(((f /* c) . m) - (f /. x0)).|| < p )
assume n <= m ; :: thesis: ||.(((f /* c) . m) - (f /. x0)).|| < p
x0 in N by NFCONT_1:4;
then rng c c= dom f by A2, A17, ZFMISC_1:37;
then ||.(((f /* c) . m) - (f /. x0)).|| = ||.((f /. (c . m)) - (f /. x0)).|| by FUNCT_2:186
.= ||.((f /. (s2 . (m + l))) - (f /. x0)).|| by NAT_1:def 3
.= ||.((f /. x0) - (f /. x0)).|| by FUNCOP_1:13
.= ||.(0. T).|| by RLVECT_1:28
.= 0 by NORMSP_1:5 ;
hence ||.(((f /* c) . m) - (f /. x0)).|| < p by A25; :: thesis: verum

end;

then A26: f /* c is convergent by NORMSP_1:def 9;
then A27: lim (f /* c) = f /. x0 by A24, NORMSP_1:def 11;
A28: ((f /* (h + c)) - (f /* c)) + (f /* c) is convergent by A23, A26, NORMSP_1:34;
A29: lim (((f /* (h + c)) - (f /* c)) + (f /* c)) = (0. T) + (f /. x0) by A23, A26, A27, NORMSP_1:42
.= f /. x0 by RLVECT_1:10 ;

now

let n be Element of NAT ; :: thesis: (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (f /* (h + c)) . n
thus (((f /* (h + c)) - (f /* c)) + (f /* c)) . n = (((f /* (h + c)) - (f /* c)) . n) + ((f /* c) . n) by NORMSP_1:def 5
.= (((f /* (h + c)) . n) - ((f /* c) . n)) + ((f /* c) . n) by NORMSP_1:def 6
.= ((f /* (h + c)) . n) - (((f /* c) . n) - ((f /* c) . n)) by RLVECT_1:43
.= ((f /* (h + c)) . n) - (0. T) by RLVECT_1:28
.= (f /* (h + c)) . n by RLVECT_1:26 ; :: thesis: verum

end;

then A30: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (h + c) by FUNCT_2:113;

now

let n be Element of NAT ; :: thesis: (h + c) . n = (s1 ^\ l) . n
thus (h + c) . n = (((s1 - s2) + s2) ^\ l) . n by A9, Th15
.= ((s1 - s2) + s2) . (n + l) by NAT_1:def 3
.= ((s1 - s2) . (n + l)) + (s2 . (n + l)) by NORMSP_1:def 5
.= ((s1 . (n + l)) - (s2 . (n + l))) + (s2 . (n + l)) by NORMSP_1:def 6
.= (s1 . (n + l)) - ((s2 . (n + l)) - (s2 . (n + l))) by RLVECT_1:43
.= (s1 . (n + l)) - (0. S) by RLVECT_1:28
.= s1 . (l + n) by RLVECT_1:26
.= (s1 ^\ l) . n by NAT_1:def 3 ; :: thesis: verum

end;

then A31: ((f /* (h + c)) - (f /* c)) + (f /* c) = f /* (s1 ^\ l) by A30, FUNCT_2:113
.= (f /* s1) ^\ l by A4, VALUED_0:27 ;
hence f /* s1 is convergent by A28, LOPBAN_3:15; :: thesis: f /. x0 = lim (f /* s1)
thus f /. x0 = lim (f /* s1) by A23, A26, A29, A31, LOPBAN_3:16, NORMSP_1:34; :: thesis: verum

end;

hence f is_continuous_in x0 by A2, A3, Th32; :: thesis: verum