let K be Ring; :: thesis: for W being RightMod of K holds opp W is strict LeftMod of opp K
let W be RightMod of K; :: thesis: opp W is strict LeftMod of opp K
set R = opp K;
reconsider V = opp W as non empty VectSpStr of opp K ;
A1: addLoopStr(# the carrier of (opp W),the addF of (opp W),the U2 of (opp W) #) = addLoopStr(# the carrier of W,the addF of W,the U2 of W #) by Th12;
then A2: for a, b being Element of (opp W)
for x, y being Element of W st x = a & b = y holds
a + b = x + y ;
A3: ( opp W is Abelian & opp W is add-associative & opp W is right_zeroed & opp W is right_complementable )

proof

thus opp W is Abelian :: thesis: ( opp W is add-associative & opp W is right_zeroed & opp W is right_complementable )

proof

let a, b be Element of (opp W); :: according to RLVECT_1:def 5 :: thesis: a + b = b + a
reconsider x = a, y = b as Element of W by Th12;
thus a + b = y + x by A2
.= b + a by A1 ; :: thesis: verum

end;

hereby :: according to RLVECT_1:def 6 :: thesis: ( opp W is right_zeroed & opp W is right_complementable )

let a, b, c be Element of (opp W); :: thesis: (a + b) + c = a + (b + c)
reconsider x = a, y = b, z = c as Element of W by Th12;
thus (a + b) + c = (x + y) + z by A1
.= x + (y + z) by RLVECT_1:def 6
.= a + (b + c) by A1 ; :: thesis: verum

end;

hereby :: according to RLVECT_1:def 7 :: thesis: opp W is right_complementable

let a be Element of (opp W); :: thesis: a + (0. (opp W)) = a
reconsider x = a as Element of W by Th12;
thus a + (0. (opp W)) = x + (0. W) by A1
.= a by RLVECT_1:10 ; :: thesis: verum

end;

let a be Element of (opp W); :: according to ALGSTR_0:def 16 :: thesis: a is right_complementable
reconsider x = a as Element of W by Th12;
consider b being Element of W such that
A4: x + b = 0. W by ALGSTR_0:def 11;
reconsider b' = b as Element of (opp W) by Th12;
take b' ; :: according to ALGSTR_0:def 11 :: thesis: a + b' = 0. (opp W)
thus a + b' = 0. (opp W) by A1, A4; :: thesis: verum

end;

now

let x, y be Scalar of (opp K); :: thesis: for v, w being Vector of V holds
( x * (v + w) = (x * v) + (x * w) & (x + y) * v = (x * v) + (y * v) & (x * y) * v = x * (y * v) & (1_ (opp K)) * v = v )
let v, w be Vector of V; :: thesis: ( x * (v + w) = (x * v) + (x * w) & (x + y) * v = (x * v) + (y * v) & (x * y) * v = x * (y * v) & (1_ (opp K)) * v = v )
reconsider a = x, b = y as Scalar of K ;
reconsider p = v, q = w as Vector of W by Th12;
A5: v + w = p + q by Th22;
A6: ( x * y = b * a & 1_ (opp K) = 1_ K & x + y = a + b ) by Lm3;
A7: ( p * b = y * v & p * a = x * v & p * b = y * v & q * a = x * w ) by Th21;
thus x * (v + w) = (p + q) * a by A5, Th21
.= (p * a) + (q * a) by VECTSP_2:def 23
.= (x * v) + (x * w) by A7, Th22 ; :: thesis: ( (x + y) * v = (x * v) + (y * v) & (x * y) * v = x * (y * v) & (1_ (opp K)) * v = v )
thus (x + y) * v = p * (a + b) by Th21
.= (p * a) + (p * b) by VECTSP_2:def 23
.= (x * v) + (y * v) by A7, Th22 ; :: thesis: ( (x * y) * v = x * (y * v) & (1_ (opp K)) * v = v )
thus (x * y) * v = p * (b * a) by A6, Th21
.= (p * b) * a by VECTSP_2:def 23
.= x * (y * v) by A7, Th21 ; :: thesis: (1_ (opp K)) * v = v
thus (1_ (opp K)) * v = p * (1_ K) by Th21
.= v by VECTSP_2:def 23 ; :: thesis: verum

end;

hence opp W is strict LeftMod of opp K by A3, VECTSP_1:def 26; :: thesis: verum