let S, T be non trivial RealNormSpace; :: thesis: for f being PartFunc of S,T
for Z being Subset of S st Z is open & Z c= dom f & ex r being Point of T st rng f = {r} holds
( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )
let f be PartFunc of S,T; :: thesis: for Z being Subset of S st Z is open & Z c= dom f & ex r being Point of T st rng f = {r} holds
( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )
let Z be Subset of S; :: thesis: ( Z is open & Z c= dom f & ex r being Point of T st rng f = {r} implies ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) ) )
assume A1: ( Z is open & Z c= dom f ) ; :: thesis: ( for r being Point of T holds not rng f = {r} or ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) ) )
given r being Point of T such that A2: rng f = {r} ; :: thesis: ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )

A3: now

let x0 be Point of S; :: thesis: ( x0 in dom f implies f /. x0 = r )
assume A4: x0 in dom f ; :: thesis: f /. x0 = r
then f . x0 in {r} by A2, FUNCT_1:def 5;
then f /. x0 in {r} by A4, PARTFUN1:def 8;
hence f /. x0 = r by TARSKI:def 1; :: thesis: verum

end;

set L = 0. (R_NormSpace_of_BoundedLinearOperators S,T);
R_NormSpace_of_BoundedLinearOperators S,T = NORMSTR(# (BoundedLinearOperators S,T),(Zero_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(Add_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(Mult_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(BoundedLinearOperatorsNorm S,T) #) by LOPBAN_1:def 15;
then reconsider L = 0. (R_NormSpace_of_BoundedLinearOperators S,T) as Element of BoundedLinearOperators S,T ;
A5: the carrier of S --> (0. T) = L by LOPBAN_1:37;
reconsider R = the carrier of S --> (0. T) as PartFunc of S,T ;
A6: dom R = the carrier of S by FUNCOP_1:19;

now

let h be convergent_to_0 sequence of S; :: thesis: ( (||.h.|| " ) (#) (R /* h) is convergent & lim ((||.h.|| " ) (#) (R /* h)) = 0. T )

A8: now

let n be Nat; :: thesis: ((||.h.|| " ) (#) (R /* h)) . n = 0. T
X: n in NAT by ORDINAL1:def 13;
A9: R /. (h . n) = R . (h . n) by A6, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
A10: rng h c= dom R by A6;
thus ((||.h.|| " ) (#) (R /* h)) . n = ((||.h.|| " ) . n) * ((R /* h) . n) by Def2, X
.= ((||.h.|| " ) . n) * (R /. (h . n)) by A10, X, FUNCT_2:186
.= 0. T by A9, RLVECT_1:23 ; :: thesis: verum

end;

then A11: (||.h.|| " ) (#) (R /* h) is constant by VALUED_0:def 18;
hence (||.h.|| " ) (#) (R /* h) is convergent by Th21; :: thesis: lim ((||.h.|| " ) (#) (R /* h)) = 0. T
((||.h.|| " ) (#) (R /* h)) . 0 = 0. T by A8;
hence lim ((||.h.|| " ) (#) (R /* h)) = 0. T by A11, Th21; :: thesis: verum

end;

then reconsider R = R as REST of S,T by Def5;

A12: now

let x0 be Point of S; :: thesis: ( x0 in Z implies f is_differentiable_in x0 )
assume A13: x0 in Z ; :: thesis: f is_differentiable_in x0
then consider N being Neighbourhood of x0 such that
A14: N c= Z by A1, Th2;
A15: N c= dom f by A1, A14, XBOOLE_1:1;
for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))

proof

let x be Point of S; :: thesis: ( x in N implies (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) )
A16: R /. (x - x0) = R . (x - x0) by A6, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
assume x in N ; :: thesis: (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))
hence (f /. x) - (f /. x0) = r - (f /. x0) by A3, A15
.= r - r by A1, A3, A13
.= 0. T by RLVECT_1:28
.= (0. T) + (0. T) by RLVECT_1:10
.= (L . (x - x0)) + (R /. (x - x0)) by A5, A16, FUNCOP_1:13 ;
:: thesis: verum

end;

hence f is_differentiable_in x0 by A15, Def6; :: thesis: verum

end;

hence A17: f is_differentiable_on Z by A1, Th36; :: thesis: for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T)
let x0 be Point of S; :: thesis: ( x0 in Z implies (f `| Z) /. x0 = 0. (R_NormSpace_of_BoundedLinearOperators S,T) )
assume A18: x0 in Z ; :: thesis: (f `| Z) /. x0 = 0. (R_NormSpace_of_BoundedLinearOperators S,T)
then A19: f is_differentiable_in x0 by A12;
then ex N being Neighbourhood of x0 st
( N c= dom f & ex L being Point of (R_NormSpace_of_BoundedLinearOperators S,T) ex R being REST of S,T st
for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) ) by Def6;
then consider N being Neighbourhood of x0 such that
A20: N c= dom f ;
A21: for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))

proof

let x be Point of S; :: thesis: ( x in N implies (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) )
A22: R /. (x - x0) = R . (x - x0) by A6, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
assume x in N ; :: thesis: (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))
hence (f /. x) - (f /. x0) = r - (f /. x0) by A3, A20
.= r - r by A1, A3, A18
.= 0. T by RLVECT_1:28
.= (0. T) + (0. T) by RLVECT_1:10
.= (L . (x - x0)) + (R /. (x - x0)) by A5, A22, FUNCOP_1:13 ;
:: thesis: verum

end;

thus (f `| Z) /. x0 = diff f,x0 by A17, A18, Def9
.= 0. (R_NormSpace_of_BoundedLinearOperators S,T) by A19, A20, A21, Def7 ; :: thesis: verum