let R be Ring; :: thesis: for G being LeftMod of R holds
( dom (ID G) = G & cod (ID G) = G & ( for f being strict LModMorphism of R st cod f = G holds
(ID G) * f = f ) & ( for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g ) )
let G be LeftMod of R; :: thesis: ( dom (ID G) = G & cod (ID G) = G & ( for f being strict LModMorphism of R st cod f = G holds
(ID G) * f = f ) & ( for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g ) )
set i = ID G;
thus dom (ID G) = G ; :: thesis: ( cod (ID G) = G & ( for f being strict LModMorphism of R st cod f = G holds
(ID G) * f = f ) & ( for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g ) )
thus cod (ID G) = G ; :: thesis: ( ( for f being strict LModMorphism of R st cod f = G holds
(ID G) * f = f ) & ( for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g ) )
thus for f being strict LModMorphism of R st cod f = G holds
(ID G) * f = f :: thesis: for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g

proof

let f be strict LModMorphism of R; :: thesis: ( cod f = G implies (ID G) * f = f )
assume A1: cod f = G ; :: thesis: (ID G) * f = f
set H = dom f;
reconsider f' = f as Morphism of dom f,G by A1, Def11;
A2: dom (ID G) = G ;
consider m being Function of (dom f),G such that
A3: f' = LModMorphismStr(# (dom f),G,m #) by Th15;
(id G) * m = m by FUNCT_2:23;
hence (ID G) * f = f by A1, A2, A3, Def13; :: thesis: verum

end;

thus for g being strict LModMorphism of R st dom g = G holds
g * (ID G) = g :: thesis: verum

proof

let f be strict LModMorphism of R; :: thesis: ( dom f = G implies f * (ID G) = f )
assume A4: dom f = G ; :: thesis: f * (ID G) = f
set H = cod f;
reconsider f' = f as Morphism of G, cod f by A4, Def11;
A5: cod (ID G) = G ;
consider m being Function of G,(cod f) such that
A6: f' = LModMorphismStr(# G,(cod f),m #) by Th15;
m * (id G) = m by FUNCT_2:23;
hence f * (ID G) = f by A4, A5, A6, Def13; :: thesis: verum

end;