let z be Complex; :: thesis: for CNS being ComplexNormSpace
for RNS being RealNormSpace
for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let CNS be ComplexNormSpace; :: thesis: for RNS being RealNormSpace
for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let RNS be RealNormSpace; :: thesis: for X being set
for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let X be set ; :: thesis: for f being PartFunc of RNS,CNS st f is_Lipschitzian_on X holds
z (#) f is_Lipschitzian_on X
let f be PartFunc of RNS,CNS; :: thesis: ( f is_Lipschitzian_on X implies z (#) f is_Lipschitzian_on X )
assume A1: f is_Lipschitzian_on X ; :: thesis: z (#) f is_Lipschitzian_on X
then X c= dom f by Def29;
hence A2: X c= dom (z (#) f) by VFUNCT_2:def 4; :: according to NCFCONT1:def 29 :: thesis: ex r being Real st
( 0 < r & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) )
consider s being Real such that
A3: ( 0 < s & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.((f /. x1) - (f /. x2)).|| <= s * ||.(x1 - x2).|| ) ) by A1, Def29;

now

per cases ( z = 0 or z <> 0 ) ;

suppose A4: z = 0 ; :: thesis: ex s being Real st
( 0 < s & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )

take s = s; :: thesis: ( 0 < s & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| ) )
thus 0 < s by A3; :: thesis: for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
let x1, x2 be Point of RNS; :: thesis: ( x1 in X & x2 in X implies ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| )
assume A5: ( x1 in X & x2 in X ) ; :: thesis: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).||
then A6: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| = ||.((z * (f /. x1)) - ((z (#) f) /. x2)).|| by A2, VFUNCT_2:def 4
.= ||.((0. CNS) - ((z (#) f) /. x2)).|| by A4, CLVECT_1:2
.= ||.((0. CNS) - (z * (f /. x2))).|| by A2, A5, VFUNCT_2:def 4
.= ||.((0. CNS) - (0. CNS)).|| by A4, CLVECT_1:2
.= ||.(0. CNS).|| by RLVECT_1:26
.= 0 by CLVECT_1:103 ;
0 <= ||.(x1 - x2).|| by NORMSP_1:8;
then s * 0 <= s * ||.(x1 - x2).|| by A3, XREAL_1:66;
hence ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= s * ||.(x1 - x2).|| by A6; :: thesis: verum

end;

suppose z <> 0 ; :: thesis: ex g being Element of REAL st
( 0 < g & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )

then 0 < |.z.| by COMPLEX1:133;
then A7: 0 * s < |.z.| * s by A3, XREAL_1:70;
take g = |.z.| * s; :: thesis: ( 0 < g & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| ) )
thus 0 < g by A7; :: thesis: for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
let x1, x2 be Point of RNS; :: thesis: ( x1 in X & x2 in X implies ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| )
assume A8: ( x1 in X & x2 in X ) ; :: thesis: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).||
then A9: ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| = ||.((z * (f /. x1)) - ((z (#) f) /. x2)).|| by A2, VFUNCT_2:def 4
.= ||.((z * (f /. x1)) - (z * (f /. x2))).|| by A2, A8, VFUNCT_2:def 4
.= ||.(z * ((f /. x1) - (f /. x2))).|| by CLVECT_1:10
.= |.z.| * ||.((f /. x1) - (f /. x2)).|| by CLVECT_1:def 11 ;
0 <= |.z.| by COMPLEX1:132;
then |.z.| * ||.((f /. x1) - (f /. x2)).|| <= |.z.| * (s * ||.(x1 - x2).||) by A3, A8, XREAL_1:66;
hence ||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= g * ||.(x1 - x2).|| by A9; :: thesis: verum

end;

end;

end;

hence ex r being Real st
( 0 < r & ( for x1, x2 being Point of RNS st x1 in X & x2 in X holds
||.(((z (#) f) /. x1) - ((z (#) f) /. x2)).|| <= r * ||.(x1 - x2).|| ) ) ; :: thesis: verum